Counterfeit Monkey — 216 of 292

Emily Short

Release 6

Chapter 12 - Britishizing Goggles

[Originally included as a joke, and a harmless one, because it was going to be in the tools exhibit and the player was never going to be able to get in there. Later, though, when I made the tool exhibit possible to break into, it became necessary to go back and implement cosmetic changes throughout the text. And then it felt like the player was getting the goggles too late in the game for them to be really fun as a toy, so I moved them much earlier, to the antiques shop.

Let this be a lesson to you, children. Jokes can cost a lot of implementation time.]

Some Britishizing goggles are a wearable thing. The description is "An experimental prototype that (from the perspective of the viewer only) adds -u- into words ending in -or, and reverses -er into -re wherever possible. Subjects wearing the [Britishizing Goggles] generally began to develop implausible accents and to have better than usual success wooing American tourists. Otherwise, the goggles are not much use: like my monocle, they don't affect the actual form of an object in any way.

The surplus stock were mostly given away as rewards to supporters of public television, and the Bureau discouraged even recreational use in the 1980s as they began to make progress towards greater linguistic purity."

[Check wearing the Britishizing goggles while the player is wearing the monocle:

try taking off the monocle;

if the player is wearing the monocle:

say "[You] can't fit the goggles over the monocle." instead.

Check wearing the monocle while the player is wearing the Britishizing goggles:

try taking off the Britishizing goggles;

if the player is wearing the Britishizing goggles:

say "[You] can't fit the monocle over the goggles." instead. ]

Rule for printing the name of the odor when the player is wearing the Britishizing goggles:

say "odour".

Rule for printing the name of the Britishizing goggles when the player is wearing the Britishizing goggles:

say "Britishising goggles".

Rule for printing the name of the synthesizer when the player is wearing the Britishizing goggles:

say "synthesiser"

To say ize:

if the player is wearing the Britishizing goggles:

say "ise";

otherwise:

say "ize"

To say izing:

if the player is wearing the Britishizing goggles:

say "ising";

otherwise:

say "izing"

To say ization:

if the player is wearing the Britishizing goggles:

say "isation";

otherwise:

say "ization"

To say IZE:

if the player is wearing the Britishizing goggles:

say "ISE";

otherwise:

say "IZE"

To say IZING:

if the player is wearing the Britishizing goggles:

say "ISING";

otherwise:

say "IZING"

To say ae:

if the player is wearing the Britishizing goggles:

say "ae";

otherwise:

say "e".

To say our:

if the player is wearing the Britishizing goggles:

say "our";

otherwise:

say "or".

To say ter:

if the player is wearing the Britishizing goggles:

say "tre";

otherwise:

say "ter".

To say er:

if the player is wearing the Britishizing goggles:

say "re";

otherwise:

say "er".

To say ense:

if the player is wearing the Britishizing goggles:

say "ence";

otherwise:

say "ense".

To say gram:

if the player is wearing the Britishizing goggles:

say "gramme";

otherwise:

say "gram".

To say Mr:

if the player is wearing the Britishizing goggles:

say "Mr";

otherwise:

say "Mr.[no line break]".

To say Mrs:

if the player is wearing the Britishizing goggles:

say "Mrs";

otherwise:

say "Mrs.[no line break]".