Counterfeit Monkey — 242 of 292

Section 17 - The rest of T

A tab is r-abstract. The description of the tab is "It lists the price of a tasting menu for two at the Literal Restaurant (seven courses not counting the intermezzo beet sorbet), with accompanying wine flights, espresso, and brandy to follow. Someone's expense account is shivering in a corner right now."

The heft of the tack is 1. The description of a tack is "The kind of thing used to stick papers to corkboards. It's pointy."

Sanity-check poking a person with the tack:

say "That would be unkind." instead.

Sanity-check poking a notepad with the tack:

say "We have no need to pin [the noun] to anything (and no corkboard, either)." instead.

Sanity-check poking an r-abstract thing with the tack:

say "[The noun] [is-are]n't sufficiently physical to interact that way." instead.

Sanity-check poking a fluid contained thing with the tack:

say "Then [the noun] would dribble all over the place." instead.

Sanity-check poking something with the tack:

say "There are no obvious advantages to making a very tiny hole in [the noun]." instead.

Test tack with "poke me with tack / poke sord with tack / poke fuel with tack / poke era with tack / poke jotter with tack / stick tack into fuel / poke tack into fuel / stick fuel with tack" holding the tack and the sord and the fuel and the era and the jotter.

The taco is edible. The description of the taco is "In the fried corn tortilla shell nestles a mixture of spiced pork, shredded lettuce, and sharp cheddar." The scent-description is "Mexican spices". Understand "spiced pork" or "pork" or "shredded lettuce" or "lettuce" or "sharp cheddar" or "cheddar" or "corn" or "tortilla" or "shell" or "fried" as the taco. The heft of the taco is 1.

A tad is r-abstract. The description of a tad is "A very small measure, like a teaspoon, of no particular substance."

The description of the tam is "A slightly baggy crocheted cap, striped in shades of blue and white." The tam is wearable. It covers the head-area.

The description of the tamale is "Still partly in its wrapper, and steaming hot. You seem to know what it is [--] some kind of traditionally Mexican or meso-American foodstuff? [--] but I can't say that it's familiar around here. The exterior looks like prepared corn dough of a fairly coarse kind. It smells like the interior may be spiced meat.". The tamale is edible.

Instead of searching the tamale:

now the description of the tamale is "Still partly in its wrapper, and gradually cooling. You seem to know what it is [--] some kind of traditionally Mexican or meso-American foodstuff? [--] but I can't say that it's familiar around here. The exterior is prepared corn dough of a fairly coarse kind, and [you] have crumbled this enough to reveal the spiced meat inside.";

say "Yup, definitely spiced meat."

The tan is an r-abstract. The heft of a tan is usually 0. The description is usually "The col[our] is the col[our] of bronzed skin as found on the beaches of Maui; a lazy, relaxed, year-round tan.". The scent-description of a tan is usually "coconut oil".

The description of the tat is "It looks like the end-of-day leftovers from a particularly ill-fav[our]ed yard sale. What's not broken is dirty, and what's not dirty is in terrible taste. There's a mechanical pencil with no lead, and a kiddie pool that leaks; a stained tablecloth that once had a pattern of squid tentacles on it; a bobble-headed doll representing the head player of the Maiana football team thirteen years ago."

The ten-object is r-abstract. The heft of the ten-object is 0. Understand "ten" or "10" as the ten-object. The description of a ten-object is usually "The number of fingers, the number of toes." The printed name of a ten-object is usually "ten".

The description of the Tao is "It presents itself as one of those circular yin-yang symbols, part black, part white. I'm afraid Atlantean understanding of Asian philosophies is fairly simplistic."

The description of a tap is "It's a tap marked [one of]Hot[or]Cold[at random][if the item described is not part of something], though not screwed into any sort of plumbing fixture at the moment[end if]."

The description of the tape is "It's clear tape, the kind you use to wrap presents or make childhood art projects. I made an entire paper village when I was small, at significant expense in sticky tape."

The description of the tar is "A pot of sticky black goo." The indefinite article of tar is "some". Instead of tasting or eating the tar: say "Ugh." Instead of smelling the tar: say "It smells like roadworks on a hot day."

The tarpan is an animal. The description is "A small, mouse-col[our]ed horse with black-barred legs. It looks wild and shows no signs of ever having been saddled or ridden."

Sanity-check mounting the tarpan:

say "The tarpan isn't broken to bridle, and I don't think we're going to start today." instead.

