Counterfeit Monkey — 248 of 292

Section 3 - Responses to demonstrations that aren't interesting

[These rules aren't usually that important: it's never necessary for the player to show any of these objects off, and they establish no critically-important information. What they *are* intended to do is give a little bit of feedback about the shown object that encourages the player to understand or recognize the possible uses of that object.]

The default comment-refusal rule is not listed in any rulebook.

A thing can be freaky. The ear, the gam, the pate, the earlap, the toe, the toes, the armpit, the heel, the rash, [the limb,] the sword-arm and the arm are freaky.

Report waving the letter-remover at something creating a freaky thing (called target):

say "[You] wave [the letter-remover] at [the second noun] and produce [a target], severed[body-part-prank].";

abide by the dangerous construction rules for the target instead.

Sanity-check wearing a freaky thing:

say "How very Silence of the Lambs. Ew." instead.

Before refusing comment by someone:

say "[demonstration of noun][paragraph break]";

Rule for refusing comment by someone when the noun is freaky:

if the current interlocutor is an animal:

make no decision;

if the current interlocutor exhibits caution:

say "[The current interlocutor] [one of]turns white[or]goes a bit green[or]looks like throwing up[or]obviously might faint[or]gags[at random]. After a moment to regain [its-their] composure, [it-they] flee[s] the vicinity.";

remove the current interlocutor from play;

reset the interlocutor;

otherwise if the ostensible motive is you-are-tourist:

say "[The current interlocutor] say[s], 'Don't worry, [the noun] [is-are] almost certainly fake. They make things like [the noun] with letter tools around here. Freaks out the tourists, though!'";

otherwise:

say "[one of][The current interlocutor] recoil[s] involuntarily.[or]'Ew!' says [the current interlocutor].[or]'Please take that away,' [the current interlocutor] say[s].[or]'Yuck,' [the current interlocutor] repl[ies].[at random]"

Last for refusing comment by someone when the noun is a long strong thing:

if the current interlocutor is an animal:

make no decision;

if the ostensible motive is:

-- you-hit-on:

say "[beat] 'I'm not impressed.'";

-- you-are-tourist:

say "[beat] 'Could you stop waving [the noun] around[if the current interlocutor exhibits courtesy], please[end if]? You could hit someone.'";

-- you-are-feckless:

say "[beat] '[awkward confrontation] I wish you'd stop waving [the noun] around.'";

-- otherwise:

say "'[awkward confrontation], please stop waving [that-those of the noun].'"

Last for refusing comment by someone when the noun is an edible thing:

if the current interlocutor is an animal:

make no decision;

if the ostensible motive is:

-- you-hit-on:

say "[beat] 'That's, uh, a nice gesture, but I'm not hungry.'";

-- you-are-tourist:

say "[beat] 'Thanks, but that's not what we do around here.'";

-- you-are-feckless:

say "[beat] '[awkward confrontation] I wish you'd leave me alone.'";

-- otherwise:

say "'I'm not hungry, thanks.'"

Last for refusing comment by someone when the noun is a wearable thing:

if the current interlocutor is an animal:

make no decision;

if the player is wearing the noun:

if the ostensible motive is:

-- you-hit-on:

say "[beat] 'I guess [the noun] look[s] fine on you.'";

-- you-are-tourist:

say "'[one of]Oh, don't worry, that's fine to wear around here[or][That-those of noun] do[es]n't make you stand out too much, don't worry[at random].'";

-- you-take-survey:

say "'If you're collecting fashion opinions, I'm not really good at that kind of thing.'";

-- you-are-feckless:

say "'Maybe go ask someone else these questions.'";

-- otherwise:

say "'That's nice, I guess[you-are-feckless].'";

otherwise:

if the current interlocutor exhibits privacy:

say "'No thanks.'";

otherwise:

if a random chance of 1 in 2 succeeds and the current interlocutor wears something (called the garment):

say "[The current interlocutor] do[es]n't think [the noun] really goes with [the garment].";

otherwise:

say "'I don't think that's my [one of]style[or]size[or]col[our][or]sort of thing[at random].'"

Definition: a thing is disruptive:

if it is noisy:

yes;

if it is an animal:

yes;

no.

Rule for refusing comment by a person when the noun is a car and the location is not a road:

if the current interlocutor is an animal:

make no decision;

if the current interlocutor exhibits courtesy:

if the current interlocutor knows you-are-feckless:

say "'I know it's confusing, but I'm going to have to ask you to remove your car,' says [the current interlocutor] politely[you-are-feckless].";

otherwise:

