Counterfeit Monkey — 40 of 292

Section 5 - Sanity and Accessibility

The sanity-check rules are a rulebook.

This is the sanity-check stage rule:

abide by the sanity-check rules.

The sanity-check stage rule is listed before the before stage rule in the action-processing rules.

To decide whether (item - a thing) must be touched:

if the item is the noun and the action requires a touchable noun, yes;

if the item is the second noun and the action requires a touchable second noun, yes;

no.

An accessibility rule (this is the no touching NPC stuff rule):

if the touch-goal is enclosed by someone (called the owner) who is not the actor and the touch-goal must be touched:

if the person reaching is the player:

say "I don't dare invade the personal space of [the owner].";

rule fails;

make no decision.

A first accessibility rule (this is the go to location rule):

if the location of the touch-goal is not the location of the person reaching:

let the target room be the location of the touch-goal;

if the number of moves from the location to the target room is 1:

try approaching target room;

if the location is not target room:

rule fails;

make no decision.

To decide what object is the touch-goal:

(- (untouchable_object) -).

Sanity-check eating an inedible thing:

say "[The noun] wouldn't agree with us even if [you] were feeling better." instead.

Sanity-check wearing something which is not wearable:

say "[one of]I don't see how you plan to do that, short of tying [the noun] to our head. (Hint: no.)[or][The noun] [is-are]n't wearable.[at random]" instead.

Sanity-check pushing someone to a direction:

say "Only very small children are so easily steered." instead.

Sanity-check pushing a bird to a direction:

say "[The noun] would just flutter out of shoving range." instead.

Instead of switching on or switching off or entering a person:

say "Depending on what you mean by that, I either don't understand or else wish you wouldn't make those suggestions while we're sharing this body."

Sanity-check throwing a heavy thing at someone:

if the second noun is attackable:

say "That would certainly be a mighty blow if [you] could heft [the noun] in the first place." instead;

else:

say "Even if I were keen to throw things, [the second noun] is too heavy for flinging." instead.

Sanity-check throwing something at someone who is not attackable:

if the second noun is an animal:

say "I am not going to throw things at animals. I also don't like bb guns or slingshots." instead;

say "I generally avoid flinging things at people." instead.

Sanity-check swinging a person:

say "[one of]What, by the feet or something?[or]If you're thinking dance moves, I have two left feet. And so do you now, I suspect.[at random]" instead.

Sanity-check rubbing a person:

if the noun is an animal:

continue the action;

say "[You] should keep our hands to ourselves." instead.

Instead of burning a person:

try attacking the noun.

Sanity-check rebooting a person:

say "[The noun] [is-are] not obviously a cyborg, so I'm not clear on how that would work." instead.

Sanity-check eating a person:

say "You're just messing about with what I'll let our body do, aren't you?" instead.

Instead of smelling a person:

if the scent-description of the noun is "":

say "No particular od[our] is coming our way, which is fine by me." instead;

otherwise:

continue the action.

Sanity-check tying a person to something fixed in place:

if the noun is an animal:

say "I doubt whether it will help to hitch [the noun] to [the second noun]." instead;

say "Maybe you're big on tying people up in your line of work, but I try to avoid the kidnapping, assault, and bondage charges." instead.

Sanity-check tying something fixed in place to a person:

if the noun is an animal:

say "I doubt whether it will help to hitch [the second noun] to [the noun]." instead;

say "Maybe you're big on tying people up in your line of work, but I try to avoid the kidnapping, assault, and bondage charges." instead.

Sanity-check tying a person to something portable:

say "I don't see the point of that suggestion." instead.

Sanity-check tying something portable to a person:

say "I don't see the point of that suggestion." instead.

Sanity-check waving a person:

say "That doesn't even make sense." instead.

Sanity-check buying a person:

if the noun is an animal:

say "This isn't a livestock sale." instead;

otherwise:

say "Slavery has never been legal on the island." instead.

Sanity-check searching a person:

say "That might well be resented." instead.

Sanity-check opening a person:

say "I'm not sure what you're imagining, but I at least am no surgeon." instead.

Sanity-check closing a person:

say "I don't understand how that could be a meaningful action." instead.

Sanity-check wearing a person:

say "Did we watch a little too much Silence of the Lambs at some point? I don't fancy wearing a suit made of [noun], thanks." instead.

Sanity-check searching the player:

try taking inventory instead.

Sanity-check mounting a person which is not an animal:

say "[The noun] [is-are]n't a ride-giving animal." instead.

Sanity-check climbing a person:

say "[The noun] [is-are]n't [one of]a ladder[or]a tree[or]a staircase[or]a wall[at random]." instead.

Instead of searching or looking under or touching or rubbing or squeezing something which is worn by a person (called the proprietor):

if the proprietor is the player:

continue the action;

otherwise:

say "[The proprietor] might object."

Instead of searching or looking under or pushing or turning or pulling or touching or rubbing or waving or squeezing a floppy wearable thing which is not worn by a person:

say "Nothing interesting turns up [--] no hidden pockets or unnoticed scraps of paper or the like." instead.

Instead of looking under a person:

if the noun is in the location:

try facing down;

otherwise:

carry out the disclosing exterior activity with the noun;

say paragraph break.

Instead of drinking something which is not fluid:

if the noun is edible:

say "I could see eating [it-them of the noun], but no more.";

otherwise:

say "[one of]Even if [the noun] were liquid, [it-they] would still not be nice to drink[or]I don't fancy [noun] smoothie[at random]."

Understand "apply pressure to [something]" as pushing.

Understand "lean on [something]" as pushing.