Counterfeit Monkey — 246 of 292

Book 2 - Person Behavior

Part 1 - Universal Groundwork

Section 1 - Asking Directions

To say holiday closures:

if the current interlocutor does not know things-close-today:

casually queue closure-excuse;

let X be a random number between 1 and 10;

if X is:

-- 1: say "'Nothing that's definitely open today.'[no line break]";

-- 2: say "'None that are open for public use right now.'[no line break]";

-- 3: say "There might be one or two places if they're really popular, but I couldn't promise anything.'[no line break]";

-- otherwise:

say "'[awkward no]. ";

say "[one of]A lot of[or]Most[or]Many[or]Lots of[at random]";

say "[one of] things[or] places[at random] ";

say "[one of]are closed[or]are shut[or]are shut down[or]are closed up[or]aren't open[or]let the employees go home[as decreasingly likely outcomes]";

say ".'[no line break]";

closure-excuse is a q-transitional NPC-directed quip.

The response is "[things-close-today][beat] [one of]'You can't find an open gas station in this town on Serial Comma Day.'[or]'People take Serial Comma Day seriously[apologetic].'[or][one of]'It's the holiday.'[or]'Serial Comma Day is a big thing around here.'[or]'It'll be worse than a Sunday today.'[or]'Any other day of the year you'd have more luck.'[cycling][stopping][line break]".

[Questions about subjects]

To say directions to (destination - a room):

say "'";

if a random chance of 1 in 3 succeeds:

say "[personal yes]. ";

say "[one of]Perhaps you should try [or]You might want [or]I'd go over to [or]Try [or]The best chance would be [at random]";

say "[the destination]";

let distance be the number of moves from the location to the destination;

let the way be the best route from the location to the destination;

if distance is:

-- 1:

say ". That's just [way] from here[run paragraph on]";

-- otherwise:

if distance is less than 5:

say ". It's not far; you'd head [way] to start[run paragraph on]";

otherwise if distance is less than 9:

say ". It's a little bit of a walk, but not too bad. Head [way] to start with[run paragraph on]";

otherwise:

say ". It's pretty far from here, though. Go [way][run paragraph on]";

if a road (called target road) is adjacent to the destination and destination is not a road:

say ". It's just off [the target road]";

if destination is outdoors: [in this case, the destination probably exists only as a facade somewhere]

say ". It might be closed, though";

if the current interlocutor does not know things-close-today:

casually queue closure-excuse;

say ".'[run paragraph on]";

Instead of a fake person discussing a quip which does not quip-supply the current interlocutor:

carry out the expressing ignorance for activity with the current interlocutor;

say paragraph break.

Rule for expressing ignorance for a fake person (called target):

say "[The target] just look[s] confused. These generated people are usually limited to acting only in one particular sphere of action.[run paragraph on]"

Carry out someone discussing a quip which mentions geography:

if the current interlocutor knows you-are-tourist:

casually queue suggest-tourist-information;

now the current interlocutor knows you-are-tourist.

Instead of someone discussing where lodging seems found when the location is dormitory or location is hostel:

try the actor discussing you-seem-confused.

Instead of a tourist person discussing a location-questioning quip:

if the correct answer of the noun is the location:

try the actor discussing you-seem-confused;

else:

if the actor knows you-are-tourist:

try the actor discussing also-tourist;

otherwise:

try the actor discussing just-got-here;

you-seem-confused is a weakly-phrased NPC-directed quip.

The response is "'[one of]Look around you,[or]You don't need to go far, do you?[or]What do you call this?[or]Uh… you seem kind of confused,[at random]' [the current interlocutor] says.".

also-tourist is a weakly-phrased q-transitional NPC-directed quip.

The response is "[one of][The current interlocutor] shrugs. 'I'm as much a tourist here as you.'[or][ignorance][stopping]".

just-got-here is a weakly-phrased NPC-directed quip.

