Counterfeit Monkey — 257 of 292

Section 3 - The Bartender

The generic adversative of the bartender is "[one of]er[or]well[or]but[at random]".

The generic confrontational of the bartender is "wait up there".

Understand "ask [bartender] for [any bartender-carried thing]" as requesting it from (with nouns reversed).

Instead of showing the screwdriver to the bartender:

try requesting the screwdriver from the bartender.

Instead of showing the screwdrivers to the bartender:

try requesting the screwdriver from the bartender.

Instead of showing the gimlets to the bartender:

try requesting the gimlet from the bartender.

Instead of showing the gimlet to the bartender:

try requesting the gimlet from the bartender.

Instead of showing the rusty nail to the bartender:

try requesting the rusty nail from the bartender.

Instead of showing the rusty nails to the bartender:

try requesting the rusty nails from the bartender.

Does the player mean buying something from the bartender:

it is very likely.

The bartender is alert. The bartender exhibits vanity.

After the bartender saying hello to the player for the first time:

say "She acknowledges us with a nod as we stroll up to the bar and get close enough to hear their conversation. [run paragraph on]".

The bartender knows you-are-possible-customer.

Instead of asking the bartender to try giving a bartender-carried thing to the player:

try requesting the noun from the bartender.

Definition: a thing is bartender-carried if it is carried by the bartender.

Availability rule for buy the screwdriver:

if the screwdriver is not bartender-carried, it is off-limits;

make no decision.

buy the screwdriver is a purchasing quip.

Understand "buy screwdriver" or "buy the screwdriver" as buy the screwdriver.

It mentions screwdriver, screwdrivers.

The comment is "[if the bartender does not recollect how-rescue]We catch the bartender's eye and order a screwdriver. She holds up a finger as though to say she'll get to it as soon as she's done with [the patron][otherwise]We order a screwdriver[end if].".

The response is "'[drink-nice-day]'".

It quip-supplies the bartender.

To say drink-nice-day:

say "[one of]Just the way you were imagining it, guaranteed.[no line break][or]Enjoy.[no line break][or]You can't order any more,' she says after that. 'You've seen all my tricks, and I have to cut people off at three.[no line break][stopping]".

buy a drink is an unlisted repeatable purchasing quip.

understand "buy drink" or "order" or "cocktail" or "buying" or "ordering" as buy drink.

It mentions the generic cocktail.

The comment is "[if the bartender does not recollect how-rescue]The bartender is still talking, but we catch her eye and pantomime glugging down a beverage[otherwise]'I'd like a drink,' we say[end if]."

The response is "[one of]'What'll you have?' she asks. 'I can't pour you a generic beverage.'[or]'Pick your poison,' she says.[or]'Sure. What do you want?'[at random]".

It quip-supplies the bartender.

The generic cocktail is a scenery thing. Understand "drink" as the generic cocktail. It is carried by the bartender. [Instead of doing something other than buying with the generic cocktail: say "All the cocktails here are specific recipes."]

Carry out the bartender discussing buy the screwdriver:

move the screwdriver to the dor-bar-top;

homonym-paddle the screwdriver;

Availability rule for buy the gimlet:

if gimlet is not bartender-carried, it is off-limits;

make no decision.

buy the gimlet is a purchasing quip.

Understand "buy gimlet" as buy the gimlet.

It mentions gimlet, gimlets.

The comment is "[if the bartender does not recollect how-rescue]The bartender is still talking, but we catch her eye and point to the gimlet selection. She gives a little nod to show she understood[otherwise]'I'll have the gimlet, if you don't mind,' we say, offering an appropriate bill[end if].".

The response is "'[drink-nice-day]'".

It quip-supplies the bartender.

Carry out the bartender discussing buy the gimlet:

move the gimlet to the dor-bar-top;

homonym-paddle the gimlet;

Availability rule for buy the rusty nail:

if rusty nail is not bartender-carried, it is off-limits;

make no decision.

buy the rusty nail is a purchasing quip.

Understand "buy rusty nail" or "buy nail" or "buy rusty" or "buy a rusty nail" as buy the rusty nail.

It mentions rusty nail, rusty nails.

The comment is "[if the bartender does not recollect how-rescue]We pantomime purchasing the rusty nails, while the bartender is still chatting with [the patron]. She gives us a thumbs-up[otherwise]'I'll have the [rusty nail], if you don't mind,' we say, offering an appropriate bill[end if].".

The response is "'[drink-nice-day]'".

It quip-supplies the bartender.

Carry out the bartender discussing buy the rusty nail:

