Counterfeit Monkey — 231 of 292

Section 6 - F through H

A fame is a thing. The indefinite article is "some". It is r-abstract. The description is "It looks like an enormous star in twinkle lights." [The player in fact should never be able to make this, because the farmer and stall should clear out by the time the player has r-abstract abilities.]

The initial appearance of the filing cabinet is "A filing cabinet stands in the corner." Understand "files" or "file" as the filing cabinet. The heft of the filing cabinet is 8. The description of the filing cabinet is "There are numerous files, and they are organized chronologically, so that it's possible to look up a specific year. They appear to begin in 1942."

Instead of opening or searching the filing cabinet:

try examining the filing cabinet.

Instead of consulting the filing cabinet about a topic listed in the Table of Filed Paintings:

say "[one of]Checking through the filing cabinet for [topic understood] reveals some images of Atlantida. [or][stopping][description entry]."

Instead of consulting the filing cabinet about a topic:

if the topic understood matches "[number]":

if the number understood is less than 1942:

say "No files appear earlier than 1942." instead;

if the number understood is greater than 2003:

say "There are no significant contents past 2003." instead;

let prev be 1942;

let promising list be { 1942, 1982, 1983, 2003 };

repeat through the Table of Filed Paintings:

if the number understood is greater than the num entry:

let prev be the num entry;

otherwise:

say "There's nothing much for [the number understood], but there are files for [prev] and [num entry]. ";

remove prev from promising list, if present;

remove num entry from promising list, if present;

say "Other promising-looking years are [promising list]." instead;

otherwise:

say "The files seem to correspond to years. Flipping through the year folders at random shows that some years were much more interesting than others. The folders for 1942, 1982, and 1983 are especially thick. 2003 has a number of memos as well."

Table of Filed Paintings

The flint crepe cap is a wearable thing. It covers the head-area. The description is "It's a stiff cap made of layers of grey, rock-toned crepe, much crinkled. It's hard to imagine any self-respecting hatter constructing such a confection, but an anagramming gun is a powerful thing.

There is [--] really there is the faintest suspicion that it's trying to spell itself 'crêpe'. Must be the foreign ingredients."

A foal is an animal. The description of the foal is "It has a brown coat, large nervous eyes, and wobbly legs that don't seem to want to hold it up." The scent-description of the foal is "newborn animal".

The metal-foil is a privately-named thing. The description is "A crumpled ball of that aluminum foil used for cooking." The heft is 1. The printed name of the metal-foil is "foil". Understand "ball" or "foil" or "aluminum" as the metal-foil. The indefinite article is "some".

A foil is a thing. The description is "One of those long springy swords used for fencing. It has a button at the tip to prevent harm to one's opponent." The foil is long. Understand "long" or "springy" as the foil. Understand "sword" as the foil when the sword is not visible.

The button is a part of the foil. The description is "A tiny cylindrical cap of red rubber." Understand "tip" or "rubber" or "red rubber" or "cap" or "cylindrical" as the button.

Instead of taking the button:

say "It's not made to come off easily: this isn't a sword for actually hurting people."

Instead of waving the foil in Walltop:

say "[You] slash through the empty air, defending the city from imaginary attackers."

Instead of waving the foil in Open-Air:

say "I would, but with the crowds around here [you][']d put someone's eye out."

Instead of waving the foil:

say "[You] feign a few attacks against no one."

Understand "use [foil]" as waving.

Understand "fight with [foil]" or "fence with [foil]" as waving.

Understand "fence" as fencing. Fencing is an action applying to nothing.

Check fencing:

if the player does not carry the foil:

say "There's an odd idea." instead.

Carry out fencing:

try waving the foil instead.

The description of the flea is "It is speck-sized. But alive, I think. An unappealing thought."

Every turn when the flea is visible:

remove the flea from play;

say "The flea jumps away. In search of a hospitable dog or cat, no doubt."

The description of the frozen dinner is "It's microwavable three-cheese lasagna."

A fuel is a contained fluid thing. The indefinite article is "some". The description is "It looks like a generic canister of unleaded gasoline." The scent-description is "volatile fumes". Understand "canister" or "unleaded" or "generic" or "canister of" as the fuel. Understand "gas" or "gasoline" or "petrol" as the fuel when the gas is not visible.

