Counterfeit Monkey — 203 of 292

Chapter 4 - The Synthesizer

The plexiglas case is a thing in the Language Studies Seminar Room. It is transparent, closed, openable, lockable, and locked. It is fixed in place. "A massive plexiglas case takes up one corner of the room." The description is "The case is made of very thick protective plastic on a metal frame[if the screws are part of the plexiglas case and the plexiglas case is lockable]. It is thoroughly locked shut; I don't think [you][']ll have any luck with normal forms of approach. However, plexiglas is a cuttable substance with the right tools, and then there are the screws at the back[otherwise if the plexiglas case is not lockable]. The lid has been compromised by a saw, and the case is now permanenty open[end if]."

Test plexibug with "tutorial off / get plexiglas" in the Language Studies Seminar Room.

A description-concealing rule when the crossword is marked for listing:

if the crossword is in the synthesizer and the plexiglas case is closed:

now the crossword is not marked for listing.

Rule for printing the name of the synthesizer when writing a paragraph about something:

say "compact but high-powered late model synthes[ize]r".

Some screws are part of the plexiglas case.

[We would also have to make a rule preventing the player from cutting the plexiglas with the sword, except that the sword only exists after the plexiglas is opened.]

Sanity-check opening or closing the plexiglas when the plexiglas is not openable:

say "Thanks to our earlier efforts, the plexiglas is now open permanently." instead.

Test plexiglas with "tutorial off / cut plexiglas / cut plexiglas with jigsaw / g / cut plexiglas with sword / drop sword / cut plexiglas / close plexiglas" in the Seminar Room holding the jigsaw and the sword.

Sanity-check cutting the plexiglas with something:

if the plexiglas is not lockable:

say "I think [you] have done enough damage here." instead;

else if the plexiglas is unlocked:

say "No need: that would only make noise, and it's already open." instead.

Carry out cutting the plexiglas with the jigsaw:

now the plexiglas is open;

now the plexiglas is unlocked;

now the plexiglas is not lockable;

now the plexiglas is not locked;

now the plexiglas is not openable;

now the screwdriver does not unlock the plexiglas.

Report cutting the plexiglas with the jigsaw:

say "It's not a silent process, but it's not as loud as I had feared, either. The jigsaw cuts straight through the plexiglas, freeing it from its attachment to the locking mechanism." instead.

The screwdriver unlocks the plexiglas case.

Some screws are a thing. The screws are plural-named. The description of the screws is "Heavy-duty flathead screws, each about an inch long[if the screws are part of the plexiglas case and the plexiglas case is lockable]. They aren't sealed over, so it would be possible to unscrew them, given a screwdriver[end if]."

Instead of taking or turning the screws when the screws are part of the plexiglas case:

if the player can see the screwdriver:

if the player is not carrying the screwdriver:

try taking the screwdriver;

if the player is not carrying the screwdriver:

stop the action;

try unlocking the plexiglas case with the screwdriver;

if the plexiglas case is not locked:

rule succeeds;

otherwise:

say "I don't think [you] can pry the screws out with our fingers."

Understand "turn [screws] with [screwdriver]" or "unscrew [screws] with [screwdriver]" as unlocking it with.

Understand "turn [screws] with [something]" or "unscrew [screws] with [something]" as unlocking it with.

Understand "unscrew [plexiglas case] with [screwdriver]" as unlocking it with.

Understand "unscrew [plexiglas case] with [something]" as unlocking it with.

Check unlocking the plexiglas case with something which is not the screwdriver:

if the heft of the second noun is greater than 3:

say "[The second noun] [is-are] hardly designed for unscrewing things, and won't fit into the necessary angle anyway." instead;

else:

if the second noun is floppy:

say "[The second noun] [is-are] not at all suited to the purpose. There's a reason they make screwdrivers for this." instead;

else:

say "[You] try contriving to get an edge of [the second noun] into the slot of the screws, but [the second noun] just slip[s] around unhelpfully. There's a reason they make screwdrivers for this." instead;

Test unscrewing-bug with "unscrew case with as / unscrew screws with as" holding the as in the Seminar Room.

Setting action variables for unlocking the screws with something:

if the screws are part of the plexiglas case:

now the noun is the plexiglas case.

Carry out unlocking the plexiglas case with the screwdriver:

move the screws to the location.

Instead of unlocking the plexiglas case with the screwdriver for the first time:

say "[You] squeeze ourselves against the wall and angle to reach the screws with the screwdriver. I start on the first screw when[--]

'Is someone in the Seminar Room?' asks a male voice in the hall. 'I thought I heard something.'

'I don't think so.'

There's a listening silence from outside. [You] hold absolutely still.

Finally the footsteps move away again. It's probably safe to try again now, when I'm feeling a tiny bit calmer."

Report unlocking the plexiglas case with the screwdriver:

say "[You] awkwardly and silently squeeze against the wall and angle ourself so that [you] can reach the screws with the screwdriver. It's annoying work, but eventually [you] do work all the screws free enough that the case could be opened." instead.

Sanity-check locking the plexiglas case with something:

say "[You][']ll never get the screws back in. [You] just have to hope no one notices what [you] did until [you] [are] long gone." instead.

Sanity-check locking keylessly the plexiglas case:

