Counterfeit Monkey — 169 of 292

Emily Short

Release 6

Part 2 - Final Departure

Chapter 1 - The Seaside

The distant-sea-view is a distant backdrop. It is fluid. It is in Customs Hallway, Precarious Perch, Old City Walls, Old Hexagonal Turret, and Crumbling Wall Face. The printed name is "view of the sea". Understand "view of the sea" as the distant-sea-view. It screens north, northwest, and northeast. Understand "ocean" or "sea" or "waves" or "water" or "horizon" as the distant-sea-view. The description is "The water is quiet today [--] though it rarely achieves very impressive waves anyhow. The col[our] ranges from a bright Bureau blue close to shore to a deep lapis at the horizon."

The sea-view is a backdrop. It is fluid. It is in Abandoned Shore, Private Beach, and Open Sea. It screens north, northwest, and northeast. The printed name is "sea". Understand "view of the sea" as the sea-view. Understand "ocean" or "sea" or "waves" or "water" or "horizon" as the sea-view. The description is "[if the location is Open Sea]The seawater is pleasantly clear here: there's little turbulence to stir up muck, little seaweed.[otherwise if the location is nautical]The surface of the water glitters in the last light.[otherwise]The waves are low and gentle, little more than a wash of foam over the surface of the beach, like an emptied dishpan.[end if]".

Instead of listening to the sea-view:

say "There's a gentle lapping of waves."

Instead of listening to a room in the presence of the sea-view:

try listening to the sea-view.

Instead of washing something in the presence of the sea-view:

say "Washing things in ocean water tends to leave them a bit gritty afterward, or even stained with rings of dried salt."

Instead of tasting or drinking or eating the sea-view:

say "Seawater makes you sick, or didn't you know?"

Instead of smelling the sea-view:

say "It smells faintly sea-weedy."

Instead of rubbing the sea-view:

try touching the sea-view.

Report touching the sea-view:

say "[You] dip our hand in the water and shake it dry. ";

if the current daytime is:

-- noon:

say "The water is a little brisk: this morning was cooler." instead;

-- early afternoon:

say "The water is still cool, but not cold." instead;

-- mid afternoon:

say "The water is only a little cooler than the surrounding air." instead;

-- late afternoon:

say "The sea has taken a lot of sun over the course of the day, and is surprisingly warm." instead;

-- sunset:

say "The water is still warm with the retained heat of a very sunny day." instead;

-- evening:

say "The water retains the heat of a very sunny day, though the air is cooling quickly." instead;

Precarious Perch is a room. It is forbidden. "From up here there's a handsome [distant-sea-view], which isn't [i]so[/i] far down [i]really[/i]. But it's a scramble down a nearly sheer cliff for the first bit, until [you] make it down to the rockfall below, and it would be easy for a careless person to injure herself."

Rule for listing exits while looking in Precarious Perch:

do nothing instead.

Instead of jumping in Precarious Perch:

say "You give a sudden, mad spring before I can clamp down on the impulse, and then [you] [are] in mid-air and I can see the boulders below and time seems to be going very slowly

until it isn't.";

end the game saying "[You] wake up four days later in hospital with one leg paralyzed".

Rule for distantly describing Abandoned Shore when the location is Precarious Perch:

say "[one of]If [you] lean out over the cliff, [you] can see that there is a way down, awkward but navigable, to a small bit of sheltered shore below[if the kayak is in abandoned shore]. There even appears to be a kayak down there, though [you] can't get a good look for very long without the vertigo kicking in. So I pull back from that position. Still, it doesn't look hopeless[end if][or][You] lean out again and get another glimpse of sand and rocks[if the kayak is in abandoned shore] and kayak[end if][stopping]." instead.

After going down from Precarious Perch:

let N be the number of entries in the path so far of the player;

if N is greater than 1:

say "[path-walked so far]";

otherwise:

clear the path-walked for the player;

say "It's a nasty business lowering ourselves over the edge, with little to hold onto up here; scrabbling around with our toes for good holds; letting go with one hand to descend a little further...

But after some minutes of this painstaking process the cliff begins to slope outward more, and it's no longer a question of climbing down a face, but rather of scrambling down over boulders. And then... [command clarification break]";

continue the action.

Instead of going up in Abandoned Shore:

say "[You] doubt whether [you] would make the return trip. It was bad enough coming down."

Instead of going north in Abandoned Shore when the player is not in the kayak:

say "[You] have too far to go; just swimming won't get us out to Slango's yacht."

Abandoned Shore is below Precarious Perch. It is forbidden. "There's a little inlet of shore here, mostly boulders with little sand, completely cut off from the dock area and sheltered by the curve of the rock so that it wouldn't be visible from the sea unless someone were very close in."

Some boulders are scenery in Abandoned Shore. Understand "crack" or "rocks" or "boulder" as the boulders. The description is "Rough black rock, the kind that tears up your hands if you try to hold onto it too tightly."

Some tidal pools are scenery in Abandoned Shore. The description is "Pools of seawater no more than a foot or two deep, temporarily cut off from the rest of the ocean."

Instead of climbing the boulders:

say "While it might be possible to scramble up over the curve of rock and get a glimpse of the harbor, there's an equally good possibility that doing so would get [me] undesirable attention."

The non-sand is scenery in Abandoned Shore. The non-sand is privately-named. Understand "sand" as the non-sand.

Sanity-check doing something when the noun is non-sand or the second noun is non-sand:

say "There's very little sand here, just boulders."

[Carry out examining the boulders when the squid is not seen:

move the squid to the location;

Report examining the boulders when the squid is not seen:

say "[A squid] has died and washed ashore in a crack of the boulders."]

[Originally, the squid here was dead and just a body washed ashore -- long before the squid became prevalent imagery in the rest of the game. But once that imagery was in place, it seemed kind of weird and depressing to have a dead squid there, so this was replaced with a different description.]

A squid is an animal on the boulders. "There is a [squid] in the tidal pools among [the boulders]." The description of a squid is "A squid, washed into a tidal pool, but not damaged. When the tide comes back in, it will be free to go."

Sanity-check saying hello to the squid:

say "[one of]One tentacle waves back. It is probably a coincidence[or]I'm not even sure squid can hear. At any rate there is no response[stopping]." instead.

Instead of taking the squid:

say "When [you] reach into the pool for it, it hangs onto the underlying rocks with all its strength and cannot be extracted."

Instead of smelling the squid:

say "As it's underwater, any natural scent the squid may exude is trapped and does not reach our nostrils."

Instead of tasting or eating the squid:

say "It's still alive. And while we're on the topic, raw squid meat is chewy, slippery white stuff, and doesn't agree with me."

Instead of touching the squid:

say "Its flesh is rubbery. It wraps one tentacle around our finger."

Rule for listing exits when looking in Abandoned Shore:

do nothing instead.

The bollard is a fixed in place thing in Abandoned Shore. "A [bollard] is bolted to one of the rocks, which is curious considering the otherwise unused and inaccessible look of the spot." Understand "bolt" or "bolted" as the bollard.

The description is "A metal pole, painted all-weather green and bolted to a rock. Its ilk are used in more trafficked places for securing boats and so on; and indeed so is this one, despite the implausible setting."

The heft of the bollard is 5.

The kayak is a vehicle in Abandoned Shore. "An old but still serviceable [kayak] is drawn up[if the bollard is in the location and the shackles are part of the kayak] and firmly shackled to the bollard[otherwise] here[end if]."

The description of the kayak is "A green plastic boat, designed to be used by one person with a paddle or oar. [if the bollard is in the location and the shackles are part of the kayak]It's seaworthy, at least for reasonable distances, and shackled to the bollard for safety[otherwise]It looks seaworthy and ready to use[end if]."

Some shackles are part of the kayak. Understand "shackle" as the shackles. The description is "They're firmly attached and locked with a rusty lock that doesn't look inclined to open again any time this century. I really do compliment you folks['] approach to security."

Instead of going somewhere by kayak when the location is Abandoned Shore:

try launching the kayak instead.

Understand "row [something]" as launching. Understand "launch [something]" as launching. Launching is an action applying to one thing.

Does the player mean launching the kayak:

it is very likely.

Check launching:

if the noun is not the kayak:

say "[The noun] [is-are]n't susceptible to being launched." instead.

Check launching:

if the shackles are part of the kayak and the bollard is visible:

say "It's hard to launch the kayak while it's still shackled to the bollard." instead.

Check launching:

if the player is not in the kayak:

if the player can see the kayak:

try entering the kayak;

if the player is in the kayak:

make no decision;

say "That might work better from inside the kayak." instead.

Check launching:

if the player does not carry the oar:

if the player can see the oar:

try taking the oar;

if the player carries the oar:

make no decision;

say "It would be helpful to have something to paddle with." instead.

[Check launching:

if the player carries anything which is not the oar:

say "Our hands are too full for rowing. [run paragraph on]";

let worn-list be a list of things;

let dropped-list be a list of things;

repeat with item running through things carried by the player:

if the item is not the oar:

if the item is wearable:

silently try wearing the item;

if the player wears the item:

add the item to the worn-list;

otherwise:

silently try dropping the item;

if the player does not carry the item:

add the item to the dropped-list;

if the player carries anything which is not the oar:

stop the action;

otherwise:

if the number of entries in the dropped-list is not 0 and the number of entries in the worn-list is not 0:

say "[You] put down [dropped-list with definite articles] and don [worn-list with definite articles].";

otherwise if the number of entries in the dropped-list is not 0:

say "[You] put down [dropped-list with definite articles].";

otherwise if the number of entries in the worn-list is not 0:

say "[You] put down [worn-list with definite articles].";]

Carry out launching the kayak:

move the kayak to the Open Sea.

Report launching the kayak:

say "With some awkwardness, [you] manage to push off and begin to lab[our]iously row for open sea.";

try looking.

Report facing in Abandoned Shore:

say "The charm of this place is that it's very hard to see anything in any direction but the ocean. In every other direction [you] are completely protected by rocks." instead.

Open Sea is north of the Abandoned Shore. It is forbidden. "The water stretches in all directions, but [you] can see off to the north where [viewed-yacht] is anchored, ready to bring us back aboard. Its metallic blue shape almost blends in with the water."

The introduction is "If [you] were further around the island to the east, [you] might be able to see bits of the drowned city: both the buildings that were legitimately destroyed when the land sunk into the sea, and the areas where during the Civil Dispute of Standard[ization] the authorities dumped unwanted foreign archaeological [if the player is wearing britishizing goggles]artefact[otherwise]artifact[end if]s. But here I'm afraid it's just shellfish and sand down there."

Rule for listing exits when looking in the Open Sea:

do nothing instead.

A description-concealing rule:

if the location is the Open Sea:

repeat with item running through things enclosed by the kayak:

now the item is not marked for listing.

The viewed-yacht is a distant, privately-named scenery thing in Open Sea. Understand "slango's" or "yacht" as the viewed-yacht. The description is "It's just there on the horizon." The printed name is "Slango's yacht".

Instead of finding viewed-yacht:

try going north.

Instead of going a direction which is not north when the location is Open Sea:

say "[You][']ve got safety in sight, just to the north. Don't go all sea-crazed on me now."

Instead of launching the kayak in Open Sea:

try going north instead.

Instead of exiting in Open Sea:

say "Leaving the kayak at this juncture would only get us all wet. And I'm too tired for that right now."

Instead of putting gel on the oar when the player is in the kayak:

say "It would be extremely inconvenient to lose the oar at this juncture."

Understand "drift" as waiting when the location is Open sea.

Instead of waiting when the player is in Open Sea:

say "Rest for a moment if you insist, but the currents can be odd here; it would be better to make for the yacht and rest after [you] get there."

Beside Slango's Ship is north of Open Sea.

Instead of facing north in Open Sea:

say "Slango's yacht is visible not too far off to the north. [You] can certainly make it."

Report facing in open sea:

say "There is mostly ocean everywhere." instead.

After going to Beside Slango's Ship:

let N be the number of entries in the path so far of the player;

if N is greater than 1:

say "[path-walked so far]";

otherwise:

clear the path-walked for the player;

say "[You] come around to the aft of Slango's yacht and give a good shout. With the help of a ladder and a hand up from Slango himself, [you] soon have the kayak stored, and ourselves and our possessions on deck.[if N is greater than 1][paragraph break][end if]";

now every other thing in the kayak is carried by the player;

now the posture of the player is standing;

remove the oar from play;

set the current interlocutor to Slango;

[queue where-is-Brock as immediate obligatory;]

move the player to Sunning Deck, without printing a room description;

follow the compass-drawing rule instead;