move the rusty nail to the dor-bar-top;

homonym-paddle the rusty nail;

Rule for refusing to buy something (called target) which is in the toolkit:

say "[one of]We ask about [the target], but the bartender says she's limited to one drink per type per club member. 'They're a loss leader,' she explains. 'Tools are more expensive than cocktails, and then even with the rusty nails, there's the energy to run the paddle.'[or]The bartender has already explained that she can't sell us more drinks of the same kind. The profit margin is too low, apparently.[stopping]"

Rule for refusing to buy a drink-form thing:

say "We've already paid for that." instead.

Definition: a thing is drink-form:

if it is screwdriver-drink:

yes;

if it is gimlet-drink:

yes;

if it is rusty-nail-drink:

yes;

no.

[Rule for deciding the concealed possessions of the bartender:

if the particular possession is the homonym paddle:

no;

yes.]

Before putting gel on a drink-form thing in the presence of the bartender:

say "We turn away from the bartender so she won't see too obviously what we're up to. I suppose it doesn't matter, but I wouldn't want her feelings to be hurt. [run paragraph on]".

Rule for printing the name of rusty nail while looking at the rusty-nail-drink through something:

say "metallic kind of rusty nail".

Rule for printing the name of rusty-nail-drink while looking at the rusty-nail-drink through something:

say "rusty nail cocktail".

Rule for printing the name of screwdriver while looking at the screwdriver-drink through something:

say "tool form of screwdriver".

Rule for printing the name of screwdriver-drink while looking at the screwdriver-drink through something:

say "screwdriver cocktail".

Rule for printing the name of gimlet while looking at the gimlet-drink through something:

say "tool form of gimlet".

Rule for printing the name of gimlet-drink while looking at the gimlet-drink through something:

say "gimlet cocktail".

Understand "tip [bartender]" as a mistake ("We slide a spare bill across the bar. The bartender receives it with a playful wink and tucks it away.").

Setting action variables for saying hello to or saying goodbye to the patron:

now the noun is the bartender.

Setting action variables for asking the patron about something:

now the noun is the bartender.

Setting action variables for asking the patron for something:

now the noun is the bartender.

Setting action variables for requesting something from the patron:

now the second noun is the bartender.

Setting action variables for telling the patron about something:

now the noun is the bartender.

Setting action variables for answering the patron that something:

now the noun is the bartender.

A first conversation-reply rule when the current interlocutor is the bartender:

if bartender does not recollect check-out-paddle:

