Counterfeit Monkey — 94 of 292

Chapter 2 - Tutorial Content

Section 1 - Initial Waking

Rule for printing the banner text when stored first name is not "Andra":

do nothing instead.

Before taking inventory for the first time:

if the player is carrying the letter-remover and the number of things carried by the player is 1:

say "You insisted that we bring almost nothing into the synthesis room, so the criminal who was performing the synthesis couldn't rob us. I had hoped there was more hon[our] among thieves, but you said no, there isn't.";

Definition: a thing is other if it is not the player.

Understand "us" or "ourselves" or "we" or "ourself" as yourself.

Check waving the letter-remover at yourself when the current setting of the letter-remover is "i":

say "If this were likely to work, it would be a terrible idea. Fortunately, we don't self-identify simply as I, and secondly, the letter-remover won't remove the last letter of something." instead.

When play begins:

say "Can you hear me? >> [run paragraph on]";

if the player consents:

say "[line break]Good, you're conscious. We're conscious. ";

otherwise:

say "[line break]Ah, smartaleck. But we're conscious. ";

say "I've heard urban legends about synthesis going wrong, one half person getting lost.

Do you remember our name?[no line break]"

[The worst is over. The operation was a success: we are now one person, unrecognizable. If you're a little disoriented at the moment, that is no surprise. I feel a little sick myself.

Fortunately, we prepared for this eventuality. Before the change, that is. We should have everything we need to leave the country.

Me, I've been wandering around a bit aimlessly, waiting for you to come to. Here, I'll let you get your bearings...]

Identification is a scene. Identification begins when play begins. Identification ends when stored first name is "Andra".

Instead of looking during identification:

do nothing.

Stored first name is indexed text that varies. Stored first name is "nothing".

New first name is indexed text that varies. New first name is "nothing".

After reading a command during identification:

unless the player's command matches "restore":

if stored first name is "nothing":

now stored first name is "[the player's command]";

now stored first name is "[stored first name in sentence case]";

replace the regular expression "\p" in stored first name with "";

if stored first name is "Alexandra":

say "That's our joint name now, yes. I was Alex before the synthesis. You were...";

otherwise if stored first name is "Alex":

say "No, I'm Alex. Together we're Alexandra; before our synthesis, you were...";

otherwise if stored first name is "Andra":

say "Exactly right. And I'm Alex, making us jointly Alexandra. As far as I can tell, the operation was a success. We're meant to be one person now, unrecognizable to anyone who knew us before.[paragraph break]";

wait for any key;

say "[banner text]";

say "[paragraph break]Let's try to get a look around. I haven't been able to run our body without your help, but maybe now you're awake, it'll work better.";

otherwise if stored first name is "No" or stored first name is "N":

say "To review, we're Alexandra now. I was Alex, before the synthesis. You were...";

otherwise if stored first name is "Yes" or stored first name is "Y":

say "Right, we're Alexandra now. Before the synthesis, I was Alex. You were...";

otherwise:

say "...er, no. We're Alexandra now. Before the synthesis, I was Alex. You were...";

otherwise:

now new first name is "[the player's command]";

replace the regular expression "\p" in new first name with "";

now new first name is "[new first name in sentence case]";

replace the regular expression "\p" in new first name with "";

if new first name is "Andra":

say "...yes! Okay. We're both here, neither of us lost our minds in the synthesis process. ";

otherwise:

say "...oh boy. Okay. Okay. I need you on form here. This is going to be hard if you don't remember being Andra. Not panicking. ";

say "As far as I can tell, the operation was a success. We're meant to be one person now, unrecognizable to anyone who knew us before.[paragraph break]";

now stored first name is "Andra";

wait for any key;

say "[banner text]";

say "[paragraph break]Let's try to get a look around. I haven't been able to run our body without your help, but maybe now you're awake, it'll work better.";

consider the scene changing rules;

reject the player's command.