The printed name of an alterna-tart is "tart". Understand "tart" as an alterna-tart. The description of an alterna-tart is usually "She's dressed to minimize coverage, but it's not completely clear whether she's an actual sex-worker or just a woman with a bold taste in clothing."

A tart is usually edible. The description of a tart is usually "It is sized for one, with a crisp crust on which sugar crystals glitter; through the indentations on the top [you] smell what might be gooseberry." The scent-description is "fresh pastry and gooseberries".

A tartar is a man. The description of the tartar is "A ferocious man in a fur cap, carrying eccentric weapons; he looks like a medley of popular depictions of Genghis Khan."

The greeting of the tartar is "The tartar stares at us wild-eyed."

The scent-description of the tartar is "Is that yak sweat I detect?"

The description of the tartrate is "A fine, just off-white powder. It doesn't smell like anything in particular." The heft of the tartrate is 1.

Sanity-check waving the tartrate:

say "It's a powder, not a flag." instead.

Sanity-check climbing the tartrate:

say "There would have to be a much bigger mound of the stuff before [you] could plausibly climb it." instead.

Sanity-check pushing, pulling, or turning the tartrate:

say "At best [you] would just smear the stuff around." instead.

Rule for clarifying the parser's choice of the that-object: do nothing instead.

A tattle is r-abstract. The heft of a tattle is 0. The description of a tattle is "It is non-physical, but it sounds like a waspish playground voice recounting the sins of another child." The tattle is noisy.

Instead of listening to the tattle:

say "[one of]A child's voice from the tattle says, 'Mom! Timmy took the R out of my rice!'[or]'Mommy, David put restoration gel on grandma but it didn't work,' tattles a childish voice.[or]'Daddy, Timmy turned my bread into a bead!' tattles a childish voice.[or]'Daddy, David says he's going to turn my cake into caca,' whimpers a small child.[or]An excited child's voice says, 'Freddy made an underage twine purchase.'[at random]".

The terracing is r-abstract. The description of the terracing is "It suggests a texture like the many-layered vinyards on the slopes of the Rhine. According to your recollection, anyway. I haven't been." The indefinite article of the terracing is "some".

The terse automaton is a push-button device. The heft of the terse automaton is 3. The description of the terse automaton is "Still an automatic seer in a glass box.".

Instead of switching on the terse automaton:

say "'[one of]Outlook: OK[or]Don't worry[or]Be happy[or]Reply hazy[or]Rocks ahead[or]You: fine[at random],' announces the terse automaton."

The printed name of the that-object is "that". Understand "that" or "pronoun" or "demonstrative" or "object" or "object known as 'that'" as the that-object. The description of the that-object is "It's a curious little object, having no particular weight or size; whenever I look at it, I find myself concentrating on something else [--] like, say, at this moment, [the random visible thing which is not the that-object]." The that-object is r-abstract.

The tea is an edible contained fluid thing. The scent-description is "[one of]bergamot[or]smoky Lapsang[or]toasted rice and green tea[sticky random]". The description of the tea is "It manifested steaming hot." Understand "earl grey" or "earl gray" or "lapsang" or "souchong" or "green tea" or "toasted rice" as the tea. [I was very very tempted to put the tea in a vintage tea cup, as I spent part of the summer collecting such cups on eBay for a party, and I had in the process cluttered my brain with a lot of useless information about historical tea cup brands and patterns that clearly needed to go somewhere. But then I realized that it would be kind of a bother implementing the cup separately from the tea, and inconsistent with how other liquid manifestations usually work, and so I decided not to after all. The reader is invited to picture her choice of Aynsley, Paragon, Wedgewood, Royal Albert, Limoges, Lomonosov, etc. tea cup as she wishes.]

Check waving the letter-remover at the tea when the current setting of the letter-remover is "t":

say "For a flickering moment, the letter-remover very nearly manages to conjure some No Tea in its place." instead.

The description of the tear is "It looks like any other droplet of water."

Instead of tasting the tear:

say "It wouldn't survive the experience."

A fake-ten is r-abstract. The heft of a fake-ten is 0. The description of a fake-ten is usually "The concept of ten is here represented by [one of]the letter X[or]the digits 1 and 0[or]the digit A[or]an Olympic judge holding up a scorecard[at random]." Understand "ten" as a fake-ten. The printed name of a fake-ten is "ten".

