Counterfeit Monkey — 118 of 292

Emily Short

Release 6

Section 5 - Outdoor Cafe

The Outdoor Cafe is south of the Fish Market and west of Deep Street. The printed name is "Outdoor Café". "From this slightly raised terrace, tourists have a view of the activity in the market and out over the docks[one of][or]. The street is [east], the Fish Market [north][stopping]."

The rocky cliff-face is a scenery facade in Outdoor Cafe. It fronts south. Understand "cliff" or "rocks" or "face" as the rocky cliff-face. The description is "This little terrace area has been carved out of the hillside. Immediately to the south there is only rough rock wall for many feet up."

The closure notice is "That way is bare cliff rock. ".

The cafe building is a scenery facade in Outdoor Cafe. It fronts west. The printed name is "café building". Understand "café" as the cafe building. The description is "The source of drinks and small snacks when the café is in full operation. At the moment there isn't much sign of life from inside." The closure notice of the cafe building is "[if traffic circle is visited]The place is entirely closed now.[else]When we approach, a girl comes to the window and waves us off. 'We're just closing up. No new customers!'[end if]"

Some round black metal tables are supporters in the outdoor cafe.

"Several [round black metal tables] have been set out, with [umbrellas]."

The description is "The wobbly, tipsy kind of table that jog at a touch and spill your coffee everywhere.".

Understand "table" as the round black metal tables.

Nexami Engeo is an alert man. Understand "Nex" as Nexami Engeo.

The description is "A big man, both tall and stout. He hasn't reached overweight yet, but it looks like a matter of time. He's wearing [a list of things which are worn by Nexami]."

The introduction is "He's a musician, the front man of engeo. Your gang helped him out with some customs issues because of his unusual name."

He wears a rocker jacket and jeans.

The description of the rocker jacket is "It's black leather. It might make the wearer look fierce if he didn't have such a round dimpled face."

The description of the jeans is "Blue. Ordinary cut. I'm not really an expert in fashion."

Rule for writing a paragraph about Nexami when Nexami is not as-yet-unknown:

carry out the writing a topic sentence about activity with Nexami;

carry out the giving surrounding details for activity with Nexami;

now the rocker jacket is mentioned;

now the jeans are mentioned;

now held-break is true;

say "[run paragraph on]";

Rule for writing a topic sentence about Nexami Engeo:

say "[one of]Curiously, there's an acquaintance of yours here: [or][stopping][Nexami Engeo] is at one of the [round black tables]. [run paragraph on]"

The wire chair is a chair in the outdoor cafe. It is scenery. On the wire chair is Nexami.

A spill is on the round black tables. It is fluid scenery. The flexible appearance is "There's [a spill] [if the spill is in the location]on the ground[otherwise][in-on the holder of the spill][end if]." The description is "It looks like a quantity of red wine, just waiting to stain some vulnerable bit of clothing."

Report Nexami saying hello to the player for the first time:

now the spill is not scenery;

say "Nexami nods to us. 'Watch out. That table next to you has something sticky spilled on it.' And indeed there is a spill. You were about to lean on it nonchalantly." instead.

Nexami-encounter is a scene. Nexami-encounter begins when Nexami is the current interlocutor. Nexami-encounter ends in abandonment when Nexami is not the current interlocutor. Nexami-encounter ends in departure when the time since Nexami-encounter began is two minutes.

When Nexami-encounter ends in departure:

say "[if the prior named noun is Nexami]He[otherwise]Nexami[end if] stands up and mutters something. I have a little trouble with his Scottish accent [--] [you] don't get a lot of that around here, for obvious reasons [--] but you interpret it as him saying he'd better go pay up.

He heads into the interior of the café.";

reset the interlocutor;

remove Nexami from play.

Instead of touching or rubbing the spill:

say "Better not to get it on ourselves."

Instead of taking the spill:

say "It's not the kind of thing [you] can just pick up and carry away."

Rule for disclosing contents of the round black metal tables when the round black metal tables support the spill:

say "Someone has left [a spill] on [if Nexami is not visible]one of the tables[otherwise]another[end if][if the round black metal tables support a mentionable thing], nearly touching [the list of mentionable things on the round black metal tables][end if].[run paragraph on]".

[The introduction of Outdoor Cafe is "It is here that you and I first met: me drinking my coffee, you with an austere cup of herbal tea. I enjoyed that meeting, but somehow I am uncomfortable being here, as though [you] might be recognized as the couple from earlier. Ludicrous, I know. You're calm." ]

Rule for listing exits when looking in Outdoor Cafe:

do nothing instead.

Instead of touching the round black metal tables: say "The table wobbles under our fingers."

Some umbrellas are part of the round black metal tables. The description of the umbrellas is "They carry advertisements for brands of liqueur and beer." Understand "umbrella" as umbrellas. The umbrellas can be open or closed. The umbrellas are open. Instead of closing the umbrellas, say "They are meant as protection against the sunlight, and might [you] not draw notice from the waitstaff if [you] messed with them?" Instead of opening the umbrellas, say "They are already open."

Check waving the letter-remover at the umbrellas when the current setting of the letter-remover is "s":

say "The waitstaff would certainly notice." instead

[Before going to the Tin Hut when the Counterfeit Monkey is unvisited:

say "I'm sure that would be interesting under other circumstances, but we have an appointment to keep." instead.

Before approaching the Tin Hut when the Counterfeit Monkey is unvisited:

say "I'm sure that would be interesting under other circumstances, but we have an appointment to keep." instead. ]