Counterfeit Monkey — 163 of 292

Section 2 - Surveillance Room

[The surveillance room looks both forward and back in the story. It shows us a little of what's to come, and also lets us see what's happened to some of the characters from earlier on, providing something of a summary of recent events.

Design-wise, we need to be careful here. On the one hand, we want to extend a bit the time between the player realizing that Atlantida exists and his encounter with her; and build up a sense of menace around her. At the same time, there's a risk of diluting things *too* much or giving the player too many things to read and research, as opposed to things to do and manipulate.

The surveillance room description is intentionally kept very brief as a partial balance to this: there's not much to see because we're going to be focused on the computer screen, which contains lots of information.]

The Surveillance Room is east of the Oracle Project. It is indoors.

The surveillance computer is a desktop computer in the Surveillance Room. It is fixed in place. "A [surveillance computer] is mounted on the wall, an impressive flat screen readout[if the surveillance computer is switched on] displaying current activity[otherwise] presently blacked out[end if]." The surveillance computer is switched on.

The description of the surveillance computer is "Below the flat screen are a keyboard and mouse, both shiny silver. Only top of the line equipment down here, it seems."

Understand "flat" or "screen" or "readout" as the surveillance computer's screen. The description of the surveillance computer's screen is "It is bigger than my parent's television, and that is saying something."

[Here we nab something straight out of the Computers documentation: a computer with a multiple-choice operating system and a range of subprograms.

The sense we want to convey here is the sense of being the spider at the center of the web: the person using this computer has access to a huge range of information, a view of the whole Bureau and parts of the city.]

The surveillance computer runs a multiple-choice program called PCOS. PCOS is privately-named. The options table of PCOS is the Table of GUI Options.

The software priority of PCOS is 1.

Table of GUI Options

This is the access rule:

say "This selection brings up on screen a database of 'Accesses.' Still visible for today's date is a record labeled Inquiry on Civic Unrest.";

repeat with item running through software run by the surveillance computer:

now the software priority of item is 5;

now the software priority of access-database is 1;

try examining access-database.

This is the requisitions rule:

say "The screen brings up what appears to be a system for requisitioning and supply for this area. The recent entries are diverse and in some cases cryptic:

[fixed letter spacing] 34224 eBook order at request of Subject A details attached[line break]

34223 toys and diversions order at request of Subject A, children's jacks, balls, puzzles, games[line break]

34222 espresso beans for Subject A - previous order unacceptable see attached[line break]

34221 bakery requisition[line break]

34220 coffee beans resupply for Subject A[line break]

34219 berg resupply to boiler - previous supply melted - NB new supply is required even if not used[line break]

34218 rifle resupply for handlers for Subject A, new gel required as safety measure[variable letter spacing]

...and so on, scrolling back and back and back."

This is the power-grid rule:

say "The screen flashes up a schematic of the entire Bureau [--] the public rooms we're familiar with, the basement, and the special section we're in now. It appears that three different power supplies feed these, one for the public areas and one, more heavily backed up, for most of the basement. Both of these are running.

A third power supply is located east of here, and [if the boiler is switched off]is currently shut down, leaving the eastern rooms dark[otherwise]is lit up like a Christmas tree with the tremendous amounts of power it's channeling[end if]."

This is the open-security rule:

repeat with item running through software run by the surveillance computer:

now the software priority of item is 5;

now the software priority of security-program is 1;

say "[You] select the surveillance program. It brings up a menu of possible camera views. [run paragraph on]";

try examining security-program.

Understand "search [text]" or "search for [text]" as typing it on when the player can see a computer which runs a search engine.

Test surveillance with "x computer / x screen / turn on computer / select security / select statue / click customs / click front exit / type tools exhibit / type interrogation rooms circuit / g / g / g /click cold storage / click porch / click dwelling / click north exit / click main / select requisitions / select power / select access / look up me in computer / search for me / search for alexandra / search for andra / search for slango / search for protest / search for arbot / search for pleice / search for lena / search for reports"

Test survey with "test surveillance" in Surveillance Room.

The surveillance computer runs a search engine called access-database. The data table of access-database is the Table of Access Data.

Table of Access Data

The surveillance computer runs an multiple-choice program called security-program. Security-program is privately-named. The options table of security-program is the Table of Security Options.

Table of Security Options

This is the customs rule:

say "The screen shows the interior of the customs house, now barely populated thanks to the late hour. The camera is focused on the poster of wartime Atlantida. It looks perfectly ordinary and has suffered no defacement."