The funded-tomcat is a cat. The printed name is "funded tomcat". Understand "funded" or "funded tomcat" as the funded-tomcat. Understand "tomcat" as the funded-tomcat when the tomcat is not visible.

The description is "Like an ordinary tomcat, but very sleek and well-fed, with a diamond-studded collar."

Sanity-check wearing the diamond-studded collar:

say "It wouldn't fit."

The funded-tomcat wears a diamond-studded collar. The description of the diamond-studded collar is "It would be worth a good bit, if it weren't for being fake. [if the player wears the Britishizing goggles]Jewellers[otherwise]Jewelers[end if] do tend to check."

Instead of taking the diamond-studded collar:

say "[The funded-tomcat] hisses ferociously when [you] come near."

The description of the gam is "It's a woman's leg, encased in a black silk stocking with a seam up the back." The scent-description is "sultry perfume". Understand "leg" or "stocking" or "silk" or "black" or "seam" as the gam.

The garage is an enterable container. The heft of the garage is 8. The initial appearance of the garage is "A garage has sprung into being between two high-end boutiques." It is fixed in place. The description is "It is a small but well-furnished garage for minor tuneups and repairs[if the mechanic is in the garage]. It even comes with a mechanic: a surprising touch, since letter-removers are usually legally prevented from creating living persons, but sometimes there are glitches if the people are not created directly[end if][if every car is unseen]. Alas, however, it doesn't come with a car in residence[end if].".

Instead of entering the garage:

say "There's just room enough for the mechanic and his possessions. It's something of a garage/shack."

A ranking rule for the garage: increase the description-rank of the garage by 80.

The garage contains a fake alert man called a mechanic. The description of the mechanic is "I'm a little surprised that you were able to generate this guy, but he seems to have come as part of the implementation of the garage."

A gas is a contained fluid thing. The indefinite article is "some". The description is "It looks like a generic canister of unleaded gasoline." The scent-description is "volatile fumes". Understand "canister" or "unleaded" or "generic" or "canister of" as the gas. Understand "fuel" as the gas when the fuel is not visible.

The geas is an r-abstract thing. The description is "It is an enchantment of some sort. It is pictured as a balled-up net of dark strands, ready to capture and bind some victim to the caster's will."

The scent-description is "smoke and cured leather".

The description of the gem is "It's a [one of]bubble-gum pink[or]London blue[or]Swiss blue[or]yellow[sticky random] topaz, all faceted and ready to be set. Not a particularly high-end article, but you weren't concentrating too hard, and the materials weren't so great to start with." Understand "topaz" or "pink" or "bubble-gum" or "gum" as the gem.

Understand "set [gem]" or "facet [gem]" as a mistake ("I don't have any training in the jeweler's arts.").

The giant-pin is wearable. The description of the giant-pin is "An outsized plastic brooch, suitable only for circus performers and halloween costume-wearers. It features a giant letter A." The printed name of the giant-pin is "giant pin". Understand "giant" or "giant pin" as the giant-pin. Understand "pin" as the giant-pin when the pin is not visible.

The giant-pint is a container. The printed name is "giant pint". Understand "giant pint" or "giant" as the giant-pint. Understand "pint" as the giant-pint when the pint is not visible. The description of the giant-pint is "There might seem to be some inherent contradiction about having a giant version of some standard measure: might as well say 'a very long inch' or 'an extra-heavy pound'. Nonetheless, popular imagination apparently construes GIANT PINT to mean an outsized beer stein. Beer not included."

The gin is an edible contained fluid thing. The scent-description of the gin is "herbs and juniper". The description of the gin is "Though clear and inert, it gives off a dangerously heady whiff of alcohol." The indefinite article of the gin is "some".

The gin-crock is an openable closed container. The description is "It's a sturdy jug with a stopper, suitable for containing the results of home distillery." The printed name of the gin-crock is "gin crock". Understand "gin crock" or "crock" as the gin-crock. Understand "gin" as the gin-crock when the gin is not visible. The heft of the gin-crock is 2.

