Counterfeit Monkey — 262 of 292

Section 8 - Backpacking Girl

[The backpacking girl is your basic standard NPC impediment -- much more so than just about any of the NPCs who come after, though both Waterstone and Higgate are fetch-quest NPCs after a fashion.

From a narrative point of view, the backpacking girl is present to establish early on

-- that some people do come to Atlantis as tourists; it's not completely sheltered; on the other hand, their expectations are not the same as those of people used to the island long-term

-- to establish a line in the level of social inappropriateness our protagonist is allowed to show. Violence, no; doing things that may shock, surprise, or distress other characters is, however, allowed within reason. (The backpacking girl doesn't really take any harm from the experience.)

-- to bond Alex and Andra as people who are both, in their own ways, significantly more knowing than she is

The Vatican snowglobe is a real souvenir that some fellow hostel-dwellers in Rome produced with great delight. ]

Rule for avoiding talking heads when the current interlocutor is backpacking girl:

if the current interlocutor is ready for transition:

if the current quip is strongly-phrased and a random chance of 1 in 2 succeeds:

say "[beat][paragraph break]";

otherwise:

say "[beat] [run paragraph on]".

Rule for beat-producing when the current interlocutor is the backpacking girl:

if the backpacking girl carries the heavy pack:

say run paragraph on;

try the backpacking girl trying dropping the heavy pack;

otherwise if the backpacking girl is in the location:

let P be a random free bed in the dormitory room;

say run paragraph on;

try the backpacking girl trying entering P;

otherwise:

if a random chance of 1 in 3 succeeds:

say run paragraph on;

try the backpacking girl trying examining the player;

otherwise:

say "[one of]She tosses restlessly[or]She turns over[or]She bangs her head against the space where a pillow ought to be[or]She scrubs at her eyes with one hand[at random].[run paragraph on]".

Report the backpacking girl trying dropping the heavy pack:

say "With a grunt, she shrugs off her pack and puts it on the ground near one of the beds.[run paragraph on]" instead.

Report the backpacking girl trying entering a bed:

say "She eyes the beds thoughtfully, punches each of the mattresses in turn, and then climbs into the one she's selected.[run paragraph on]" instead.

Report the backpacking girl trying examining yourself:

say "She watches us with interest.[run paragraph on]" instead.

Report the backpacking girl trying examining a thing:

say "She checks out [the noun].[run paragraph on]" instead.

Report the backpacking girl trying getting off a bed:

say "The bed creaks as she rolls off it in unseemly haste. She doesn't meet our eye, but mutters something about needing to go buy something right away." instead.

[Report the backpacking girl trying going to a room (called destiny) when the actor is avoiding:

record "getting the dorm room to ourselves" as achieved;

say "A moment later she is gone." instead. ]

Report the backpacking girl trying saying hello to the player:

say "[one of]'Hey,' says the girl. [run paragraph on][or]The girl takes our reappearance in stride.[stopping]" instead.

Definition: a bed is free if it does not support a person.

The greeting of backpacking girl is "'Greetings, fellow traveler!'"

whether she seems really from canada is a questioning quip.

The printed name is "whether she is really from Canada". The true-name is "whether she seems really from canada".

Understand "if" or "is" or "canadian" as whether she seems really from canada. The comment is "'So,' we say, nodding at the pack. 'Are you really Canadian?'".

It mentions heavy pack.

The response is "'Uh, no. I come from Ohio[fake-canada]. But don't tell anyone that. My mom thought this would be safer in case of terrorists. She's also worried about serial killers but there's not much I can do about that.'".

It quip-supplies the backpacking girl.

It assumes canada-girl.

An availability rule for whether she seems really from canada:

if we have examined the heavy pack:

make no decision;

otherwise:

it is off-limits.

fear-of-killers is an NPC-directed quip.

The response is "'Do you think this place is safe?' asks the girl conspiratorially.

I must look blank, because she goes on, 'I saw this documentary once, right, about a serial killer who went from youth hostel to youth hostel, [i]grooming[/i] girls and [i]killing them[/i]. And then he'd chop up the bodies and put the [i]body parts[/i] into the lockers. And no one would find out until he'd gone away again.'

Nothing like that has happened around here, but she seems to get a charge out of scaring herself with this story."

It quip-supplies the backpacking girl.

wish-i-hadnt is an NPC-directed quip.

The response is "'Wish I hadn't remembered that serial killer thing,' the girl remarks, half to herself. 'Now it's going to keep me up later. Picturing someone with a saw hacking me up.'"

It quip-supplies the backpacking girl.

so-jet-lagged is an NPC-directed quip.

The response is "'Oh my gosh, I am SO jetlagged. I feel like I'm just going to fall over, you know?'"

It quip-supplies the backpacking girl.

sympathize about jetlag is a performative quip. The comment is "'I know how that is,' you say. Which is interesting: apparently you do know. I don't, never having left this island.". Understand "sympathise" as sympathize about jetlag.

It mentions transportation.

The response is "She frowns curiously at us. 'I don't get your accent, actually. Where are you from?'".

It quip-supplies the backpacking girl.

It directly-follows so-jet-lagged.

be honest about our origins is a weakly-phrased unlisted performative quip. The comment is "'[if the backpacking girl recollects lie about our origins]Actually the truth is [end if]I spent some of my life around here and some of it traveling around the Mediterranean, living on a yacht and conducting acts of international espionage. That's when I wasn't working on a university degree in language studies.'".

Understand "tell the truth" or "tell truth" or "be truthful" as be honest our origins.

It mentions yourself.

The response is "[if the backpacking girl recollects lie about our origins]'There's nothing wrong with coming from California,' she says. 'You don't have to make something up.'[otherwise]'...Right,' she says. 'I'm guessing world-traveling professor-spies don't stay in youth hostels.'[end if]".

It quip-supplies the backpacking girl.

It indirectly-follows sympathize about jetlag.

lie about our origins is a weakly-phrased performative quip. The comment is "'[if the backpacking girl recollects be honest about our origins]Actually the truth is [end if]I grew up in California,' you say. 'In... sort of a suburb of Los Angeles, though pretty far out. Fontana, if you've heard of that.'".

Understand "lieabout" as lie about our origins.

It mentions yourself.

The response is "'Nah,' she says, without interest. 'But that's cool.'".

It quip-supplies the backpacking girl.

It indirectly-follows sympathize about jetlag.

when-get-here is an NPC-directed quip.

The response is "'So when did you get to Anglophone Atlantis, anyway? How long have you been here?'"

It quip-supplies the backpacking girl.

lie about visiting is a performative quip. The comment is "'Just a few days. I wanted a little time to see the place, before it got all crazy for Serial Comma Day,' you lie smoothly.".

Understand "lieabout" as lie about visiting.

It mentions celebration, yourself.

The response is "'Oh, yeah, that was smart,' she says. 'I am really not ready for this at all.'".

It quip-supplies the backpacking girl.

It directly-follows when-get-here.

[because otherwise we get interference with the LIE ON THING command from Postures:]

After reading a command when the current interlocutor is the backpacking girl:

if the player's command matches "lie":

change the text of the player's command to "lieabout";

otherwise if the player's command includes "lie about":

change the text of the player's command to "lieabout".

what-think-so-far is an NPC-directed quip.

The response is "'Do you like this place so far?'"

It quip-supplies the backpacking girl.

Instead of saying no or frowning when the current quip is what-think-so-far:

try discussing disapprove of Atlantis.

Instead of saying yes or smiling when the current quip is what-think-so-far:

say "We respond with a friendly smile. [run paragraph on]";

try discussing approve of Atlantis.

Instead of shrugging when the current quip is what-think-so-far:

say "We shrug. [run paragraph on]";

try discussing equivocate about Atlantis.

equivocate about Atlantis is an unlisted performative quip. The comment is "'I've seen better and I've seen worse.' Which is a lie, at least on my part: I've seen nothing but Atlantis my whole life.".

It mentions yourself.

The response is "'Makes sense.'".

It quip-supplies the backpacking girl.

It directly-follows what-think-so-far.

disapprove of Atlantis is an unlisted performative quip. The comment is "'There are a lot of things to say about the government,' we reply cautiously.".

It mentions yourself.

The response is "'Like what?'

'It's better not to say them out loud.'

'If you can't say something nice, it's better not to say anything at all,' the girl responds. 'I hate gossip especially when people won't give hard details. That's how this girl Stacy at my school got totally ostracized for supposedly doing something slutty only no one knew what it was.'".

It quip-supplies the backpacking girl.

It directly-follows what-think-so-far.

approve of Atlantis is a performative quip. The comment is "'Sure,' you say. 'It's pretty, it's clean, there's lots of interesting stuff around.' I can see why your career isn't with a tourist board.".

It mentions yourself.

The response is "'I guess.'".

It quip-supplies the backpacking girl.

It directly-follows what-think-so-far.

grr-no-showers is an NPC-directed quip.

The response is "'I can't believe this room doesn't have its own bathroom and showers. I mean, gross.'"

It quip-supplies the backpacking girl.

Instead of saying yes or smiling when the current interlocutor is the backpacking girl and agree about showers is available:

try discussing agree about showers.

agree about showers is a performative quip. The comment is "'I'm more used to having my own bathroom,' we agree. Which I guess is true for me; your memories appear to be a little more diverse.".

It mentions yourself.

The response is "'I know, right?'".

It quip-supplies the backpacking girl.

It directly-follows grr-no-showers.

Instead of saying no or frowning or scoffing when the current interlocutor is the backpacking girl and disagree about showers is available:

try discussing disagree about showers.

disagree about showers is an unlisted performative quip. The comment is "'Practically third-world,' you say sarcastically.".

It mentions yourself.

The response is "'I know, right?'".

It quip-supplies the backpacking girl.

It directly-follows grr-no-showers.

have-you-checked is an NPC-directed quip.

The response is "'Have you tried talking to the desk girl downstairs? I mean for more than two seconds? She is a total witch that starts with B, know what I mean? Like, she looked at me like I was completely an idiot, right, and, like, what does she expect? Of course I don't know my way around, I just got here.'"

It quip-supplies the backpacking girl.

Availability rule for mention the louse incident:

if the location of the attendant is the Hostel:

it is off-limits.

mention the louse incident is a performative quip. The comment is "'I'm afraid I made [if immediately]her[otherwise]the attendant[end if] go away,' we confess. 'I turned her blouse into something else.'".

It mentions louse, attendant.

The response is "She blinks, startled, and you have the impression that you've frightened her a little. 'Oh... right. My mother warned me to be careful.'".

It quip-supplies the backpacking girl.

It indirectly-follows have-you-checked

Instead of saying yes when the current interlocutor is the backpacking girl and agree about the attendant is available:

try discussing agree about the attendant.

agree about the attendant is a performative quip. The comment is "'I've seen more impressive customer service,' you say.".

It mentions attendant.

The response is "'You'd think they'd be a little nicer if they want repeat customers,' she grumps. I decide not to point out that the hostel is by far the cheapest lodging place on the island, is probably run on subsidies to make it possible for foreign students to visit at all, and never suffers from any lack of custom.".

It quip-supplies the backpacking girl.

It directly-follows have-you-checked.

Instead of saying no when the current interlocutor is the backpacking girl and disagree about the attendant is available:

try discussing disagree about the attendant.

Instead of frowning when the current interlocutor is the backpacking girl and disagree about the attendant is available:

say "We frown. [run paragraph on]";

try discussing disagree about the attendant.

disagree about the attendant is an unlisted performative quip. The comment is "'She's probably paid about five dollars an hour to greet visitors and scrub toilets while everyone else has a holiday,' we say. 'This place is heavily subsidized to run at all. Having to work here is a form of punitive community service.'".

It mentions attendant.

The response is "'Well, okay. But she must have done something to get assigned community service, then.'

'Exceeded her allowance of accidental misspellings, I imagine,' I say.

The girl starts to laugh, then trails off when she realizes this is not a joke.".

It quip-supplies the backpacking girl.

It directly-follows have-you-checked.

souvenir-buying is an NPC-directed quip.

The response is "'I hope this place has good souvenirs. I got this great snowglobe at the Vatican, right, that has the Pope inside saying, like, a blessing.'"

It quip-supplies the backpacking girl.

Instead of laughing when the current interlocutor is the backpacking girl and the current quip is souvenir-buying:

say "We snicker. [run paragraph on]";

try discussing mock the snowglobe.

Instead of smiling when the current interlocutor is the backpacking girl and the current quip is souvenir-buying:

say "We go for a friendly, non-fake smile. [run paragraph on]";

try discussing admire the snowglobe.

mock the snowglobe is an unlisted performative quip.

Understand "make fun" or "make fun of" or "laugh at" or "diss" or "denigrate" or "insult" as mock the snowglobe.

The comment is "'[if immediately]That's pretty special[otherwise]Your snowglobe must be a collector's item[end if],' we say. 'It only snows at the Vatican once every couple of decades.'".

The response is "'Oh yeah! Cool.'

'Not like those Norwegian snowglobes,' you add. 'Those are a dime a dozen.' Pushing your luck a little, perhaps. She gives us a faintly puzzled look but doesn't say anything."

It quip-supplies the backpacking girl.

It indirectly-follows souvenir-buying.

admire the snowglobe is a performative quip.

The comment is "'[if immediately]I bet your friends back home are going to love that[otherwise]I'm sure your snowglobe will be a big hit with your friends back home[end if].'".

The response is "'Yeah,' she says. 'Though I have to keep my souvenir buying light because there isn't that much room in my pack.'"

It quip-supplies the backpacking girl.

It indirectly-follows souvenir-buying.

An availability rule for recommend the gift shop:

if the Gift Shop is unvisited:

it is off-limits;

make no decision.

recommend the cathedral gift shop is a performative quip.

The comment is "'[if immediately]Oh, yeah, actually, there's a great shop attached to the New Church. It's just across the square. You should go there; they've got lots of stuff like your snowglobe[otherwise]If you do want to do some shopping, there's the New Church across the square. It's got a bunch of gifts like your snowglobe[end if].'".

The response is "'Sweet! I'll check it out when I'm more rested. Thanks!'

Oh well. It was worth a try."

It quip-supplies the backpacking girl.

It indirectly-follows souvenir-buying.

A first conversation-reply rule when the current interlocutor is the backpacking girl:

let N be a random NPC-directed quip which quip-supplies the backpacking girl;

if the backpacking girl does not recollect fear-of-killers:

queue fear-of-killers as postponed obligatory;

otherwise if the backpacking girl does not recollect N:

queue N as postponed obligatory.

Instead of waiting when the current interlocutor is the backpacking girl:

say "[beat][paragraph break]".

ask for privacy is a repeatable performative quip. The comment is "[one of]'Would you mind giving me a minute?' we say. 'Sorry, I could just use a little privacy.'[or]'I'd really like to be alone for a couple of minutes now,' we say.[or]'This will just take a moment, but you would you mind giving me the room to myself?' we say.[at random]".

It mentions yourself.

The response is "[one of]She waves a hand generously. 'Don't worry about it, do whatever you've got to do, I don't care,' she says. 'I'm so tired I couldn't move a muscle, but I've seen everything. I have three brothers and two sisters and I'm in women's rugby so I'm pretty hard to shock.'[or]She just grunts and waves to indicate we may strip naked at our leisure.[or]'Dude,' she says, exasperated. 'If you wanted a private room you should've not stayed at a freaking hostel.'[or]She moans.[stopping]".

It quip-supplies the backpacking girl.

Carry out discussing ask for privacy:

now ask for privacy is unlisted.

whether she had trouble alongside customs is a questioning quip.

The printed name is "whether she had trouble with customs". The true-name is "whether she had trouble alongside customs".

Understand "with" or "if" as whether she had trouble alongside customs. The comment is "'How was coming through Customs?' we ask. 'Any trouble there?'".

It mentions immigration.

The response is "'Not really. There were a few people in line, and they made me take all my stuff out of my backpack... and this one guy I saw them take away into a back room, and I don't think he ever came out again. But, uh, they were nice enough to me I guess. I was expecting worse.'".

It quip-supplies the backpacking girl.

It is background-information.

Test backpacking with "tutorial off / look / z / z / z / z / z / show arm to girl" in the Dormitory holding the arm.