Counterfeit Monkey — 140 of 292

Section 7 - Samuel Johnson Basement

Below Samuel Johnson Hall is Samuel Johnson Basement. The description of Samuel Johnson Basement is "Dank and malod[our]ous: there are no windows down here, and the drainage is terrible.

The stairs [up] are here; the lecture room at the [east]. Immediately [south] is the Graduate Student Office, and [southwest] is Professor Brown's office. The most interesting of all is the small door west, trying to look inconspicuous, but locked with a keycard lock: it's where the department stores its most dangerous licensed equipment[if the small door is open]. At the moment it stands invitingly open[end if]."

Rule for listing exits while looking in Samuel Johnson Basement:

do nothing instead.

Instead of smelling Samuel Johnson Basement, say "The distinctive scent of mildew, no doubt a result of the endless flooding and re-flooding of this corridor." Samuel Johnson Basement is indoors.

The small door is west of Samuel Johnson Basement. The small door is a door. It is closed and locked. It is scenery. The description of the small door is "It has no label, only a keycard-reading lock.".

Report unlocking the small door with something:

say "[You] unlock the small door with a swipe of [the second noun]." instead.

The keycard-reading lock is a container. It is part of the small door. The description is "It looks high-tech: all black plastic, and a slot to swipe a keycard through." Understand "slot" or "keycard lock" as the keycard-reading lock.

Instead of inserting something into the keycard-reading lock:

say "[The noun] won't fit."

Instead of inserting the keycard into the keycard-reading lock:

try unlocking the small door with the keycard.

Instead of inserting the card into the keycard-reading lock:

try unlocking the small door with the noun.

Instead of inserting the passcard into the keycard-reading lock:

try unlocking the small door with the noun.

Instead of inserting the pass into the keycard-reading lock:

try unlocking the small door with the noun.

Understand "swipe [something]" as taking.

Understand "swipe [keycard]" as swiping. Swiping is an action applying to one thing.

Check swiping:

if the player cannot see the keycard-reading lock:

say "There's nothing here to read it with." instead.

Carry out swiping:

try unlocking the small door with the keycard instead.

Understand "swipe [keycard] in/through [something]" as inserting it into.

Instead of unlocking the small door with the card:

say "It slides through the lock, but of course it doesn't have a magnetic unlocking stripe, so this does no good. [You] need more of a keycard."

Instead of unlocking the small door with the passcard:

say "It slides through the lock, but since the information it encodes is passport information, not a key code, the door does not open."

Instead of unlocking the small door with the pass:

say "This is the sort of pass that you show to people in order to gain access to places. What [you] need is more of a hard plastic keycard."

[Originally a "large box", but the risk of having it become a large ox was too great -- it would be easy to implement the transformation but hard to make it fair to the player if the box were to move from its appointed position.]

A large carton is a container in Samuel Johnson Basement. It is fixed in place. Understand "recycling" as the large carton. "A large open carton stands against the wall right between Brown's lab door and [if the rectification room is visited]the Rectification Room[otherwise]the interesting door[end if][if the carton-sign is part of the carton]. 'Recycling,' reads the sign over the carton. 'Place your lab-created items here for processing.'[otherwise].[end if]".

The carton-sign is a sign. The carton-sign is part of the carton. The printed name is "sign". Understand "sign" as the carton-sign. The description is "'Recycling. Place your lab-created items here for processing.'"

In the large carton is a banana. The banana is edible. It is a vegetable. The description of the banana is "Just beginning to get brown and spotty."

Instead of going to the Rectification Room when the large carton does not contain something noisy:

let N be the number of entries in the path so far of the player;

if N is greater than 1:

say "[path-walked so far]";

otherwise:

clear the path-walked for the player;

say "[one of]Before [you] go through the door to the Rectification Room, it occurs to us that Professor Brown is just next door, and that he is likely to be able to hear if [you] do anything in there. Possibly some kind of masking noise is in order[or][if the player carries something noisy (called the mask)][The mask] do[es] make noise, but you figure we should leave it out here in the hallway so that it will be louder than whatever we do in the room[otherwise]I defer to your judgment that [you] ought to provide some masking sound before proceeding[end if][stopping].".

Instead of dropping something in Samuel Johnson Basement when the heft of the noun is less than 4:

say "I'll just leave [that-those of noun] in the carton; less likely to be disturbed there.";

try inserting the noun into the large carton;

After dropping something noisy in the large carton:

say "[You] set [the noun] in the carton, where [it-they] ought to provide a helpful distraction for the time being."

Understand "recycle [something]" as recycling. Recycling is an action applying to one carried thing.

Sanity-check recycling a person:

say "[The noun] might not take kindly to that." instead.

Check recycling something when the large carton is not visible:

say "There's no place to recycle [the noun]." instead.

Carry out recycling something:

try inserting the noun into the large carton instead.