Counterfeit Monkey — 266 of 292

Emily Short

Release 6

Section 1 - The Activist

[The scene with the activist is not a puzzle in any meaningful sense: we can walk on past the activist at any time. However, it does serve as a pacing device, slowing down access to SJ Hall. It also provides some useful exposition about what Alex is working on.

We can end the scene in three ways: by leaving, by donating money to the cause (which Alex won't like, since he considers it culpably naive), and by explaining to her at length why her idea is flawed.

Once the activist has left the area, her sign will be available for us to take, and we can make it into a sin or a sig if we're so inclined. (It is one of four signs we can affect, not including the sign on Atlantida's neck.)]

The greeting of the activist is "'[one of]Hi![or]Hello again![or]Hi there![stopping]'".

The generic positive of the activist is "yeah".

The generic negative of the activist is "[one of]no[or]no way[at random]".

The generic adversative of the activist is "buut".

The generic confrontational of the activist is "come on".

Report the activist saying hello to the player when the activist does not recollect environment-offer:

queue environment-offer instead.

Rule for avoiding talking heads when the current interlocutor is activist:

if the current interlocutor is ready for transition:

if the current quip is strongly-phrased and a random chance of 1 in 2 succeeds:

say "[beat][paragraph break]";

otherwise:

say "[beat] [run paragraph on]".

Rule for beat-producing when the current interlocutor is the activist:

if the activist carries the yellow sign:

say run paragraph on;

try the activist trying dropping the yellow sign;

otherwise:

if a random chance of 1 in 3 succeeds:

say run paragraph on;

try the backpacking girl trying examining the player;

otherwise:

say "[one of]She touches our arm[or]She channels all her rhetorical power through her eyebrows, which rise towards her hairline at moments of greatest earnestness[at random].[run paragraph on]";

Report the activist trying dropping the yellow sign:

say "She sets down the sign in order to free her hands for more expressive argument.[run paragraph on]" instead.

environment-offer is an NPC-directed quip.

The response is "'Do you have a minute to help save the environment?' the activist asks brightly."

Instead of saying no when no is available:

try discussing no.

no is an informative quip.

It mentions environment.

The comment is "'I'm sorry, I'm in a hurry,' we say. ".

The response is "Evidently she has a greater than usual flair for drama, because she refuses to be brushed off that easily. 'You're in a hurry now,' she says, 'but in a few short decades, you'll be much too late. Please, for the good of your planet.'".

It quip-supplies the activist.

It directly-follows environment-offer.

Instead of saying yes when yes is available:

try discussing yes.

yes is an informative quip.

It mentions environment.

The comment is "'Sure: why not?' we say.".

The response is "'Wonderful!' she beams. ".

It quip-supplies the activist.

It directly-follows environment-offer.

Carry out the activist discussing something when the activist does not recollect further-enviro-stuff: queue further-enviro-stuff.

further-enviro-stuff is an NPC-directed quip.

The response is "'Listen, we're trying to gain financial support to make a major advertising campaign pushing the concept of [i]toxi waste[/i] throughout the anglophone world. If you know anything about linguistic efficacy, I'm sure you can imagine the implications.' [paragraph break]I can, in fact, imagine the implications, probably a little better than she would like."

Rule for avoiding talking heads when the current interlocutor is the activist:

say "[one of]She steps closer to us. If I were in my regular body I would find this intrusion into my personal space intriguing.[or]She is swinging the sign back and forth by its stick while she talks. I try not to let this distract me too much.[or]She bites her lower lip.[or]She taps the sign against her boot.[stopping]".

encourage the activist to elaborate on the implications is a performative quip.

It mentions environment, activist.

The comment is "'Oh?' we say neutrally. This is all it takes.".

The response is "'[i]Toxi waste[/i] would be, in concept, a completely harmless, safe, and neutral substance that would have no detrimental impact on the surrounding environment. By raising awareness of [i]toxi waste[/i] throughout the Anglophone world, we would put the collective consciousness to work for the environment! It would then be possible for volunteer workers to convert large stocks of dangerous toxic waste into the safe, neutral [i]toxi waste[/i] using minimal energy.'".

It quip-supplies the activist.

It directly-follows further-enviro-stuff.

First report smiling when the current interlocutor is the activist and the current quip is further-enviro-stuff:

say "We smile in a blandly interested fashion.";

queue encourage the activist as immediate obligatory instead.

Sanity-check listening when the current interlocutor is the activist and the current quip is further-enviro-stuff:

say "We put on our most attentive expression.";

queue encourage the activist as immediate obligatory instead.