say "[You][']ll never get the screws back in. [You] just have to hope no one notices what [you] did until [you] [are] long gone." instead.

Sanity-check turning the screws when the screws are not part of the plexiglas case:

say "There's no point now: they're not holding anything in place." instead.

The synthesizer is a container in the plexiglas case. The heft of the synthesizer is 4. The synthesizer is fixed in place. Understand "synth" or "synthesiser" as the synthesizer.

The description is "It is designed to accept two items and then be turned on. It is shiny and white, and looks a little like a bathtub for very short people."

The introduction is "It was a full-sized, human version of this that made us what [you] [are] now, so the object makes both of us feel a little skittish and self-conscious."

A crossword is in the synthesizer. The description of the crossword is "It looks like it's been snipped out of Chard-Farmer's Weekly, but it hasn't been filled in at all." Understand "puzzle" as the crossword.

Understand "solve [crossword]" or "fill in/out [crossword]" or "do [crossword]" or "finish [crossword]" as a mistake("My mother is good at these, but I've never had much luck with them myself.").

After inserting something into the synthesizer for the first time:

say "Voices from the hallway. I freeze. For a moment [you] hear them all too sharply: 'You check downstairs, I'll ask the professors.' It's a conversation of security guards, or police, or Bureau Officers. Someone is being looked for.

Then it's over. [run paragraph on]";

continue the action.

Sanity-check inserting something irretrievable into the synthesizer:

if the noun contains the tub:

try taking the tub;

if the noun contains the letter-remover:

try taking the letter-remover;

if the noun is irretrievable:

say "Since [the noun] contain[s] [if the noun encloses the tub][the tub][otherwise]something useful[end if], it might be a bad idea to change its form. [You] might not be able to get the contents back." instead.

Instead of switching on the synthesizer when the synthesizer contains the roll and the synthesizer contains the rock:

say "You can't get to rock & roll with just a synthes[ize]r. You'd need an ampersand generator, which unfortunately (despite promising research and a prototype resembling a pretzel-maker) has yet to achieve stable results."

Instead of switching on the synthesizer when the synthesizer contains the sill and the synthesizer contains the cate:

say "It feels like [you] ought to be close to getting a silicate out of all this, but no, I fear not. That final L on SILL is going nowhere."

Instead of switching on the synthesizer when the synthesizer contains the key-lime and the synthesizer contains a pi-object:

say "What, are you hoping for key lime π? I'm afraid the synthes[ize]r is literal-minded and doesn't do puns as such."

Instead of switching on the synthesizer when the synthesizer contains the pan and the synthesizer contains the ear:

say "That Indian soft cheese is called paneer, you know, not panear."

Instead of switching on the synthesizer:

synthesize contents of synthesizer.

To synthesize contents of (source - a thing):

let count be 0;

if source is a container:

let count be the number of things which are in source;

otherwise if source is a supporter:

let count be the number of things which are on source;

unless the count is two:

say "An indicator message lights up: FAIL: TWO OBJECTS REQUIRED FOR SYNTHESIS.";

stop;

let X be the player;

if source is a container:

let X be a random thing in the source;

otherwise:

let X be a random thing on the source;

let Y be X;

while Y is X:

if source is a container:

let Y be a random thing in the source;

otherwise:

let Y be a random thing on the source;

let the chosen article be Y;

let comparison number be the hash code of X with the hash code of Y added;

repeat with item running through things in the repository:

let matching success be true;

if the comparison number is the hash code of the item:

let the goal text be the name of the item minus the name of X;

replace the text " " in goal text with "";

if the goal text is "0":

change matching success to false;

otherwise:

if goal text exactly matches the text "[Y]":

now the chosen article is the item;

otherwise:

let the goal text be the name of item minus the name of Y;

replace the text " " in goal text with "";

if goal text exactly matches the text "[X]":

now the chosen article is the item;

if the chosen article is not Y:

if the heft of the chosen article is greater than 4 and source is synthesizer:

let N be indexed text;

let N be "[chosen article]";

say "An indicator message lights up: OVERRIDE: GENERATED OBJECT [N in upper case] EXCEEDS MAXIMUM SIZE LIMIT.";

stop;

abide by the dangerous destruction rules for X;

abide by the dangerous destruction rules for Y;

abide by the dangerous construction rules for the chosen article;

now the chosen article is not proffered by anything;

if the source is a container:

repeat with item running through things in the source:

now the item proffers the chosen article;

if the source is a supporter:

repeat with item running through things on the source:

now the item proffers the chosen article;

if an essential thing (called parent) proffers the chosen article:

now the chosen article is essential;

[if something which proffers the chosen article encloses an essential thing:

now the chosen article is essential; ]

if the source is a container:

now everything in the source is in the repository;

otherwise:

now everything on the source is in the repository;

move the chosen article to the source;

record "using the synthesizer" as achieved;

say "[The source] [if the source is a container]hums like a microwave oven for 43 seconds, then pings. Inside there [is-are a list of things in the source][otherwise]glows vibrant blue for five seconds, leaving behind [a list of things on the source][end if].";

try examining the chosen article;

have the parser notice the chosen article;

otherwise:

say "[The source] whirs for a moment, then dies down again.";