Counterfeit Monkey — 165 of 292

Emily Short

Release 6

Section 4 - Generator Room

[This whole puzzle is a late-in-design addition. Originally the player went through the ODOR/DOOR and ran into Atlantida directly. But beta-testers felt that the process of getting to Atlantida was too easy and rapid, with insufficient build-up; there wasn't enough time to create apprehension. They also felt that the Bureau sequence was too linear. So we open things out a bit with a couple of puzzles that can be solved simultaneously: installing the power cord and getting the boiler working could happen in either order.

The imagery for this area is intentionally a bit first-person-shooterish, though I was thinking more Portal 2 than Half-Life. ]

The Generator Room is east of the Workshop. It is indoors and forbidden. "The walls are lined with concrete. [Yellow paint lettering] says CAUTION: HIGH ENERGY EQUIPMENT and DO NOT OPERATE WITHOUT TRAINING."

The concrete-lining is scenery in the Generator Room. The printed name is "concrete lining". Understand "concrete" or "lining" or "walls" or "wall" as the concrete-lining. The description is "It's untreated grey concrete."

The yellow paint lettering is scenery in the Generator Room. "CAUTION: HIGH ENERGY EQUIPMENT, it says. DO NOT OPERATE WITHOUT TRAINING. There is also a stenciled letter A surrounded by atom-style rings." Understand "stenciled" or "letter" or "letter a" or "atom-style" or "rings" or "ring" or "atom" as the yellow paint lettering.

The printed name is "[if looking]Yellow[otherwise]yellow[end if] paint lettering".

The first aid station is in the Generator Room. "[A first aid station] is built onto the wall[if the first aid station is open] and hangs open[otherwise]. It is closed[end if]." The first aid station is an openable closed container. The description of the first aid station is "It's a large box mounted to the wall, with a red cross painted on the front of it." Understand "large" or "box" or "red" or "cross" as the first aid station.

A ranking rule when the first aid station is mentionable:

increase the description-rank of the first aid station by 10.

In the first aid station is a balm. The indefinite article of the balm is "some". The description of the balm is "According to the label, it is designed to relieve the pain of severe burns."

Instead of waving the letter-remover at the balm when the current setting of the letter-remover is "b":

say "For a moment, just a moment, the balm starts to turn into an old-fashioned coin representing the concept of 'alm'; then it flickers out again uncertainly. Probably because 'alms' is not really a plural form and 'alm' is unattested in practice."

The boiler is a device in the Generator Room. It is fixed in place. "Most of the room is taken up with a gigantic boiler installation[if the boiler is switched on] periodically giving off flashes of light and steam[otherwise] that is currently off[end if]. The locking mechanism is [a cryptolock][if something is in the cryptolock], currently containing [a list of things in the cryptolock][otherwise], currently empty[end if]." It is switched off.

The description is "This frighteningly massive contraption has pipes and compression tanks and steam gauges and dents and rust stains[if switched on]. It trembles a little. The needles of the gauges twitch, but stay out of the red[otherwise]. All the gauge needles point to 0[end if]. A thick glass pane allows a view of one of the first chambers."

Understand "rust stains" or "stains" or "gauges" or "steam" or "power" or "generator" or "boilers" or "compression tanks" or "pipe" or "pipes" or "needles" or "large pipe" or "water" as the boiler.

Every turn when the location contains the switched on boiler:

if the remainder after dividing turn count by 3 is 0:

say "[one of]Light flashes[or]White light flashes[or]There's a particularly vibrant blue-white flash[or]There's a flash of light[or]Ice flashes into steam[or]A loud pfft! sounds[at random] [one of]within[or]inside[or]from within[or]in[at random] the boiler[one of] and[or] and all[or]. All[at random] the [one of]meters twitch[or]meter needles flicker into the red[or]steam gauge needles jump[at random][if a random chance of 1 in 3 succeeds] violently[end if]."

Instead of touching the boiler:

if the boiler is switched on:

say "The metal pipes are warm to the touch, and in a few places hot enough to scald.";


say "The pipes are mostly warm, except one running into the chamber which feels cool."

The thick-glass-pane is part of the boiler. Understand "thick" or "glass" or "pane" as the thick-glass-pane. The printed name is "thick glass pane".

Instead of examining the thick-glass-pane:

try searching the thick-glass-pane.

Instead of searching the thick-glass-pane:

if the boiler is switched off:

say "Water lies stagnant inside a large pipe, and a metal rod points down towards the water.";


say "Water flows steadily through a large pipe. Floating on the surface of the water are bergs of ice; before they melt entirely, a zap from a b-remover converts them to ergs. Each time this happens, there is a flash of light and steam, and the pane of glass becomes temporarily too fogged up to see through. The steam gauge needles jump.

Gradually the passage of the water cools the pane down again."

Check an actor switching on the boiler:

if the actor is not the player:

stop the action;

if the boiler is switched on:

say "The boiler is already in operation." instead;


say "There is no obvious switch. They most likely keep this thing locked." instead.