Counterfeit Monkey — 148 of 292

Section 4 - Public Convenience

[The public convenience existed from a fairly early stage of the game development, as a place to change your wig or look in the mirror or acquire some soap. The dead-drop puzzle was a late addition to the game, and it came about because I felt that I wanted to make the espionage aspects more convincingly espionage-y. I used this excuse to read a couple of LeCarré novels — research, you see — and then extracted the concepts that I thought would be easiest to transfer into the context of IF.]

The Public Convenience is east of Bus Station. It is indoors. The Public Convenience is a public restroom. The description of Public Convenience is "There are just the two toilet stalls[if at least two sinks are in the location] and a couple of [sink-collectives], but the place has been kept up reasonably well, if one doesn't count the [random graffiti][otherwise if one sink is in the location] and a single [random sink], the other one having been vandalized. The [random graffiti] adds a grim touch[otherwise] though both sinks are gone and there is [random graffiti] on the walls[end if]."

The introduction of the Public Convenience is "A faint smell of lavender lingers in the air."

Some sink-collectives are scenery in the public convenience. The sink-collectives are privately-named. The printed name is "sinks". Understand "sinks" as sink-collectives.

Sanity-check doing something other than examining to the sink-collectives:

if the number of sinks in the location is 0:

say "[You][']ve already gotten rid of all the sinks to be found in this area." instead;

let target be a random sink in the location;

change the noun to the target.

[After going to Public Convenience:

let N be the number of entries in the path so far of the player;

if N is greater than 1:

say "[path-walked so far]";

otherwise:

clear the path-walked for the player;

[if hurrying:

say "[line break]";]

say "I double-take before remembering to go into the women's side; it's a good thing you're nudging me along.";

continue the action.]

A soap is a fluid thing. The indefinite article is "some". The description is "Clear fluid for washing up with."

The scent-description is "herbes de Provence".

Does the player mean waving the letter-remover at the soap:

it is very likely.

The soap dispenser is a closed container in the Public Convenience. It is privately-named. Understand "dispenser" or "soap dispenser" as the soap dispenser. Understand "soap" as the soap dispenser when the soap is not visible. It is fixed in place. The initial appearance of the soap dispenser is "A [soap dispenser] hangs beside the mirror." The description of the soap dispenser is "It's the kind where a squeeze will dispense new soap into the sink[if the soap is not in the soap dispenser]. It is also empty[end if]."

Does the player mean waving the letter-remover at the soap dispenser:

it is very unlikely.

Sanity-check taking the soap when the soap is in the soap dispenser:

try squeezing the soap dispenser instead.

Instead of squeezing the soap dispenser:

if soap is in the dispenser:

if the number of sinks in the location is greater than 0:

let target be a random sink;

if a visible sink contains an open container (called receptor):

now target is the receptor;

otherwise:

now target is a random sink in the location;

say "[You] give the dispenser a squeeze and it deposits some soap in [the target][if the target is a sink] [--] just viscous enough not to drain away instantly[end if].";

move the soap to the target;

otherwise:

say "[You] give the dispenser a squeeze and it deposits some soap on the floor, the sink having been removed from the area.";

move the soap to the location;

otherwise:

say "This time nothing much comes out."

The soap is in the soap dispenser.

The wall-hole is a fixed in place container in the Public Convenience. Understand "hole" or "hole in the wall" or "hole in wall" or "wall" as the wall-hole. The printed name is "[if looking]hole[otherwise]hole in the wall[end if]". "About knee-height in one of the stalls is a [wall-hole] that runs right through the wall between the men's and women's restrooms." The description of the wall-hole is "It's too small to get a good look through, really, and usually cluttered with junk."

Report searching the wall-hole when the ash is in the wall-hole:

say "[one of]At first there doesn't seem to be anything in there, but when we put our finger in, we find it's full of ash[or]The ash is still mounded up in the hole[stopping]." instead.

A description-concealing rule:

if the ash is marked for listing and the ash is in the wall-hole:

now the ash is not marked for listing.

The introduction is "It's here that you and Brock and Slango usually leave things for one another."

The ash is a fluid thing in the wall-hole. The description is "It's fine grey-white powder, and a fair quantity of it: too much to have come from a cigarette or two." The indefinite article is "some".

The scent-description of the ash is "bitter smokiness".

Instead of touching the ash:

say "It leaves white-grey smears on our fingers."

Test ash with "tutorial off / open tub / get ash / smell ash / touch ash / put gel on ash / x card / wave t-remover at trash / wave r-remover at rash / x ash / gel ash / x trash" in the Public Convenience holding the tub.