Counterfeit Monkey — 153 of 292

Chapter 2 - Bureau Basement

Section 1 - Foot of Stairs

Below Bureau Hallway is Bureau Basement South. Bureau Basement South is indoors and forbidden. The description of Bureau Basement South is "[You] have descended into a windowless underground passage. The hallway runs [north] from here, and for an eerily long way [--] the tunnels must extend well beyond the above-ground profile of the building."

Rule for writing a paragraph about the plywood cutout when the seer automaton is mentionable and the location is Bureau Basement South:

say "Propped in the corner are some articles that were probably meant to be used as part of the Serial Comma Day Fair, but got confiscated instead: [a seer automaton] and [a plywood cutout] depicting Atlantida.".

A push-button device is a kind of device.

Sanity-check switching off a push-button device:

say "[The noun] [one of]only runs for a little while at a time, and is already off[or]has already shut down again[at random]." instead.

The seer automaton is a push-button device in Bureau Basement South. Understand "robot head" as the seer automaton. The heft is 3. The description is "It's a robotic head inside a glass box. When turned on, it gives out fortunes. There's an old-fashioned carnival feel about the thing, and the fact that it's a portable size makes it a good candidate for traveling fairs."

Instead of switching on the seer automaton:

say "The seer cranks to life, looks us up and down with painted wooden eyeballs, and in a tinny voice, says, 'I predict [one of]you will become BIG. Much bigger than you were yesterday[or]you will escape.' Asthmatic whirring. 'Possibly on the back of an interstellar whale[or]the Bureau won't last past tomorrow[cycling].'"

The plywood cutout is a fixed in place thing in Bureau Basement South. "A plywood cutout depicting Atlantida is propped in the corner." Understand "painted" or "depicting" or "atlantida" or "hole" or "head" or "funny pose" as the plywood cutout. The heft is 5. The description is "It's one of those plywood cutouts where a tourist sticks his head through and someone else takes a photo showing the tourist a funny pose. This one puts the tourist's face on Atlantida, complete with flowing blue robes and expansive bosom."

Understand "put [something] through [something]" as inserting it into.

Sanity-check inserting something into the plywood cutout:

if the noun is the player:

try poking head through the plywood cutout instead;

say "[The noun] would not balance inside the face cutout." instead.

Understand "put my/our/your head in/into/through [something]" as poking head through.

Understand "put head in/into/through [something]" as poking head through.

Poking head through is an action applying to one thing.

Sanity-check an actor poking head through something which is not the plywood cutout:

if the noun is wearable:

try the actor wearing the noun instead;

otherwise if the noun is a door:

try the actor entering the noun instead;

otherwise:

if the player is the actor:

say "I'm not sure that's feasible.";

stop the action.

Report someone poking head through the plywood cutout:

say "[The actor] look[s] frankly awesome with [its-their] head poking through above the bosom and flowing robes of Atlantida." instead.

Report poking head through the plywood cutout:

say "[You] momentarily enjoy the sensation of being cast as Atlantida, spirit of the island, invincible, implacable, the sum of the devotions and desires of all our people.

It's a giddy feeling. No wonder the Bureau confiscated this thing and wouldn't let it be shown at the fair." instead.

Test BBS with "tutorial off / look / x cutout / put head through cutout / put seer through cutout / turn on seer / turn off seer / cad, put your head through the cutout / kiss cad / cad, put your head through the cutout" holding the cad in Bureau Basement South.

Test automaton with "tutorial off / open tub / x automaton / put automaton in inserter / get it / gel it / put it in inserter" holding the tub and the automaton in the Sensitive Equipment Testing Room.