This is the statue rule:

say "The view shifts to a shot at the Roundabout, with its Atlantida statue, taken apparently from some building across the road. The crowd from earlier is long gone, and there's no obvious sign of vandalism."

This is the storage rule:

say "The screen shows the interior of the Cold Storage room. Nothing is moving in there."

This is the front rule:

say "The screen shows the rotunda. [one of]One tourist is heading towards the front door[or]A security guard makes a slow round[or]A family of tourists passes through[or]A young blond man, probably about 20, stands looking up at the Rotunda surface, his lips moving[cycling]."

This is the interrogation rule:

say "[one of]The screen shifts to displaying interrogation room A. [Higgate-behavior][or]The screen shifts to interrogation room B. [teen-behavior][or]The screen shifts to interrogation room C. [Brock-behavior][or]The screen shifts to interrogation room D. [stored-behavior][cycling].";

To say Higgate-behavior:

say "[one of]Professor Higgate is standing next to a metal table. She is wearing her shirt, but for some reason her lower half is stripped to the underwear. She is speaking urgently to someone who is not shown[or]Professor Higgate is shaking her head at someone she is talking to[or]Professor Higgate is slumped over a metal table, motionless[or]A hand reaches across the screen and presents Higgate with a plastic cup of coffee. She takes a sip of the coffee, looks stricken, and spits it back into the cup[or]Professor Higgate is sitting at a metal table, grimly clutching the crushed remains of a plastic coffee cup[or]The room is empty[stopping]".

To say stored-behavior:

if library message person is first person:

say "It's empty";

otherwise:

say "[one of]It's my father. He's been cuffed to a metal chair. Someone is sitting on the table and leaning towards him, but [you] can't see that person's face[or]Whoever-it-is is still talking to my father. It seems like it could be worse [--] maybe [--] but Father is still handcuffed[or]Father sits alone, cuffed to his chair. His interrogator has gone away for the moment[or]Father is sitting alone. He glances up at the camera, then back down at the table[or]My father is still alone in there[stopping]".

To say Brock-behavior:

if library message person is second person:

say "It's empty";

otherwise:

say "Brock sits behind a metal table, not speaking, not moving, just as Slango taught you guys".

To say teen-behavior:

if the teenagers are not in the Traffic Circle:

say "It's empty";

otherwise:

say "[one of]The defiant teenager from earlier is sitting in a chair with her feet on the table. She makes an obscene gesture at her interrogator, then at the camera as well[or]There's a flash of light. The defiant teenager's chair has been replaced by a hair[or]An officer is bent over something on the floor[or]It's empty[stopping]".

This is the tools rule:

say "The screen switches. [tv description][line break]".

This is the perch rule:

if the Precarious Perch is visited:

say "The camera shifts to the window outside Atlantida's window[if the tall window is open] (which is standing open as [you] left it)[end if] and a bit of cliff face.";

otherwise:

say "The camera shifts to show a bit of cliff overlooking the water. There's a window cut into the cliff face [--] that must be the exit in question[one of]. Is that a hint of movement behind the window? It's hard to be sure[or].

As we watch, a pale face appears at the window, too quickly to study, and then vanishes again[or][stopping]."

This is the static rule:

say "Nothing shows but a steady field of static."

This is the tunnel-display rule:

say "The camera shifts to show a dimly lit corridor cut through sedimentary rock[if Tunnel is visited][--] just below here, in fact[end if][if something portable is in the Tunnel]. [You] can make out [a list of portable things in the Tunnel][end if]."

Software can be quittable. A software is usually not quittable. Security-program is quittable. Access-database is quittable.

A first input handling rule for quittable software (called chosen software):

let N be indexed text;

let N be the topic understood;

if N is "main":

reset to operating system;

say "[You] return to the operating system.";

try examining PCOS;

rule succeeds.

Carry out switching off the surveillance computer:

reset to operating system.

To reset to operating system:

repeat with item running through software run by the surveillance computer:

now the software priority of item is 5;

now the software priority of PCOS is 1;

After examining a quittable software (called chosen software):

say "[You] can also select MAIN to return to the operating system."

Rule for listing exits when looking in Surveillance room:

say "[if Workshop is visited]The Workshop[otherwise]Another room[end if] lies to the east. The door [you] came through is west, and there is also a spiral staircase down[if tunnel is visited] to the tunnel[end if]."

The spiral staircase is a down-staircase in Surveillance Room. "A [spiral staircase] descends into a hole in the corner of the room, into what looks like a tunnel through natural rock."