An availability rule for how consciousness will be raised:

if the activist recollects bid-for-cash, it is off-limits;

make no decision.

how consciousness will be raised is a questioning quip.

It mentions environment.

The comment is "'And, er, how do you plan to raise awareness of [i]toxi waste[/i] to sufficient levels to achieve linguistic efficacy?' we ask. Well, that was mostly me. But I'm curious.".

The response is "'That's where people like you come in,' she admits, with a sweet little smile.".

It quip-supplies the activist.

It indirectly-follows encourage the activist to elaborate on the implications.

how the campaign will address problems of visualization is a questioning quip.

It mentions environment, activist.

The comment is "'Studies have shown that linguistic efficacy is drastically harder to achieve when the body of speakers does not have a consensus about how to visual[ize] the object in question,' we point out, settling into our element. I've had so many undergraduates with ideas just like this one, all eager to tell me how they're going to change the world. I suppose I have exactly the same problem, only on a grander scale. [paragraph break]My comment seems to have gotten her a little lost, though, so I add, 'People need to have some image to attach to the term you're inventing for them. Otherwise, it will be much harder to achieve functional awareness levels.'".

The response is "'Oh! Yes, I left that part out,' she says. 'Our ad campaign will include extensive imagery of what we envision [i]toxi waste[/i] to look like [--] that is, a clear, od[our]less liquid.'".

It indirectly-follows encourage the activist to elaborate on the implications.

It quip-supplies the activist

whether this liquid will be water is a questioning quip.

It mentions environment.

The comment is "'Is the role of [i]toxi waste[/i] by any chance going to be played by, say, filtered water?' we ask.".

The response is "Her eyebrows crinkle together. 'Yes [--] well, maybe,' she says. 'Why?'".

It quip-supplies the activist.

It is restrictive.

It indirectly-follows how campaign will address problems of visualization.

Understand "if" as whether this liquid will be water.

ask whether this liquid will also be flavorless is a performative quip.

Understand "flavor" or "flavour" or "flavourless" or "if" as ask whether this liquid will also be flavorless.

It mentions environment.

The comment is "'[if immediately]Will it[otherwise]Will your proposed toxi waste liquid[end if] be flavorless, too?' you ask. I didn't come up with this one.".

The response is "'Huh?' [paragraph break]'I think,' you go on maliciously, 'that toxi waste should have a catchy flavor. Maybe spearmint.' [paragraph break]The furrow between her brows deepens as she tries to work out whether we are joking and, if so, what response would be appropriate. Finally she settles for, 'The ads are going to be on TV, so it's hard to show any flavors on television.'".

It quip-supplies the activist.

It indirectly-follows how the campaign will address problems of visualization

Report scoffing when the current interlocutor is the activist and the current quip is whether this liquid will be water:

say "We snort rudely. ";

try discussing warn the activist about term-reassignment instead.

Report laughing when the current interlocutor is the activist and the current quip is whether this liquid will be water:

say "We chuckle darkly. ";

try discussing warn the activist about term-reassignment instead.

warn the activist about term-reassignment is a performative quip.

It mentions environment.

The comment is "'Because,' we say, 'if you show people pictures of what is obviously water, they will continue thinking of it [i]as[/i] water [--] not as [i]toxi waste[/i], or whatever you want them to call it. Studies have shown that people's word concepts are very persistent in that way [--] and anyway there are a variety of reasons why even if you could do it, it would be very bad to overwrite the linguistic efficacy of [']water['].'".

The response is "She purses her lips. 'You're in Language Studies, aren't you?' she asks. 'I was warned about people from your department. You can be very negative.'".

It quip-supplies the activist.

It directly-follows whether this liquid will be water.

After reading a command when point out that being from language studies is available:

if the player's command includes "point out" or the player's command includes "point":

replace the matched text with "language".

point out that being from Language Studies does not make us wrong is a performative quip.

It mentions environment, research.

The comment is "'Negative or not, it is true,' we say. 'If you try to teach people a new word for an existing substance, you have to fight with their preconceptions about how to categor[ize] that substance. If, on the other hand, you try to make them think of a new and as-yet-non-existent substance, you have less control over what happens when it reifies [--] the result might not be quite what you wanted.'".

The response is "'All right,' she says belligerently. 'How would you do it?' [paragraph break]At this precise moment I feel myself fall for this girl. She's still naive and earnest and probably too young for me, but there is something about the determination and assertion and the spirit of I-dare-you-to-think-of-one-better that makes me want to drag her off to a coffee shop and enlighten her for four or five hours.

