Counterfeit Monkey — 263 of 292

Section 9 - Gift Shop Volunteer

The greeting of the gift shop volunteer is "'Good [rough daytime],' he says."

The generic positive of the gift shop volunteer is "yes".

The generic negative of the gift shop volunteer is "no".

The generic adversative of the gift shop volunteer is "[one of]alas[or]sadly[at random]".

The secondary apology of the gift shop volunteer is "[one of]sorry[or]I'm afraid[at random]".

The generic confrontational of the gift shop volunteer is "miss".

Instead of asking the gift shop volunteer about something:

let N be indexed text;

let N be "[one of][generic adversative of the gift shop volunteer in sentence case][or][secondary apology of the gift shop volunteer in sentence case][at random]";

say "[You] frame up a vague question about [the second noun].

[beat] '[N], don't think I can help you there.'[paragraph break]"

The gift shop volunteer knows you-are-possible-customer.

A first conversation-reply rule when the current interlocutor is the gift shop volunteer and the gift shop volunteer recollects at least one quip:

if the ostensible motive is you-are-dangerous:

if the current interlocutor does not recollect you-should-leave:

queue you-should-leave as postponed optional;

if the ostensible motive is you-are-possible-customer:

if the current interlocutor does not recollect offer-souvenirs:

queue offer-souvenirs as postponed optional.

broke-it-buy-it is an NPC-directed quip.

The response is "'You broke it, you buy it,' says the volunteer. 'Though the tomes were free. But please at least take your mess away with you when you leave.'"

Rule for beat-producing when the current interlocutor is the gift shop volunteer:

say "[one of]He looks at us keenly[or]He drums a little pattern on the surface of the counter[or]He absently straightens the arrangement of the postcards in the display[or]He polishes a smudge off one of the souvenir shot glasses[or]He nods to another customer who is just leaving before turning his attention back to us[or]He rearranges the objects on sale[as decreasingly likely outcomes].[run paragraph on]".

To say rough daytime:

if the current daytime is:

-- noon:

say "[one of]morning [--] or afternoon, I suppose it might be afternoon by now[or]afternoon[stopping]";

-- sunset:

say "evening";

-- evening:

say "evening";

-- otherwise:

say "afternoon";

what seems worth seeing in the New Church is a questioning quip.

The printed name is "what is worth seeing in the New Church". The true-name is "what seems worth seeing in the New Church".

Understand "is" as what seems worth seeing in the New Church.

The comment is "'So tell me, what should I be looking for in the New Church?' we ask.".

The response is "'Other than God?' he asks dryly.".

It quip-supplies the gift shop volunteer.

whether he believes in God is a questioning quip.

It mentions religion.

The comment is "'Are you a believer?' we ask[you-are-dangerous].".

The response is "'Some of the time. The rest of the time I just wish I were.' He flattens his hands on the surface of the counter. They are veiny, with coarse thick nails. Some reflection about the end of life, or the perspective of old age, seems inevitable. But he says: 'You choose to believe or not. There's no such thing as absolute proof. So then the question is, do you want to believe in God? And, if so, what kind of God do you want to believe in? You go from there[casually queue curate-backstory].'".

It quip-supplies the gift shop volunteer.

It is background-information.

Understand "if" or "man" or "volunteer" or "gift" or "shop" as whether he believes in God.

what sort of God he believes in is a questioning quip.

It mentions religion.

The comment is "'What sort of God do you believe in[if immediately], then[end if]?' we ask. This isn't exactly how I expected this conversation to go, but no doubt you have some reason of your own for chatting with random strangers about their deeply held beliefs while we are supposed to be [i]fleeing the country[/i].".

The response is "'Today?' He shrugs his cardigan-clad shoulders. 'I figure he's a good enough type but he's a little tired of humans. Who wouldn't be? It might be that he's working on a new project and he's gotten distracted from us[casually queue curate-backstory].'".

It quip-supplies the gift shop volunteer.

It indirectly-follows whether he believes in God.

Rule for quip-introducing whether there seem points of architectural interest:

say "Hm [--] the volunteers aren't very well trained, are they? I was expecting something about the points of architectural interest."; list no other quips.

whether there seem points of architectural interest is a weakly-phrased questioning quip.

The printed name is "whether there are points of architectural interest". The true-name is "whether there seem points of architectural interest".

Understand "if" or "are" as whether there seem points of architectural interest.

The comment is "'Are there, er, points of architectural interest about the Church?' we persist.".

The response is "'Not that I know of.'".

It quip-supplies the gift shop volunteer.

It directly-follows what seems worth seeing in the New Church.

offer-souvenirs is an NPC-directed q-transitional quip.

The response is "His voice quavers. 'Could I interest you in the purchase of a souvenir tea towel? Or a shot glass? Or perhaps a paper model of the church.'"

The nag is "[one of]'All purchases go towards the fund to rebuild the church roof,' he reveals enticingly.[or]'Money spent in the New Church shop is non-taxable,' he adds.[or]'It's in a good cause. This is a historical monument.'[or]The moral pressure from the old man has not abated.[stopping]".

It is restrictive.

Instead of frowning or saying no when decline to buy trashy souvenirs is available:

try discussing decline to buy trashy souvenirs.

Instead of saying yes when decline to buy trashy souvenirs is available:

