Emily Short

Section 7 - Fireworks

Fireworks is a scene. Fireworks begins when Pinata Celebration has ended and the time since Pinata Celebration ended is 2 minutes. Fireworks ends when the number of filled rows in the Table of Pyrotechnics is 0.

[Instead of going to a room during Fireworks:

say "[You] [are] relishing the not moving for a moment."]

When Fireworks begins:

now the firework display is part of the sky;

[if the player can see the sky:

say "The sky cracks with a tremendous boom, and you register a flash of golden fire overhead.";

otherwise:

say "There is a huge distant noise. Something is happening to the sky.";

say "Slango tooks one look at us and wraps us in a blanket. 'Stay here,' he says firmly. ";

if the player encloses the rock or the roc is visible:

now Brock is in Brock's Stateroom;

now the rock is in the repository;

now the roc is in the repository;

say "He gels Brock back into existence and the two of them walk away.";

otherwise:

say "He walks away. A moment later, the ship engines start up.";

now Slango is in the command chair;

now Slango is seated.]

Every turn during Fireworks:

repeat through the Table of Pyrotechnics:

if the player can see the sky:

say "[description entry][paragraph break]";

otherwise:

say "[noise entry][paragraph break]";

blank out the whole row;

make no decision;

Table of Pyrotechnics

description	noise
"A silver rocket shoots up into the sky and bursts into a dozen tiny pinwheels like floating silver asterisks."	"There is a long whistle, a peppery burst. The fireworks must have started outside."
"Four red jets of fire appear over the old city turret. They shape into a cloud of red smoke, curling into very plausible quotation marks before dissipating."	"There is a distant roar like a hissing dragon."
"A thousand tiny golden double-dagger symbols material[ize] like stars and wink out."	"It sounds as though the sky is making popcorn."
"A delicate green flame leaps into the darkness and [--] elegant as a swimming fish [--] chases its own tail to form an @ overhead."	"The sky is temporarily very quiet."
"Something booms in the old city turret [--] something shot out of the deplural[izing] cannon! But it is not deplural[izing] shot. It is a ball of fire that arcs out over the harbor. At the height of its parabola it fragments and forms a gorgeous blue seriffed A over the water. The symbol and flag of Anglophone Atlantis."	"There is a deep boom of cannon fire."

Instead of examining the sky when firework display is part of the sky:

say "Over the island, the fireworks are shooting off from the old city walls, in hon[our] of Serial Comma Day."

The firework display is a distant thing. The description is "The end of the last burst is fizzing into nothingness." Understand "fireworks" or "rockets" or "rocket" or "fire" or "flame" or "symbols" as the firework display.

Counterfeit Monkey — 89 of 292