But I bet you wouldn't like to play gooseberry to that expedition.".

It quip-supplies the activist.

It is restrictive.

It directly-follows warn the activist about term-reassignment.

explain about our plans is a performative quip.

It mentions environment.

The comment is "'To do this really right,' I say, under our breath so that no one will overhear us, 'you have to think even bigger than you have been. Forget English. Forget Mandarin Chinese. Forget Spanish, Hindi, Russian, Arabic. You have to make a [i]new language[/i] to resolve these difficulties, and you have to teach it on an epic scale.'".

The response is "She has been leaning in, breathlessly, to listen to this explanation, but now she backs up and looks at us like we've sprouted a second head, which, all things considered, would not be all that unnatural. [paragraph break]'That would take forever!' she exclaims. (I had calculated maybe fifty or a hundred years to the first significant successes, but I suppose that is not unlike forever if you're sufficiently short-sighted.) 'And you'd need a huge amount of money!' [paragraph break]I sigh. 'All the same,' we say, a little sadly. 'It would work better than what you're proposing here. I'm sorry. I wish I thought it would work.'".

It quip-supplies the activist.

It directly-follows point out that being from Language Studies does not make us wrong.

Report smiling when the current interlocutor is the activist and the current quip is not explain about our plans:

say "[You] smile, a little more broadly than usual[one of][or]. So I think she's cute[stopping]." instead.

Report smiling when the current quip is explain about our plans and the current interlocutor is the activist:

say "[You] smile, a little bit apologetically.

She doesn't smile back. [run paragraph on]" instead.

Report laughing when the current quip is explain about our plans and the current interlocutor is the activist:

say "[You] laugh ruefully. 'Look, don't worry. No one believes my idea. Yours is simpler to explain.'

She smiles weakly. [run paragraph on]" instead.

Report frowning when the current quip is explain about our plans and the current interlocutor is the activist:

say "[You] frown. 'Look, there's no point in your getting annoyed at me because I'm telling you something you don't [i]want[/i] to be true. It's not my fault linguistic science works the way it does. But if you're going to try to make a change in the world, there's absolutely no point going at it without bothering to learn what works and what doesn't.'

She scowls at us." instead.

Report shrugging when the current quip is explain about our plans and the current interlocutor is the activist:

say "[You] shrug. 'Look, you don't have to believe what I'm saying.'" instead.

Before doing something when the current quip is explain about our plans and the current interlocutor is the activist:

casually queue better-go.

better-go is an NPC-directed quip.

The response is "'I'd better go,' she says. 'There are other people, I should try to [--] I've got a quota.'

She turns and heads across the quad, head down. Halfway there she stops and looks back at us, then walks on, more quickly."

After the activist discussing better-go:

reset the interlocutor;

remove the activist from play;

continue the action.

Carry out the activist discussing something when the activist recollects further-enviro-stuff and the activist does not recollect bid-for-cash:

queue bid-for-cash.

Carry out going to Samuel Johnson Hall:

remove the activist from play.

bid-for-cash is an NPC-directed quip.

The response is "'The next few months are critical to our operation,' the activist says. 'We need to be able to blitz multiple countries simultaneously with an intense and outrageous advertising campaign that will garner further media coverage from news sources and provoke discussion on the internet and in the workplace. But in order to do that, we need the funding to place high profile advertisements in a variety of places. That's why donations from people like yourself are going to be so very necessary.'"

donate is a performative quip.

Understand "cash" or "money" as donate.

donate mentions the roll of bills.

The comment is "Oh, you're not seriously going to [--] oh, god, you are. You know, this is never going to work. There are sound scientific reasons why [--] oh FINE.

We hand over some of your money [--] I guess I should console myself that it is yours [--] to the girl."

The response is "'Thanks!' she says brightly. Tucking the bill into her pocket, she gives a little skip and heads off across the oval to accost some other innocent.

You just enriched some random television network, you understand. That money won't do a lick of good to anyone else."

It quip-supplies the activist.

It indirectly-follows bid-for-cash.

After the activist discussing donate:

reset the interlocutor;

remove the activist from play;

continue the action.

Test activist with "tutorial off / z / x activist / yes / encourage / ask how consciousness / a campaign / donate / look" in Oval.

Test activist2 with "tutorial off / z / x activist / yes / listen / ask how consciousness / a campaign / a flavorless / a water / warn / point out / explain / smile" in Oval.

Test activist3 with "tutorial off / z / x activist / yes / smile / smile / ask how consciousness / a campaign / a water / laugh / point out / explain / frown" in Oval.