The scent-description is "alcohol".

The description of the god is "A small, heavy metal figurine representing some pagan deity. He carries a bow and quiver, and looks prepared to use them." Understand "metal" or "small" or "heavy" or "figurine" or "bow" as the god. The heft of the god is 2.

The description of the hackle is "A long feather, as from the neck of a giant bird." Understand "feather" or "quill" as hackle.

A strand is privately-named. The description of a strand is "A single strand, about a foot long, of blonde hair." The heft of a strand is 1. The printed name of a strand is "hair". Understand "strand of" or "strand" or "hair" as a strand.

Rule for printing the plural name of a strand:

say "hairs".

[Again, there is no gameplay reason whatever for the procedural element here, but it feels more in keeping with the rest of the game to have it this way than to use a static list.]

The genre apron is a wearable thing. The description of the genre apron is "It is an ordinary apron, but lists across the front [i][genre-list][/i] and so on."

To say genre-list:

sort the table of genres in random order;

repeat with index running from 1 to 8:

if index is less than 5:

choose row index in the table of genres;

say "[noun entry] - ";

otherwise if index is less than 7:

let offset be a random number between 3 and index;

decrease offset by 1;

let old-index be index minus offset;

choose row old-index in the table of genres;

say "[one of][soft-adjective entry][or][adjective entry][at random] ";

choose row index in the table of genres;

say "[noun entry] - ";

otherwise:

let offset be a random number between 3 and index;

decrease offset by 1;

let old-index be index minus offset;

choose row old-index in the table of genres;

say "[soft-adjective entry] ";

increase old-index by 1;

choose row old-index in the table of genres;

say "[adjective entry] ";

choose row index in the table of genres;

say "[noun entry] - ";

Table of Genres

Test genres with "tutorial off / x apron / g / g / g / g / g" holding the genre apron.