queue check-out-paddle as postponed optional; [She'll only say this once.]

otherwise if bartender does not recollect dangerous-paddle:

queue dangerous-paddle as postponed optional;

otherwise if bartender does not recollect how-rescue:

queue how-rescue as postponed optional;

otherwise if the bartender does not recollect punitive-effects and a random chance of 1 in 3 succeeds:

queue punitive-effects as postponed optional;

otherwise if a random chance of 1 in 4 succeeds:

if looking:

do nothing;

otherwise:

casually queue drink-service.

check-out-paddle is an NPC-directed quip.

The response is "'It was originally produced as a toy, but it's actually a bit dangerous,' the bartender is saying.

'Dangerous? How so?' asks [the patron].

'Various ways,' she says. 'Suppose I hit a small object that has a big homonym, like say a plane. You know, the carpentry kind. Suddenly I've got an airplane-style plane on top of me.'"

It quip-supplies the bartender.

dangerous-paddle is an NPC-directed quip.

The response is "'What if you hit something that doesn't mean anything else?' the patron asks. 'Like a chicken?'

'Nothing,' she says. 'That's safe.' As though to demonstrate, she smacks the paddle against her left buttock. 'See? I don't get changed into a different bartender. Want to try?'

She holds up the paddle as though she's going to tap him with it.

'Uh... my name is Mark[mark-known],' he says.

'Maybe not, then!' she says, laughing brightly."

It quip-supplies the bartender.

Carry out someone discussing dangerous-paddle:

now patron is proper-named;

now the printed name of patron is "Mark";

reset hash code of patron.

how-rescue is an NPC-directed quip.

The response is "'That was a little dangerous, wasn't it?' [the patron] asks. 'If you had tapped me with that thing, wouldn't I be a giant X on the carpet now?'

'Not for long,' the bartender says. 'I do have some restoration gel for emergencies. Or I could just hit you again with the paddle. But there would be an incident report and I could lose my lic[ense]. So, yeah, better not.'"

It quip-supplies the bartender.

punitive-effects is an NPC-directed quip.

The response is "[The patron] looks thoughtfully into his [gin-tonic]. 'I hear that sometimes the Bureau turns people into inanimate objects as a criminal sentence. Is that true?'

For the first time, the bartender looks uncomfortable. 'I just pour the drinks,' she says. 'Hey, you're almost out there! Let me give you a refill.' And she busies herself getting down the Bombay Sapphire and refilling his drink.

'You ever tempted to paddle the Sapphire?' [the patron] asks. 'Should be worth a lot.'

'Alas, [if the player wears the Britishizing goggles]jewellers[otherwise]jewelers[end if] tend to check for authenticity around here,' she replies."

It quip-supplies the bartender.

drink-service is an NPC-directed quip.

The response is "[atmospheric-event]".

It quip-supplies the bartender.

what the paddle does is an unlisted repeatable questioning quip.

The comment is "'Tell me about that paddle,' [you] say."

The response is "[one of]'This item,' says the bartender, flourishing it for you to see, 'is a genuine licensed homonym paddle. Changes one item into another item as long as the two have identical names.'[or]The bartender explains again the concept of a homonym paddle that is able to convert an item into another item of the same name.[stopping]".

It quip-supplies the bartender.

To say atmospheric-event:

if going south:

say "[The patron] and [the bartender] from earlier are still here.";

otherwise:

say "[one of][The patron] is sipping his [gin-tonic], while [the bartender] tidies up the bar[or][The bartender] is laughing at something [the patron] just said to her[or][The bartender] is cleaning her [homonym paddle] for future use[or]One of the businessmen wanders up to the bar and orders some peanuts[or]The bartender [is-s]get[ing-s] busy washing up some glassware[or]The bartender [is-s]pour[ing-s] tequila shots for a guest[or]One of the customers comes up and asks [the bartender] about the toolkit, and [the bartender] explains what drinks they turn into[or]A businesswoman comes up to the bar for directions to the nearest restroom[or]The bartender [is-s]construct[ing-s] a garish layered blue-and-white drink in a very tall glass[or]The bartender [is-s]pour[ing-s] someone a daiquiri with plastic monkeys clinging to the side of the glass[or]The bartender [is-s]pour[ing-s] a pink beverage for one of the customers, preparing the rim with a bit of flamed orange peel[or][The patron] [is-s]talk[ing-s] with [the bartender] about the weather in Atlantis[at random].[no line break]"

To say is-s:

if the bartender is the person asked:

do nothing;

otherwise:

say "is ".

To say ing-s:

if the bartender is the person asked:

say "s";

otherwise:

say "ing".

After someone discussing drink-service:

now the bartender does not recollect drink-service;

continue the action.

Rule for beat-producing when the current interlocutor is the bartender:

repeat with item running through the planned conversation of the current interlocutor:

if the item is a purchasing quip:

say "[one of][The patron] sips his gin and tonic, and there's time to see to our order[or]In the natural rhythm of the conversation, she turns our way[stopping].[run paragraph on]";

rule succeeds;

make no decision.

Rule for refusing comment by the bartender:

if the player is not holding the noun:

silently try taking the noun;

if the player is not holding the noun:

say "We're having a little trouble holding it up so that she can see.";

rule fails;

if the noun is naughty-sounding:

say "[The bartender] takes a look and smirks.

'[unless the noun is the ass][one of]Honey, it would be too small to see[or]I'm not going to homonym-paddle that for you, so don't ask[stopping][otherwise]That's a lot of junk for one trunk[end if],' she says. [if the noun is an animal]'In fact, you really shouldn't have brought it in here.'[otherwise]'In fact, I'm not sure you're even supposed to have that.'[end if]";

rule succeeds;

if the noun is the card:

reset the card;

say "The bartender taps [the card] with the paddle. 'Was this your card?' she asks, returning a card now representing [article of (card-style of the card)][card-style of the card].";

record "getting a product of the homonym paddle" as achieved;

rule succeeds;

let target be the homonym-match of the noun;

if the heft of the target is greater than 4 or the target is fixed in place:

say "[paragraph break]'[The target] would be bigger than I want to generate in here,' comments [the bartender].";

rule succeeds;

otherwise if the noun is a person or the noun encloses a person:

say "'That would be way too dangerous. I'd lose my lic[ense] for sure.'";

rule succeeds;

otherwise if target is the player:

say "'I don't think [that-those of the noun] would turn into anything,' says the bartender. She taps [it-them of the noun] with the paddle to demonstrate. 'See? No change.'";

rule succeeds;

otherwise if the target is a person:

say "'Making live [if the target is not an animal]people[otherwise]critters[end if] is outside my lic[ense], bub.' (Bub? Who says that? But she carries it off.)";

rule succeeds;

otherwise if the target is the piece:

say "'Er… I think that would make a handgun, which would be illegal around here,' she says.";

rule succeeds;

otherwise:

if something (called the source) proffers the noun:

now the target is not proffered by anything;

now the source proffers the target;

if the noun is part of something (called the encloser):

now the target is part of the encloser;

otherwise:

now the target is carried by the player;

move the noun to the repository;

record "getting a product of the homonym paddle" as achieved;

say "She shrugs good-naturedly, hits [the noun] with the paddle, and grins at us. We look down at what we're holding: [the description of the target][paragraph break]".

Rule for refusing comment by the bartender when the noun is the Slangovia map or the noun is the fake-legend:

if the fake-legend is not part of the Slangovia map:

make no decision;

let the target be the legend;

now the noun is the fake-legend;

if something (called the source) proffers the noun:

now the target is not proffered by anything;

now the source proffers the target;

if the noun is part of something (called the encloser):

now the target is part of the encloser;

otherwise:

now the target is carried by the player;

move the noun to the repository;

record "getting a product of the homonym paddle" as achieved;

say "[one of]'This?' she says, looking a little surprised. 'You want it converted?'

'Why not?'

'No reason,' she says. 'Just I did the same item a few hours ago for a gentleman. Really hot, with these amazing eyes—'

'Whatever,' you say, before she can get any more excited about Brock.

She smirks. Then she taps the legend with her paddle and it transforms into a proper map legend.[or]'Okay, one more time.'[or]She may be tiring of this operation.[stopping]".

Carry out examining the legend:

record "reading a legend" as achieved;

Rule for refusing comment by the bartender when the noun is the Slangovia map or the noun is the fake-legend:

if the legend is not part of the Slangovia map:

make no decision;

let the target be the fake-legend;

now the noun is the legend;

if something (called the source) proffers the noun:

now the target is not proffered by anything;

now the source proffers the target;

if the noun is part of something (called the encloser):

now the target is part of the encloser;

otherwise:

now the target is carried by the player;

move the noun to the repository;

record "getting a product of the homonym paddle" as achieved;

say "[one of]She sighs. 'This isn't even good spectacle,' she says, tapping [the noun] with her paddle. 'Next time, bring me something fun, huh?'[or]She may be tiring of this operation.[stopping]"

Rule for refusing comment by the bartender when the noun is the foil:

if the player is not holding the foil:

silently try taking the foil;

if the player is not holding the foil:

say "[line break]It seems we're having a little trouble holding it up so that she can see.";

rule fails;

say "[one of]'Now that is definitely too awesome to turn down. Swordfight!'

So we lunge at her with the foil, she defends with the paddle, there is a crackle of purple-white, and we're left holding a ball of crumpled aluminum.

People around the bar shout and whoop.[or]We hold up the foil. 'Could you paddle this?'

'I'll probably get in trouble if I do this act too often, but what the hell, right? It's a holiday.'

Our fight-scene is a little better-choreographed than last time, and the customers clap enthusiastically.[stopping]";

move the foil to the repository;

record "getting a product of the homonym paddle" as achieved;

if something (called the target) proffers the foil:

now the metal-foil is not proffered by anything;

now the target proffers the metal-foil;

move the metal-foil to the player.

Rule for refusing comment by the bartender when the noun is the ball:

say "[one of]We hold up the ball. 'Can you paddle this?' we ask.

[The bartender] laughs. 'It might be fun to have a big dance in here but I think I'd get fired,' she says.[or]We tried that already, and it didn't go well.[stopping]"

[Rule for refusing comment by the bartender when the noun is a drink-form thing:

say "She's already done her thing with [the noun]." ]

Rule for refusing comment by the bartender when the noun is the shuttle:

say "[one of]We hold up the shuttle. 'Can you do this?' we ask.

[The bartender] frowns. 'If I paddled that, it'd break the whole bar. Besides, isn't it Bureau property?'

We shrug amiably.

She gives us a long, admonitory stare, then goes back to what she was doing.[or]We tried that already, and it didn't go well.[stopping]" .

Test bartender with "tutorial off / z / ask about paddle / show ball to bartender / show foil to bartender / show map to bartender / show card to bartender / g / g / show cock to bartender" in the Drinks Club holding the slangovia map and foil and the ball and the card and the cock.