Counterfeit Monkey — 245 of 292

Section 2 - Animal Following

[Carry out entering the line:

change pursuing-state to true;

[repeat with traveler running through animals in the location:

try the traveler entering the noun;]

repeat with traveler running through fake people in the location:

try the traveler entering the noun;

change pursuing-state to false.]

Carry out entering a vehicle:

change pursuing-state to true;

repeat with traveler running through fake people in the location:

try the traveler entering the noun;

change pursuing-state to false.

Check a fake person entering a vehicle when the heft of the person asked is greater than 3:

stop the action.

Check a fake person going from a road to a road when the protesters are not off-stage:

stop the action.

Unsuccessful attempt by a fake person entering the car:

say "[The person asked] makes an effort to get in, but does not remotely fit." instead.

Rule for writing a paragraph about a fake person which is in a car (called target):

say "Sitting in [the target] [is-are the list of fake people in the target][if the number of fake people in the target is greater than 1], like players in a Marx Brothers movie[end if]. [paragraph break]"

Carry out exiting:

change pursuing-state to true;

repeat with traveler running through fake people in the container exited from:

try the traveler exiting;

change pursuing-state to false.

Carry out going:

change pursuing-state to true;

repeat with traveler running through fake people in the room gone from:

try the traveler going the noun;

change pursuing-state to false.

After a fake person going, exiting, or entering when pursuing-state is true:

if the person asked is a cat:

add cat-sample to the incoming-list;

otherwise:

add the person asked to the incoming-list, if absent.

Pursuing-state is a truth state that varies. Pursuing-state is false.

The incoming-list is a list of objects that varies.

After going or entering or exiting when the player is staid:

report followers;

continue the action.

To report followers:

if the number of entries in the incoming-list is not 0:

let N be indexed text;

let N be "[The incoming-list with definite articles]";

say "[N in sentence case] ";

say "[one of]trail[or]come[or]follow[or]walk[at random][if the number of entries in incoming-list is 1]s[end if] after us";

sort the incoming-list;

repeat through the Table of Animal Sets:

let group be the grouping entry;

sort group;

if group is the incoming-list:

say "[epithet entry]";

say ".";

truncate the incoming-list to 0 entries;

continue the action.

After describing path of the player:

report followers.

The cat-sample is a cat. The printed name is "cat". Understand "cat" as a cat.

Table of Animal Sets

[ {pet, cat-sample} "[one of]: the cat looks as though it would like to make short work of the pet, but the pet is cunning and keeps close to our leg[or], the pet still carefully dodging being alone with the cat[or]: the pet because it doesn't want to be alone with the cat, the cat because it would like to catch up with the pet[or] again[stopping]" ]

Understand "pet [something]" as touching.

Instead of touching or rubbing or squeezing an animal:

say "[You] gingerly pet [the noun]."

Instead of touching the pet:

say "It arches its back into your touch and gives a soft, contented trill. The fur really is as soft as it appears."

Sanity-check attacking an animal:

say "[You] may be in serious trouble, but you're not the kind of person who would take it out on dumb animals. At least [--] yes, that's a relief. You're not the sort." instead.

Sanity-check saying hello to an animal:

say "[The noun] [one of]blink[s][or]regard[s] us mutely[at random]." instead.

Sanity-check saying hello to an insect:

say "Our greeting has no visible effect whatever on [the noun]." instead.

Sanity-check saying goodbye to an animal:

say "[The noun] [one of]regard[s] us mutely[or][is-are] completely indifferent[at random]." instead.

Sanity-check saying goodbye to an insect:

say "Predictably, [the noun] do[es] not react." instead.