The description of a tent is usually "It's one of those round pup tents, made of [one of][primary-color][or][secondary-color][at random] rip-stop nylon, big enough to sleep one diagonal adult or two children. There's a window of netting mesh so that it's possible to see inside." The tent is usually transparent openable enterable.

The printed name of the plural-tents is "tents". Understand "tents" as the plural-tents. The description of some plural-tents is usually "They're half a dozen identical A-line tents in olive-drab, looking like a temporary encampment from a 20th century war." A plural-tents is usually plural-named transparent openable enterable.

The description of the tepal is "It appears to be the petal from a tulip (or perhaps tulips don't have petals, properly speaking?). The col[our]ation is vivid and baroque, lush impenetrable black streaked with red, like a love note from Amsterdam."

The thick sari is wearable. It covers the torso-area. The description of the thick sari is "It's a fine Indian garment, made of vivid purple and silver wool, and thick enough to offer some protection from the cold."

The description of the tic is "It is manifested as a bit of reflective mylar that flashes and changes shape spasmodically. I can't look at it without wanting to blink and rub my eyes." The tic is r-abstract.

The tick is an insect. The description of the tick is "A flat, black, blood-sucking insect. It's also tiny, smaller than a match. Considering its size I'd be surprised if [you] manage to hold on to it for two minutes without losing it.". The heft of the tick is 1.