if the player encloses the roll of bills:

say "I hate to interfere in this act of charity, but we need our cash for other purposes.";

otherwise:

say "We're flat broke."

Instead of laughing or scoffing when mock the trashy souvenirs is available:

try discussing mock the trashy souvenirs.

mock the trashy souvenirs is an unlisted performative quip.

The comment is "We snort. 'There's nothing here I would buy if my money were on fire.'".

The response is "'Not even a lovely illustrated retelling of the story of Ananias and Sapphira?' suggests the volunteer. 'So inspiring for any young children in your life.' I've no idea what he's talking about, but you recall them as a couple who lied about their donations to the early church and were punished with death.

'The divine enforcement policy isn't what it used to be,' you say[casually queue curate-backstory].".

It quip-supplies the gift shop volunteer.

It directly-follows offer-souvenirs.

decline to buy trashy souvenirs is a performative quip.

The comment is "'Thank you, but no,' we say firmly.".

The response is "He gives a resigned, what-can-you-do? shrug.".

It quip-supplies the gift shop volunteer.

It directly-follows offer-souvenirs.

curate-backstory is an NPC-directed quip.

The response is "'I used to be a curate,' says the volunteer reminiscently. 'Had myself smuggled into the country disguised as a crate, and that all but killed me. But I was determined to be a missionary and bring the population of Atlantis back into the fold. And now look. It's come to this.'".

It quip-supplies the gift shop volunteer.

why gift shop volunteer seems here is a questioning quip.

The printed name is "why he is here". The true-name is "why gift shop volunteer seems here".

Understand "is" or "he" as why gift shop volunteer seems here.

It mentions volunteer, employment.

The comment is "'If you aren't interested in this place, why do you volunteer here?' we ask[you-are-dangerous].".

The response is "His left eyelid twitches. 'The Rosehip woman,' he says, after a moment. 'She's a looker.' [paragraph break]I'm not sure what's more disturbing: someone expressing attraction to my mother; that person being a good thirty years her senior; or the use of the phrase 'she's a looker', which even this old character probably got from a movie.".

It quip-supplies the gift shop volunteer.

It indirectly-follows what seems worth seeing in the New Church.

remind the gift shop volunteer that Mrs Rosehip seems married is a performative quip.

The printed name is "remind the gift shop volunteer that [Mrs] Rosehip is married". The true-name is "remind the gift shop volunteer that [Mrs] Rosehip seems married".

Understand "is" or "dad" or "father" or "my father" or "my dad" or "your father" or "your dad" as remind gift shop volunteer that Mrs Rosehip seems married.

It mentions my mother.

The comment is "'My mother[--]' we begin, before you catch me.

Sorry about that!

'[--] always tells me it is unwise to chase after married women,' we finish lamely. ".

The response is "He shakes with laughter. 'Bless you,' he says. 'I'm not [i]chasing after[/i] anyone! At my age, you just like a bit of good scenery. You're not hard on the eyes yourself, you know.'".

It quip-supplies the gift shop volunteer.

It directly-follows why gift shop volunteer seems here.

what new project that might be is a weakly-phrased questioning quip. The comment is "'What kind of new project?'".

It mentions religion.

The response is "'If I knew, I'd be the almighty, wouldn't I?'".

It quip-supplies the gift shop volunteer.

It directly-follows what sort of God he believes in.

whether he approves of government is a questioning quip. The comment is "'Do you approve of the present government of the island[you-are-dangerous]?'".

It mentions bureau, legislation, and gift shop volunteer.

The response is "His eyes narrow sharply. 'That's not a question we get asked a lot around here,' he comments. 'It's a little like being asked whether you approve of the plumbing in your house, or the brake lines on your car. If it ever broke, you'd know, but the rest of the time you just don't give it much consideration. Underappreciated folks, our orthographers, but they work hard and they make things run smoothly, and barring the odd popular referendum we don't have to waste nearly as much time on arguing politics as folks in most countries.'".

It quip-supplies the gift shop volunteer.

It is background-information.

Understand "if" as whether he approves of government.

why he isn't at the celebration is a questioning quip. The comment is "'I'm surprised you're in here and not outside enjoying the festivities,' we comment.".

It mentions celebration and gift shop volunteer.

The response is "'The prizes and the candy are for kiddies,' he says. 'The part I like best's what comes later. The fireworks. They're always first rate.'".

It quip-supplies the gift shop volunteer.

It is background-information.

how to see the fireworks is a questioning quip. The comment is "'[if immediately]Really? I wouldn't want to miss that. [end if]How do we see the fireworks display?'".

It mentions celebration.

The response is "'It's after dark,' he says, 'naturally. But you'll be able to see it from anywhere around, not to worry. They fire the blasts off over the water but you can see them from miles off.'".

It quip-supplies the gift shop volunteer.

It indirectly-follows why he isn't at the celebration

you-should-leave is a q-transitional NPC-directed quip.

The response is "He looks at us thoughtfully and I almost have the feeling he knows something I don't want him to know. 'You should keep moving. Don't waste time,' he says."

mess-complaint is an NPC-directed quip.

The response is "'I hope you're planning to clean that up,' he comments."

Test shop-volunteer with "tutorial off / s / a worth seeing / a god / g / ask why he is here / a rosehip / z / wave m-remover at tomes" in the New Church.