The response is "[one of]'You probably know more about that than I do,' says [the current interlocutor]. 'I just got here.'[or][ignorance][stopping]".

Instead of a native person discussing a location-questioning quip when the current interlocutor can see the guidebook and the current interlocutor does not recollect try-guidebook:

try the person asked discussing try-guidebook.

Instead of someone discussing a location-questioning quip when the person asked recollects at least three location-questioning quips:

try the person asked discussing ask-someone-else.

Instead of someone discussing a location-questioning quip when the location is the correct answer of the noun:

try the person asked discussing you-seem-confused.

Last report discussing a quip which mentions geography for the first time:

say "(Incidentally, you know, we don't have to go around asking where everything is like a tourist just off the boat. If you want to go to some place you've heard of, just say so and I'll handle the navigation [--] unless of course you actually want to give the impression of being a tourist just off the boat, in which case far be it from me to critic[ize] your methods.)" instead.

location-questioning quip is a kind of questioning quip.

A location-questioning quip is usually weakly-phrased.

A location-questioning quip has some text called the place-sought.

A location-questioning quip has an object called the correct answer.

The comment is "'[if the current interlocutor knows you-are-tourist]Do you know[otherwise]I was wondering: do you know[end if] where [one of]I could find[or]there's[at random] [place-sought of the item described] [one of]around here[or]near here[or]in this town[or]hereabouts[at random]?'"

The response is "[if the correct answer of the item described is Park Center][holiday closures][otherwise if the correct answer of the item described is the location]'[Well], look around you.'[otherwise][directions to the correct answer of the item described]".

where there seems airport is a weakly-phrased location-questioning quip.

The printed name is "where there is an airport". The true-name is "where there seems an airport".

Understand "is" or "airport" or "international" or "plane" or "airplane" as where there seems airport. The place-sought is "an airport".

It mentions geography, transportation.

The response is "[one of]'Atlantis doesn't have a commercial airport,' says [the current interlocutor]. 'There's an airstrip that belongs to Dental Consonants Limited, but if you don't have a corporate jet, forget it.'[or]'[awkward no]. Occasionally you might see planes or even a helicopter, but they're going to the DCL campus for business purposes. Tourists only come by ocean.'[or][The current interlocutor] explains, as we've already heard, that there is no airport, at least not as far as we're concerned.[stopping]".

It is background-information.

The correct answer is Park Center.

where there seems garage is a weakly-phrased location-questioning quip.

The printed name is "where there is a garage". The true-name is "where there seems a garage".

Understand "is" or "a" as where there seems garage. The place-sought is "a garage".

It mentions geography, car, transportation.

It is background-information.

The correct answer is Park Center.

where there seems telephone service is a weakly-phrased location-questioning quip.

The printed name is "where there is telephone service". The true-name is "where there seems telephone service".

Understand "is" or "phone" as where there seems telephone service. The place-sought is "a public telephone".

It mentions geography.

It is background-information.

The correct answer is Park Center.

Availability rule for where there seems internet service when the current interlocutor is the attendant:

if the attendant recollects whether there seems an internet connection nearby:

make no decision;

otherwise:

it is off-limits.

where there seems internet service is a weakly-phrased location-questioning quip.

The printed name is "where there is internet service". The true-name is "where there seems internet service".

Understand "is" as where there seems internet service. The place-sought is "internet service".

It mentions Internet, geography.

The response is "[one of]'There are some cafés and places that have access to the Atlantis network,' [the current interlocutor] say[s]. 'But a lot of them are probably closed today for Serial Comma Day.'[or][holiday closures][stopping]".

It is background-information.

where food seems sold is a weakly-phrased location-questioning quip.

The printed name is "where food is sold". The true-name is "where food seems sold".

Understand "is" as where food seems sold. The place-sought is "a source of groceries".

It mentions food, geography.

The response is "[one of]'All the regular grocery stores are probably closed for Serial Comma Day, but you could try the farmer's market up on Hesychius Street.'[or][holiday closures][at random]".