[and since we're making this anyway, we might as well add the capacity to reference genres elsewhere...]

To say one-genre:

if a random chance of 1 in 3 succeeds:

choose a random row in the table of genres;

say "[soft-adjective entry] ";

if a random chance of 1 in 2 succeeds:

choose a random row in the table of genres;

say "[adjective entry] ";

choose a random row in the table of genres;

say "[noun entry]";

The gilet is floppy and wearable. It covers the torso-area. The description is "A sleeveless padded jacket made of some sort of shiny army green nylon. Not my preferred look, to be honest." The heft of the gilet is 3.

The description of the gilt is "It's a single very thin sheet of beaten gold, which seems to want to stick to everything it touches. Best be careful with it." The heft of the gilt is 0. The indefinite article is "some".

A gimlet-drink is a contained fluid edible thing. The printed name of a gimlet-drink is "Gimlet". Understand "gimlet" or "cocktail" or "drink" or "beverage" as a gimlet-drink. The description of a gimlet-drink is "Lime juice, gin, and simple syrup: it's limeade with a difference."

The description of a git is usually "His face is fixed in a permanent sneer."

The greeting of a git is usually "'[one of]Oh, you is it?[or]You again?[or]Still with the face like a barn door, you,[or]Haven't you got someone else to annoy?[at random]' says the git unpleasantly."

The grin is r-abstract. The description of the grin is "It hangs, smiling, in mid-air, with none of the Cheshire Cat to go with it."

The description of the grit is "It's a small quantity of fine sand, the kind that might be used for grinding or polishing things." The indefinite article of the grit is "some".

The hairband is wearable. It covers the head-area. The description is "It's blue, with felt flowers and rhinestones. I think it may be meant for a younger wearer than ourself."

The hairpiece is wearable. It covers the head-area. The description is "A fairly natural-looking extension the col[our] of our own hair, attachable by comb. It [if worn]comes[otherwise]should come[end if] to about shoulder length on us."

Sanity-check cutting the hairpiece:

say "It's reasonably well-trimmed as it stands. I wouldn't trust myself to re-style it." instead.

The harp limit is an r-abstract thing. The heft is 0. The description of the harp limit is "In its presence, no more than two pedal harps can be played (or a single double chromatic harp)."

The hat is wearable. The description of the hat is "It's a top hat, but one that doesn't take itself quite seriously; the sort of hat used to conceal rabbits in magic shows."

The scent-description of the hat is "damp felt".

Every hat covers the head-area.

The description of the hatband is "Grosgrain ribbon, dark purple, with a purple and silver rosette pinned to one side. It looks like it belongs to someone from a barbershop quartet." The scent-description of the hatband is "pomade".

Sanity-check wearing the hatband:

say "Setting aside the question of a suitable hat on which to wear it, this article is not exactly what one wears when trying to be inconspicuous." instead.

The initial appearance of a hart is usually "A hart stands a few feet from you, looking at you intently. There is nowhere in the room to hide, though I suspect both you and the creature would be grateful to get away, just at the moment." The description of a hart is usually "It's rather frightening, since it plainly isn't tame, but it doesn't seem to have any immediate intent to rush at us."

The hairstick is a wearable thing. It covers the head-area. The heft is 1. The description is "Formally indistinguishable from a chopstick, but intended to hold buns together and otherwise do exciting things with long hair. This would work better if we had two of them.

This particular hairstick is stamped at the end with a tiny but ornate DCL sigil, which puzzles me for quite a while until I recollect that DCL used to (and for all I know still does) have a very active trade partner in Hong Kong."

[Check wearing the wig when the player is wearing the hairstick:

try taking off the hairstick;

if the player is wearing the hairstick:

stop the action. ]

The heel is a thing. The description is "Calloused and leathery, a gruesome souvenir of years of unhappy shoe-wearing."

Sanity-check digging in heel:

say "Oh, I think we can both be stubborn when we have to." instead.

The herds are an animal. The heft of the herds is 10. The description of the herds is "Cows, goats, and sheep, all mingled together and furious to be thus manifested without a shepherd."

Every turn when the herds are in the location:

say "Something spooks the herds [--] not surprising, as there is scarcely enough room here for them to move. The cows try to go one direction, the goats another, and we are dragged underhoof.";

end the story saying "That was unwise".

The ho is a woman. The description of the ho is "She looks to be in her mid-twenties and is wearing a tight, neon blue outfit that makes her look like a naked water nymph."

The hod is long and strong. The description of the hod is "It's a three-sided box on a stick, for carrying bricks and mortar. It looks grubby and not especially convenient, but manual lab[our] isn't my area of expertise."

The description of the hoe is "It's a common gardening implement, perhaps a little larger than usual."

The description of the hooting owl concealer is "A cunningly made blanket designed to fit snugly over an owl, camouflaging it and silencing its calls. The outside of the blanket is painted with a pattern of pine branches, and the inside is quilted with a thick, sound-muffling insulation."

The scent-description of the hooting owl concealer is "pine forests and snow".

The hopping bag is an openable closed transparent container. The description is "A small bag made of fine mesh, used for dry hopping as part of the brewing process." The carrying capacity of the hopping bag is 2.

Check inserting something into the hopping bag when the heft of the noun is greater than 1:

say "[The noun] won't fit into such a small bag." instead.

The description of the hoses is "There are at least a half-dozen of them, spraying water in every direction as though the concept of conservation had never been invented."

Test hoses with "wave r-remover at fountain / wave r-remover at horses / get hoses / wave r-remover at horses / get hoses / x fountain / wave s-remover at hoses / x hoe / get hoe / x fountain / wave e-remover at hoe / x fountain / autoupgrade / wave e-remover at hoe / x fountain / get ho" in the Park Center.

Some hot-pink-clan are a woman. The heft is 7. The printed name is "hot pink clan". Understand "hot" or "pink" or "clan" as the hot-pink-clan. The description is "A huddle of nearly-identical anime girls with hot pink hair. They are watching us with large eyes."

The greeting of the hot-pink-clan is "'Hello!' 'Hi!' 'Greetings!' The clan choruses and giggles, and we can't pick who is who."

The hurt is r-abstract. The heft of the hurt is 0. The description of the hurt is "It's an abstract depiction of hurt, currently represented by [one of]a bruise[or]a broken collar bone[or]a splinted finger[or]a torn ligament[at random]."