Counterfeit Monkey — 244 of 292

Volume 6 - Animal Actions and Human Conversation

Book 1 - Some Rules of Animal Behavior

Section 1 - Lifting Animals

Instead of taking an animal when the heft of the noun is less than 4:

if the player carries the noun:

say "[You][']ve already got [the noun].";

otherwise:

say "[You] scoop [the noun] into our arms.";

now the player carries the noun.

[Every turn:

now the score is the number of useful things enclosed by the player;

if the score is 3, end the game saying "You are now ready for the next episode!"]

Every turn:

repeat with burden running through contained people:

if the burden is the pirate:

next;

if the burden is the pirate-crew:

next;

if the burden is the crew-group:

next;

if the burden is not the player and the burden is not Brock and the burden is not the mechanic and the burden is fake:

try the burden exiting;

Definition: a person is contained:

if it is in a container which is not the repository:

yes;

if it is on a supporter which is not in the repository:

yes;

no.

Check an animal exiting when the person asked is in the kayak:

say "[one of][The person asked] make[s] as though to climb out of the kayak, then see[s] that everything outside is made of water, and withdraw[s] sulkily.[or][The person asked] waits in the bottom of the kayak.[stopping]" instead.

Check an animal exiting when the person asked is in the synthesizer:

if the person asked is a bird:

say "[The person asked] make[s] some attempts to flutter out of [the synthesizer], but do[es]n't get much lift and give[s] up for the moment." instead;

otherwise:

say "[The person asked] scrabbles at the smooth sides of [the synthesizer], but can't get out." instead.

Report an animal exiting when the container exited from is the t-inserter:

say "[The person asked] clamber[s] out of [the t-inserter]." instead.

Report a bird exiting when the container exited from is the t-inserter:

say "[The person asked] hop[s] and flutter[s] out of [the t-inserter]." instead.

Test kayakcat with "autoupgrade / wave s-remover at shackle / wave l-remover at bollard / wave d-remover at board / wave b-remover at boar / get oar / get in kayak / launch kayak / z" holding the tomcat in the Abandoned Shore.