It is background-information.

The correct answer is Hesychius Street.

where a school seems is a weakly-phrased location-questioning quip.

The printed name is "where a school is". The true-name is "where a school seems".

Understand "is" or "elementary" or "grammar" or "comprehensive" or "junior" as where a school seems. The place-sought is "an elementary school".

It mentions education, geography.

It is background-information.

The correct answer is Roget Close.

where customs seems found is a weakly-phrased location-questioning quip.

The printed name is "where customs is found". The true-name is "where customs seems found".

Understand "is" as where customs seems found. The place-sought is "customs services".

It mentions immigration, geography.

It is background-information.

The correct answer is Customs House.

where post office seems found is a weakly-phrased location-questioning quip.

The printed name is "where a post office is found". The true-name is "where a post office seems found".

Understand "is" or "post office" or "postal" or "mail" or "postal/mail service" as where post office seems found. The place-sought is "a post office".

It mentions geography.

It is background-information.

The correct answer is Deep Street.

where pharmacy seems found is a weakly-phrased location-questioning quip.

The printed name is "where a pharmacy is found". The true-name is "where a pharmacy seems found".

Understand "is" or "drugs" or "drug" or "druggist" or "chemist" or "chemists" as where pharmacy seems found. The place-sought is "a pharmacy".

It mentions geography.

It is background-information.

The correct answer is Midway.

where lodging seems found is a weakly-phrased location-questioning quip.

The printed name is "where lodging is found".

The true-name is "where lodging seems found".

Understand "is" or "hostel" as where lodging seems found. The place-sought is "lodging for the night".

It mentions geography, hostel.

It is background-information.

The correct answer is Hostel.

where there seems hotel is a weakly-phrased location-questioning quip.

The printed name is "where there is a hotel". The true-name is "where there seems a hotel".

Understand "is" or "a" or "fleur" or "d'or" as where there seems hotel. The place-sought is "a hotel".

It mentions geography, fleur d'or.

It is background-information.

The correct answer is Fleur d'or.

where there seems Arbot is a weakly-phrased location-questioning quip.

The printed name is "where to find Arbot Maps & Antiques". The true-name is "where there seems Arbot".

Understand "is" or "a" or "Arbot" or "antiques" or "arbots" or "arbot's" or "maps" or "&" as where there seems arbot. The place-sought is "Arbot Maps & Antiques".

It mentions geography.

It is background-information.

The correct answer is Arbot Maps & Antiques.

where there seems cinema is a weakly-phrased location-questioning quip.

The printed name is "where there is a cinema". The true-name is "where there seems a cinema".

Understand "is" or "a" or "cinema" as where there seems cinema. The place-sought is "a cinema".

It mentions geography, cinema.

It is background-information.

The correct answer is Cinema.

where there seems pub is a weakly-phrased location-questioning quip.

The printed name is "where there is a pub". The true-name is "where there seems a pub".

Understand "is" or "a" or "bar" as where there seems pub. The place-sought is "a pub".

It mentions geography, counterfeit monkey.

It is background-information.

The correct answer is Counterfeit Monkey.

suggest-tourist-information is an NPC-directed quip.

The response is "[if current interlocutor is attendant and guidebook is visible]'You're welcome to that Guidebook, you know. It has a lot of spare information.'[otherwise]'If you have trouble finding your way, you can ask other people on the way.'[end if]"

ask-someone-else is an NPC-directed quip.

The response is "[beat] '[awkward confrontation], I can't answer this kind of question all day[if the secondary apology of the current interlocutor is not blank], [secondary apology of the current interlocutor][end if].'"

try-guidebook is an NPC-directed quip.

The response is "[if the player carries the guidebook]'I don't know why you're asking me when you've got that guidebook.'[otherwise]'Try that guidebook.'[end if]".

Definition: some text is blank if it is "".