[The tick is a problem. It's technically an animal, but it shouldn't act like animals act because it's too small. In fact, it's so small that it's not realistic for the player to be able to hold onto it for long. Fortunately, though, the stick isn't an essential item in the game, so we can afford to lose it. This is one place where I have Alex really step in and take some action if the player doesn't do something: either we change the tick back into the sticky in a few moves, or we lose it.]

Tick-removal is a scene. Tick-removal begins when the player can see the tick.

Every turn during tick-removal:

say "[one of]That is, of course, if it doesn't attach to our skin and give us Lyme disease[or]I guess what I'm trying to say here is that I don't want our very own pet tick[or]...Okay, sorry, there's something I just need to do here. Blame my phobias if you will[stopping]."

Tick-removal ends painfully when the time since tick-removal began is 3 minutes. Tick-removal ends well when the player cannot see the tick.

Instead of putting the tick on something:

say "If [you] set it down, it'll be lost for good."

Instead of inserting the tick into something:

say "If [you] set it down, it'll be lost for good."

Instead of dropping the tick:

say "If [you] set it down, it'll be lost for good."

When tick-removal ends painfully:

if the player can see the restoration gel:

try putting the restoration gel on the tick;

otherwise:

remove the tick from play;

say "Whoops, I seem to have lost our tick! Oh well. Here's hoping it has a juicy and eventful life."

The description of the ticket is "It reads ADMIT ONE in large black letters."

Test coffer with "load gun / shoot cup" holding the anagramming gun and the bullets in the Private Solarium.

The tidy puce coffer is a closed openable container. The description is "It's a heavy, old-fashioned box with a peaked lid, lacquered all over in a shade somewhere between dark pink and dusty purple. It is very clean and precisely crafted."

The tilting-piano is an instrument. Understand "tilting" or "piano" as the tilting-piano. The printed name of the tilting-piano is "tilting piano". The description is "The legs on one side of the piano are very much lower than on the other side, so that the keyboard can only be played by someone with a very unconventional posture. To make the object look all the more carnivalesque, it is painted white and studded with blue and white rhinestones."

Test paintings with "autoupgrade / load gun / wave s-remover at paintings / shoot painting / put giant pin in t-inserter / shoot giant pint / wave g-remover at pig tat inn / shoot pi tat inn / put pin in inserter / shoot titan pint / open tub / gel tint / shoot paintings / wave g-remover at sign / shoot sin" holding the anagramming gun and the bullets and the paintings and the tub in the Sensitive Equipment Testing Room.

The titan-pin is wearable. The description of the titan-pin is "The pin depicts two giant-like figures locked in a wrestling match." The printed name is "titan pin". Understand "titan" or "titan pin" as the titan-pin. Understand "pin" as the titan-pin when the pin is not visible.

The titan-pint is a container. The description of the titan-pint is "It's a beer stein on whose side are two giant-like figures locked in a wrestling match. It's as though some Greek vase painters moved to Bavaria when the retsina ran out." The printed name is "titan pint". Understand "titan" or "titan pint" as the titan-pint. Understand "pint" as the titan-pint when the pint is not visible.

The tier is r-abstract. The description of the tier is "It's represented as a certificate hon[our]ing a donor in the fifth 'tier of giving'."

The description of the till is "An old-fashioned cash register with separate keys for half- and quarter-cents: Atlantean currency inflated more slowly than most, and still had absurdly low numbers until we went over to the Euro. Both sides are molded with a graceful female figure holding a cornucopia of goods from land and sea." The till is an openable closed container.

The description of the tills is "There is a whole heap of them, mostly old-style cash registers from before they were computerized, but also some more recent sorts, and even one of those clever modern ones that is just a prop for a tablet computer."

The tillage is r-abstract. The description of the tillage is "The fleeting images show acres of rolling farmland being worked over in preparation for planting. It looks like more wide-open space than we usually have in one place here on Atlantis. Perhaps the farmland pictured is French or even American."

The printed name of a tin-can is "tin". Rule for printing the plural name of a tin-can: say "tins". Understand "tin" as a tin-can. Understand "tins" as the plural of tin-can.

The description of a tin-can is "Since the label has come off, there is no knowing what might be inside. Might be squid rings (popular hereabouts, packed in olive oil). Might be pickled mushrooms. Might be dog food." The heft of a tin-can is 2. A tin-can is closed and openable.

Instead of opening a tin-can:

say "We don't have a tin-opener, and these are not the type where the top peels back."

A tint is r-abstract. The description of a tint is "A [one of][primary-modifier] shade of [primary-color][or][pastel-modifier] shade of [pastel-color][or][secondary-modifier] shade of [secondary-color][at random], as though someone had watercol[our]ed that bit of air."

The tip is r-abstract. The description of the tip is "The tip at the moment reads, '[one of]Foreign water may cause indigestion[or]Wear earplugs in tourist areas to avoid accidental dialect contact[or]Standing in the midst of a herd can be dangerous[or]Never g-remove gall[at random].'"

The tippet is a floppy wearable thing. The description of the tippet is "It's a very long black scarf-like garment, made of plain material. The alpha and omega of the New Church are embroidered just where they would appear over the heart of the wearer." The scent-description is "liturgical incense".

Sanity-check poking head through tippet:

try wearing the tippet instead.

The description of the tiptoes is "These severed toes insist on balancing on the tips. The effect is frankly disturbing."

Sanity-check standing up on the tiptoes:

say "[stand-on-tiptoe]" instead.

The description of the tiptoe is "A single severed toe balanced on its tip."

Sanity-check standing up on the tiptoe:

say "[stand-on-tiptoe]" instead.

To say stand-on-tiptoe:

say "Going around on tiptoe is only stealthy in movies. And that's assuming you're using your own tiptoes and not someone else's."

The tiptop is r-abstract. The description of the tiptop is "At the moment it resembles [one of]the weathervane at the top of a spire[or]the topmost point of a star from a Christmas tree[or]the capstone of a pyramid[at random]."

The description of the tit is "A small, harmless-looking bird." A tit is naughty-sounding. The heft of a tit is 2.

The description of the alterna-tit is "It is indeed a severed breast. Maybe a C-cup, creamy-skinned and all, but the fact that it looks like it's been raggedly chopped off by a serial killer really decreases the appeal."

The titan of diarists is a man. The description is "He looks vaguely, non-specifically reminiscent of Pepys. At any rate, the kind of guy who would have gone through the London Fire."

The titer is a contained fluid thing. The description of the titer is "The most dilute detectable solution of some virus. I doubt it can be too dangerous."

The titter is r-abstract and noisy. The description of the titter is "It's just about invisible except as a ripple in the air, but it sounds like a girl laughing behind her hand. Repeatedly."

Instead of listening to the titter:

say "The titter says, '[titter-noise]!'"

[There's really no need for the randomized laughter here, but then again, why not? It's in keeping with lots of other elements in the game.]

To say titter-noise:

let sound be indexed text;

let sound be "[one of]hee[or]he[or]hu[at random]";

let N be a random number from 2 to 4;

repeat with index running from 1 to N:

change sound to "[sound][sound]";

replace character number 1 in sound with "t";

say "[sound in sentence case]".

Test titter with "z / z / listen to titter / g / g / g" holding the titter.

A TNT is a kind of thing. The indefinite article is "some". The description of a TNT is usually "It is almost comically dangerous, like something out of a cartoon. Fuses stick out of the tubes, ready for lighting."

Instead of burning the TNT:

say "No, thanks, I'd rather not explode us both."

The toasts are an edible thing. The description of the toasts is "Two slices, one white, one whole-wheat. Both are brown around the edges and have been buttered lightly."

The scent-description is "butter and warm bread".

The description of the toe is "It looks like a little toe raggedly cut off with a bread knife. It wasn't, of course." The heft of the toe is 1. The scent-description of the toe is "inner shoe".

The description of the toes is "It looks like a set of toes raggedly cut off with a bread knife. They weren't, of course." The heft of the toes is 1. The scent-description of the toes is "inner shoe". The toes are plural-named.

To say body-part-prank:

say "[one of] (because after all it would be beyond the parameters of the change to generate the person whose body part it is). [It-they] [is-are] only moderately gory, and most locals get used to seeing this kind of thing as a prank from six-year-olds every halloween. Still, [it-they] might startle a tourist[or][stopping]".

The toe-ring is a wearable thing. The printed name is "toe ring". The description of the toe-ring is "A silver toe ring stamped with a celtic pattern."

The toil is r-abstract. The description of toil is "An utterly typical Atlantean image of an older man sweating in the sun and brushing sweat out from under his hat as he sees to the olive harvest. It could be taking place any time in the last century."

[It was, unsurprisingly, Graham who suggested TS Eliot as an alternate anagram for toilets/litotes.]

The description of the toilets-collective is "Enough toilets to stock a public restroom for a thea[ter] or a small sporting venue[one of]. And here I was hoping we'd get T.S. Eliot.[or].[stopping]". The heft of the toilets-collective is 10. The toilets-collective is plural-named. The toilets-collective is a toilet.

The description of the toll is "It's a list of prices for taking the high road across to Maiana. Different prices pertain depending on whether the toll-payer is driving a horse-cart or a donkey-cart."

The tom is a bird. The heft of the tom is 3. The description of the tom is "It's a boy turkey. At least, I assume it must be: I don't know how to sex a turkey. But it corresponds to the name."

[Guernsey tomato wine is a real thing. I quote from a BBC article:

"He explained that they called their wine Aztecato after the Aztecs who it is believed first cultivated the crop, but he did admit that his brew "didn't taste too good", but that did not stop them selling all 250 gallons."]

The tomato sauterne is a contained edible fluid thing. The heft of the tomato sauterne is 2. The description of the tomato sauterne is "The clear glass bottle contains a dessert wine [--] not the golden col[our] one might expect of a sauterne, but virulently red. Curly Edwardian script on the label declares the wine to be a tomato sauterne, vintage 2003, based on 'a unique recipe from the Channel Islands.' It also describes the winery as 'the Château d'Yquem of Guernsey.'"

The scent-description is "sticky-sweet marinara sauce".

Some toms are a bird. The heft of the toms is 10. The description of the toms is "A whole collection of male turkeys."

The tomcat is a cat. The printed name is "tomcat". The heft of the tomcat is 3. The description of the tomcat is "It's angry and feral and looks like it is ancestrally part bobcat or something else mad and wild."

Some tomcats are a cat. The heft of the tomcats is 10. The printed name is "tomcats". The description of the tomcats is "Wrathful, hissing, un-herd-able. They don't like one another and they don't like us. Let's get rid of them as soon as possible."

The description of the tome is "Extremely dusty, learned, and virtuous, such that I almost fall asleep just looking at it. It's nothing so ribald as the Bible, or even a hymnal or order of service: it appears rather to be a selection of sermons of the 18th century, from a period when it was considered somehow exciting to sit through a three-hour discourse on theology."

The description of the tomtit is "A small bird with some of its markings in black. I don't claim to be expert in these things, and neither, it seems, are you." The tomtit is a bird.

The description of the ton is "A big block of concrete. A fatal big block of concrete, as it turns out." The heft of the ton is 12.

The top-toy is privately-named. The printed name of the top-toy is "top". Understand "top" or "toy" as the top-toy. The description of the top-toy is "One of those painted wooden tops given to small children. The plants and animals on the side are typically Atlantean: an Atlantean miniature donkey, a squid, an olive tree, and a humble chard plant. In fact, each of these is subscribed with a word; these are, respectively, PERSISTENCE, INVENTION, FRUITFULNESS, and RESOURCE."

Instead of turning the top-toy:

say "[You] give the top a spin, and it whirls until the virtuous plants and animals blur together into a ribbon of green and grey. The [one of]donkey[or]squid[or]olive[or]chard[purely at random] lands face-up."

The torc is a wearable thing. The description of the torc is "It's a very heavy ring of precious metal, open at the front, so that it could just about be worn around the neck. The metal is worked in a pattern of braids and Celtic knots, and the ends of the torc are shaped like the heads of dragons." The heft of the torc is 3.

The tort is an r-abstract thing. The heft of the tort is 0. The description of the tort is "It shows a tiny image that, after enough squinting, I recogn[ize] as Tortious Linguistic Interference: a tiny man is converting his tiny neighbor's [one of]lawn into a local area network[or]house into a hose[at random]."

[More like Sacher torte than other kinds, probably.]

The torte is an edible thing. The description of the torte is "It is a thickly iced chocolate torte with a fine dusting of confectioner's sugar and layered with apricot jam." The heft of a torte is 1. The scent-description of the torte is "cocoa and apricots".

The heft of a tot is 3. The description of a tot is "An angelic little girl with big blue eyes and golden curls. She looks as though she was recently rescued from a Victorian orphanage by a kindly gentleman of means."

The greeting of a tot is "'Hewwo thew,' lisps the tot[if the player carries an edible thing]. Her eyes fix hopefully on [the random edible thing carried by the player][end if]."

[The normal response to pushing people in some direction says that only very small children can be manipulated that way; but of course, the tot *is* very small…]

Sanity-check pushing the tot to a direction:

say "[You] give them an encouraging push; the girl starts to whimper. Perhaps [you] should lead rather than herd." instead.

Sanity-check washing the tot:

say "I know you think on general principles that all small children are by definition sticky and need a bath, but this one seems to have manifested in a treacle-free condition." instead.

Some plural-tots are people. The printed name of the plural-tots is "tots". Understand "tots" as the plural-tots. The heft of the tots is 3. The description of the plural-tots is "An angelic boy and girl, looking like an illustration for Hansel and Gretel. They are wide-eyed and very small, and don't actually look capable of any independent thought. Sometimes one sucks its thumb."

Sanity-check pushing the plural-tots to a direction:

say "[You] give them an encouraging push; the girl starts to whimper. Maybe they're more inclined to follow than to be shoved?" instead.

Sanity-check washing the plural-tots:

say "I know you think on general principles that all small children are by definition sticky and need a bath, but these seem to have manifested in a treacle-free condition." instead.

The printed name of a tote-bag is "tote". Understand "bag" or "tote" as a tote-bag. The description of a tote-bag is "A two-handled sack for shopping purposes. It's made of sturdy canvas and looks resistant to stains."

Some totes are a container. The description of the totes is "A selection of shopping sacks. They are made of sturdy canvas and look resistant to stains."

The description of the totem is "A raven, carved in wood and painted in red and black."

The description of the totems is "A series of animals, carved in wood. The carving style is vaguely northwestern American, but it seems a bit slapdash [--] I suspect because it's a culture not well known here."

The description of the towering chute is "This is the lower end of a tremendous chute, perhaps from a fun-fair slide or a waterpark. The top of the chute is not clearly visible."

Instead of entering the chute:

say "Down here we're at the bottom end of the chute, so it's not as though we could slide anywhere on it."

The description of the toy rug is "It is a tiny but intricately woven oriental rug suitable for an expensive doll house." The toy rug is floppy. The heft of the toy rug is 1.

The track is long and strong. The description of the track is "It's a piece of the old tramcar track that used to run up Long Street from the docks. The original has mostly been pulled up now, of course, but there are still a few bits in the street. This length is about a half [if the player wears the britishizing goggles]metre[otherwise]meter[end if] long. And heavy." The heft of the track is 3.

The description of the tram is "One of the old-style trams that used to putt up Long Street from the docks back in the 20s and 30s. It is olive-col[our]ed, with wood flooring and sideboards, and carries an advertisement for ladies['] hair rinse on the side."

The description of the tramcar is "One of the old-style trams that used to putt up Long Street from the docks back in the 20s and 30s. It is olive-col[our]ed, with wood flooring and sideboards, and carries an advertisement for ladies['] hair rinse on the side.". The heft of the tramcar is 8. The tramcar is an enterable container. It is open. It is not openable.

The trampet is an enterable supporter. The description of the trampet is "It's a very small trampoline used for therapeutic exercises." The trampet allows seated and standing.

The trampet has a number called the jump count.

Instead of jumping when the player is on the trampet:

say "[one of]We get a pretty good height this way. [or][stopping]";

increase the jump count of the trampet by 1;

say "B";

repeat with index running from 1 to the jump count of the trampet:

say "o";

repeat with index running from 1 to the jump count of the trampet:

say "i";

repeat with index running from 1 to the jump count of the trampet:

say "n";

say "g!".

Before getting off the trampet:

now the jump count of the trampet is 0.

Before exiting when the player is on the trampet:

now the jump count of the trampet is 0.

Test trampet with "tutorial off / drop trampet / stand on trampet / jump / jump / jump / out / jump / stand on trampet / jump / jump / jump / jump / get off trampet / get on trampet / jump" holding the trampet.

The description of the traveller tips is "It's a pamphlet of suggestions for traveling in Atlantis. It recommends such standard precautions as having your name analyzed for possible weaknesses, leaving a photocopy of your passport with your embassy, and ridding your luggage of anything purchased in a non-English-speaking country."

The description of a traveller tip is "Now just a single piece of paper suggesting that one look at State Department reports on Atlantis to see whether the current political unrest is especially severe."

The description of the trap is "If you were expecting something small and harmless like a mousetrap, you're wrong: this is big and iron and would do a respectable job on a bear. [if open]Currently the jaws are forced apart, ready to spring on the unwary[otherwise]The jaws of the trap are closed, at least[end if]." The trap can be openable. The trap can be closed. The trap can be open. The trap is openable and closed. Understand "jaws" as the trap.

Understand "set [trap]" as opening.

Sanity-check opening the trap:

if the trap is open:

make no decision;

if the trap is not in the location:

say "It would be difficult, not to mention unsafe, to try to set the trap when it's anywhere but on the ground." instead.

Report opening the trap:

say "[You] apply a great deal of pressure to the levers of the trap and finally manage to get the jaws open." instead.

Sanity-check taking the open trap:

say "[You] don't want to get our hand anywhere near the trap while it's still set to spring." instead.

Sanity-check pushing or pulling or turning the open trap:

say "[You] don't want to get our hand anywhere near the trap while it's still set to spring." instead.

Sanity-check closing the trap:

say "It's not something one can just casually close back up. [You][']d have to spring it with something, preferably not one of our own limbs." instead.

Understand "spring [something]" as springing it with. Understand "spring [something] with [something]" as springing it with. Understand "spring [trap] with [a long thing]" as springing it with. Springing it with is an action applying to one thing and one carried thing.

Understand "poke [something] with [something]" as attacking it with. Understand "prod [something] with [something]" as attacking it with.

Understand "insert [something] into/in [trap]" as springing it with (with nouns reversed).

Understand "put [something] into/in [trap]" as springing it with (with nouns reversed).

Rule for supplying a missing second noun while springing something with:

if the player carries a long strong thing (called means):

now the second noun is the means;

otherwise:

say "[You] would need something long and sturdy to spring it with." instead.

Check springing something with something:

if the noun is not the trap:

say "[The noun] [is-are] not susceptible to springing." instead;

if the trap is not open:

say "[The noun] [is-are] closed already." instead;

if the second noun is the trap:

say "We need some second object to spring the trap with." instead;

if the second noun is not long:

say "[The second noun] [is-are] not long enough to provide protective distance." instead;

if the second noun is floppy:

say "[The second noun] [is-are] too floppy to apply the necessary pressure at a distance." instead.

Carry out springing the trap with something:

remove the second noun from play;

now the trap is closed.

Report springing the trap with something:

say "[You] prod [the trap] with [the second noun]. The trap snaps violently shut, shattering [the second noun]." instead.

Sanity-check attacking the trap with something:

try springing the trap with the second noun instead.

Instead of entering the open trap:

say "Even you don't have the self-control [--] or the suicidal inclination [--] necessary to break your own leg with forty pounds worth of cold iron bear trap."

Test trap with "open the trap / spring the trap / set the trap / drop the trap / set the trap / enter the trap / put stick in trap" holding the trap and the stick.

The description of the trash is "[one of][card-intro][or]A collection of random bits [--] sweet wrappers, tissues, bus tickets. Nothing of any value[stopping]." Understand "sweet" or "wrappers" or "bus" or "tickets" or "tissues" as the trash. The indefinite article of the trash is "some".

The appointment card is a thing. The heft of the appointment card is 1. The description of the appointment card is "It's a card from Arbot Maps & Antiques: FINE GOODS BY APPOINTMENT ONLY. The time scribbled at the bottom is 9 AM this morning. Looks like Brock's handwriting. There's also a tiny heart drawn in the corner." The scent-description of the appointment card is "mingled lavender and ash".

A description-concealing rule when Kate carries the appointment card:

now the appointment card is not marked for listing.

Instead of turning or searching or looking under the appointment card:

say "The reverse of the card is completely blank."

Instead of frowning at the appointment card:

say "We contemplate the card, but it doesn't reveal its secrets any faster than before."

To say card-intro:

assign "Trace Brock's movements at the antique shop" at Arbot Antiques;

complete "Check the dead drop at the public convenience";

record "visiting the dead drop" as achieved;

move the appointment card to the player;

say "Most of it's junk: sweet wrappers, tissues, bus tickets. But there's also, suggestively, an appointment card for Arbot Maps & Antiques".

The trig is r-abstract. The description of the trig is "A constantly moving figure of circles, triangles, sine and cosine graphs."

The description of the trigram is "It's a bone tile representing [one of]earth[or]mountain[or]water[or]wind[or]thunder[or]fire[or]swamp[or]heaven[at random]."

The triple varlet is plural-named. The triple varlet is a man. The description of the triple varlet is "Three inseparable page-boys, all with sneering, dishonest faces. They would plainly as soon rob you as look at you."

Check waving the letter-remover at triple varlet when the current setting of the letter-remover is "r":

say "Nice try, but a drinks-trolley-pushing TIPPLE VALET would need another P." instead.

The trill is an r-abstract noisy thing. The heft of the trill is 0. The description of the trill is "It sounds like an opera singer got stuck on repeat."

Instead of listening to the trill: say "The trill keeps on trilling."

The troll is a man. "The troll [one of]grunts[or]looks at us with an unpleasantly hungry expression[or]picks its nose[or]pounds one of its meaty fists into the opposite palm[or]looks around for something to smash[at random]." The description of the troll is "Grey skin, yellow teeth, green eyes. Legs as big around as tree trunks. A pot belly, speaking of a great deal of food eaten raw."

The greeting of the troll is "The troll grunts."

[A lightweight nod to tv tropes, focusing on the artifact section, both because it places us very early in the count and because it seemed like a suitable place to start for this game.]

The trope count is an r-abstract thing. The description of the trope count is "The count is currently only up to '[one of]applied phlebotinum[or]amulet of concentrated awesome[or]amulet of dependency[or]amplifier artifact[or]antimatter[or]artifact of death[or]artifact of doom[or]artifact of attraction[cycling].' This could take a while."

The truck is a car. The heft of the truck is 6. The description is "The cab of the truck is beaten and rusted, and the flatbed bears the stains of many years['] solo farming." Understand "cab" or "flatbed" as the truck.

The tub is an essential closed openable container. The description is "Now a handsome, giant-sized tub with RESTORATION GEL prominently emblazoned on the front." A restoration gel is in the tub. The description of the restoration gel is "The [holder of the restoration gel] contains a clear, sticky gel that restores objects to their original state, before any letter changing. This is a valuable item in your line of work." The indefinite article is "some".

Instead of smelling the tub, try smelling the restoration gel.

Instead of putting the tub on something when the player's command includes "gel":

silently try opening the tub;

if the tub is open, try putting the restoration gel on the second noun.

Some tubas are an instrument. The heft of the tubas is 5. The description of the tubas is "A shiny, cacophonous mass."

Instead of listening to the tubas:

say "Mercifully, they didn't materialize with a complement of tuba players, so there's nothign to hear." instead.

A tuba is an instrument. The heft of the tuba is 2. The description of the tuba is "I associate instruments like this entirely with band practice misery."

The tuck is r-abstract. The description of a tuck is "A neatly-stitched fold in a piece of cloth."

The heft of the tun is 12. The description of the tun is "It's a huge vat for wine, about 250 gallons worth: the equivalent of three puncheons or four hogsheads or 14 rundlets."

The description of two-added-nutmegs is "The nutmegs do somehow convey an air of superfluity. They're embarrassed. They've made their dish too spicy. They feel ashamed." The printed name of two-added-nutmegs is "two added nutmegs". Understand "two" or "added" or "nutmegs" or "spice" as the two-added-nutmegs.