Counterfeit Monkey — 119 of 292

Section 6 - Tin Hut

The Tin Hut is east of the Fish Market. It is indoors. "Most of the light in here comes from [circular windows] punched into the tin walls just under the ceiling. From the inside, the building looks both larger and more sound than it appears from outside: there are plenty of sturdy [struts] supporting the roof and keeping the walls upright."

The introduction is "Sometimes smugglers and forgers have been known to stash things in here, since the building is close to the docks but rarely attracts the interest of customs officials."

Understand "hide [text]" as a mistake ("A natural impulse, but I don't think she's coming in here. And if she did, the last thing [you][']d want would be to be caught hiding. The key thing is to be in plain sight and obviously innocent.") when the location is the Tin Hut and the Authenticator is in the Fish Market.

Rule for listing exits while looking in the tin hut:

do nothing instead.

Some tarpaulin-covered masses are an enterable supporter in Tin Hut. They are fixed in place. "Various [tarpaulin-covered masses] fill the room." The description is "From the shapes visible under the blue plastic, it appears that they are probably tables and stalls, buckets, signs, and other necessary features of the fish market when sales are in progress. There's a flattish area we could probably scramble onto." Understand "tarpaulin" or "tarp" or "tarps" or "tables" or "stalls" or "awnings" or "signs" or "buckets" or "table" or "stall" or "awning" or "bucket" or "flattish" or "area" as the masses.

The masses allow seated, standing, and reclining. The posture of the masses is standing.

Test massesbug with "x masses / stand on masses / climb on masses" in Tin Hut.

Test areabug with "jump onto flattish area / scramble onto flattish area / go to flattish area" in the Tin Hut.

Understand "jump onto/on/into/in [something]" as entering.

Understand "scramble onto/on/into/in [something]" as climbing.

Sanity-check approaching the masses:

try entering the masses instead.

Sanity-check climbing the masses:

try entering the masses instead.

Report entering the masses:

say "[You] identify the sturdiest-looking part of the construction and clamber onto it." instead.

Instead of taking the masses:

say "It all looks fairly heavy, but not useful. Also, and I real[ize] this weighs more with me than with you, I think the people who own it might mind the loss."

Instead of searching or looking under the masses:

say "[one of]Lifting the edges of the nearest tarps confirms what [you] already suspected: they[or]They[stopping] are various tables, stalls, awnings, etc. belonging to the fish market."

Some circular windows are scenery in Tin Hut. "The windows admit diffuse light only."

Understand "sky" or "ellipse" or "window" or "ellipse of sky" as the circular windows.

Every turn when the Authenticator is in the Fish Market and the location is Tin Hut:

if a random chance of 1 in 3 succeeds:

say "[one of]Ominous sounds come through the windows, but we're at the wrong angle to see out[or]More racket comes in through the windows[stopping].".

Instead of entering or climbing the circular windows, say "Even if they were low enough to reach, each one has a hand's-breath diameter. At best [you] might be able to see through them."

The Authenticator has a number called patience. The patience of the Authenticator is 3.

Instead of searching the circular windows:

if the player is on the masses:

decrement the patience of the Authenticator;

if the patience of the Authenticator is 0:

remove the Authenticator from play;

say "[You] put an eye to one of the windows. ";

if the Authenticator is in Fish Market:

say "[one of]The Authenticator is still in sight. Two assistants are in the middle of arresting a man for selling germ-based gems, but she is ignoring this play and looking for something or someone else[or]The Authenticator is still out there, looking for something[or]The Authenticator is crossing the market in this direction, but she's not looking straight at us, at least[stopping]." instead;

otherwise:

say "The coast looks clear. No one from the Customs House is doing a sweep at the moment." instead;

say "At this angle, there is nothing to see but an ellipse of sky."

The struts are scenery in Tin Hut. Understand "strut" or "roof" or "wall" or "walls" or "tin" or "corrugated" as the struts. The description is "The struts form a dull but sturdy lattice of metal, supporting the corrugated metal roof and walls."

Instead of attacking the struts:

say "When struck, the metal booms hollowly, but nothing happens."

The trap-door is a door. It is below the Tin Hut. "A [trap-door] is set in the floor[if something wedges the trap-door], propped by [a random thing which wedges the trap-door][end if]." The printed name is "trap door". Understand "trap" or "door" or "trapdoor" or "hinge" or "hinges" or "hinging" or "mechanism" as the trap-door. The description is "It is a wooden door set into the floor. The hinging mechanism is designed to keep the door closed if possible, perhaps as a safety feature so that people won't fall into an open hole."

Rule for writing a paragraph about the trap-door when the location is the Crawlspace:

say "[The trap-door], wedged open by [a random thing which wedges the trap-door], admits the only light.";

say line break.

Every turn when the trap-door is open and the trap-door is not wedged by something:

now the trap-door is closed;

say "The trap-door makes a creaking noise and slams shut again";

if the player is in the Crawlspace:

say ". I DO NOT LIKE being in the dark in a confined space with potential rats. Sorry, I'm getting us out of here. You can come back later.";

wait for any key;

try going up;

otherwise if Crawlspace is not visited:

say ". They must prop it open when they use it.";

otherwise:

say "."

Instead of going to the Crawlspace when the Crawlspace is visited and the trap-door is not wedged by something:

say "Let's wait to explore down there until [you] can make sure the trap door won't slam on us."

Before closing a door which is wedged by something (called the impediment):

say "(first removing [the impediment])[command clarification break]";

try taking the impediment;

if the noun is wedged by something:

stop the action.

Before taking something which wedges the trap-door when the player is in the crawlspace:

say "I'd rather not be confined down here in the dark, if it's all the same to you." instead.