say "'We prefer a no-offroad-motor-vehicles policy here,' says [the current interlocutor] politely[you-are-feckless].";

otherwise if the current interlocutor knows you-are-feckless:

say "'That doesn't belong in here,' says [the current interlocutor] impatiently. 'Please stop cluttering the place.'";

otherwise:

say "'[you-are-feckless][awkward confrontation] that really doesn't belong in here,' says [the current interlocutor]."

Rule for refusing comment by a person when the noun is noisy:

if the current interlocutor is an animal:

make no decision;

if the current interlocutor exhibits courtesy:

say "'[awkward confrontation] [the noun] [is-are] a bit disruptive,' says [the current interlocutor].";

otherwise if the current interlocutor knows you-are-possible-customer or the current interlocutor knows you-are-past-customer:

say "'[The noun] [is-are] [one of]likely[or]going[at random] to drive away other customers,' says [the current interlocutor].";

otherwise:

say "'[The noun] [is-are] [one of]annoying[or]a nuisance[or]irritating[at random],' says [the current interlocutor].";

Rule for refusing comment by a person when the noun is a contained fluid thing:

if the current interlocutor is an animal:

make no decision;

if the current interlocutor exhibits courtesy:

say "'Just be careful not to spill [the noun],' says [the current interlocutor].";

otherwise if the current interlocutor knows you-are-possible-customer or the current interlocutor knows you-are-past-customer:

say "'Don't get any of [the noun] on the merchandise,' says [the current interlocutor].";

otherwise:

say "'Hm.'";

Rule for refusing comment by a police person (called stern person) when the noun is the roll of bills:

if the current interlocutor is an animal:

make no decision;

if the stern person knows you-are-dangerous:

say "Based on our behavi[our] so for, [the stern person] decide[s] this must be an attempt at bribery, and take[s] us in. And while [you] [are] able to get around the bribery charge eventually, quite a few other undesirable facts come out in the process...";

end the story saying "That was an error in judgment";

otherwise:

say "[You-are-dangerous][The stern person] recite[s] to us a bit of the penal code applying to attempts to bribe officers of the law."

Rule for refusing comment by someone when the noun is r-abstract:

if the current interlocutor is an animal:

make no decision;

if the current interlocutor is police:

say "[The current interlocutor] look[s] a little suspicious. 'I hope you got [that-those of noun] from someone who was licensed to create abstracts.'";

otherwise if the current interlocutor is tourist:

say "[one of][The current interlocutor] stare[s] at [the noun] in fascination. 'That's odd,' [it-they] say[s]. 'It's like it's there but not there.'[or][The current interlocutor] looks at [the noun] from several angles. 'I'm not sure what it's for, but that's cool.'[or]'Weird,' says [the current interlocutor]. 'You don't get that where I come from.'[at random]";

otherwise:

say "[The current interlocutor] [is-are] puzzled. '[one of]Looks like [a noun].'[or]Huh, [a noun].'[or]I guess it's supposed to be... [noun]?'[at random]";

Rule for refusing comment by someone (called listener) when the noun is the roll of bills:

if the current interlocutor is an animal:

make no decision;

if the listener is the attendant:

say "You paid for your stay already. If we pay again, she'll think we're checking in (as someone else).";

otherwise if the listener knows you-are-possible-customer:

say "'How about if you say what you want to buy?'";

otherwise if listener knows you-are-feckless:

say "'Hang on to your money.'";

otherwise:

say "[You-are-feckless][The listener] fold[s] our hand back over the bills. 'Better hold on to those.'"

Rule for refusing comment by someone who exhibits privacy when the noun is the letter:

if the current interlocutor is an animal:

make no decision;

say "'[awkward no], that doesn't seem like any of my business.'"

Rule for refusing comment by someone when the noun is an as:

if the current interlocutor is an animal:

make no decision;

if the current interlocutor knows you-are-possible-customer:

say "'[one of]That's not legal tender in Atlantis[or]I can't accept that as currency[at random].'";

otherwise if current interlocutor knows you-are-feckless:

say "'That's nice,' [the current interlocutor] say[s] insincerely.";

otherwise:

say "'[one of]Looks old[or]Huh[or]Looks like it came up heads[or]Tails, I see[at random].'"

Rule for refusing comment by an animal (called viewer):

say "[The viewer] cock[s] [its-their] head[if the noun acts plural]s[end if].".

Rule for refusing comment by something:

say "[one of]This evokes no particular interest[or][The current interlocutor] shake[s] [its-their] head[or][The current interlocutor] do[es]n't have anything to say in response[at random]."