Counterfeit Monkey — 211 of 292

Emily Short

Release 6

Chapter 10 - The Anagramming Gun

Section 1 - Pistols and Shooting

[This is lightly adapted from the Technological Terror example in the manual. SHOOT is an annoying verb because there are several different equally valid syntaxes in English and we want to account for all of them, and make good guesses if the player types just SHOOT TARGET or SHOOT WITH GUN.]

A pistol is a kind of thing. A pistol can be loaded or unloaded. A pistol is usually loaded.

Definition: a thing is ungunlike if it is not a pistol.

Shooting it with is an action applying to one visible thing and one carried thing. The shooting it with action has an object called the detritus.

Check shooting something with something which is not a pistol:

say "[You] are insufficiently armed." instead.

Check shooting something with an unloaded pistol:

say "[The second noun] [is-are] not loaded." instead.

Check shooting a pistol with the noun:

say "[The noun] doesn't bend that way." instead;

Does the player mean shooting something which is not held by the player with something which is held by the player:

it is very likely.

Understand "shoot [pistol] at [something ungunlike]" as shooting it with (with nouns reversed).

Understand "shoot [something ungunlike] with [a pistol]" as shooting it with. Understand "shoot [something] with [something]" as shooting it with.

Understand "shoot [something] at [something]" as shooting it with (with nouns reversed).

Understand "fire [pistol] at [something ungunlike]" as shooting it with (with nouns reversed). Understand "fire at [something ungunlike] with [a pistol]" as shooting it with. Understand "fire at [something] with [something]" as shooting it with.