Counterfeit Monkey — 274 of 292

Section 9 - Mother

[ Mother has only this one brief scene, but she's an important influence in Alex's life: a source of cosmopolitan and slightly subversive ideas, more in touch with the world outside than Alex's father, and source of the unquestioned privilege of his upbringing. ]

My mother is a woman. Understand "mom" or "ma" or "mum" or "mommy" as mother. "My mother is here, looking around as though she would like to comment on my housekeeping." The description of my mother is "She is a tall woman with short brown hair expertly cut, and a tailored suit."

The introduction is "She has in addition a certain air which is very rare on this island: the air of seeming not to care whether anyone is watching her, or whether she is exhibiting the proper respect for authority."

Sanity-check kissing my mother:

say "Save the skeezy Oedipal reenactments for when you're inhabiting your own body, eh?" instead.

Instead of waiting in the presence of my mother:

say "[beat][line break][paragraph break]".

Definition: a thing is apartmental if it is in my apartment.

Rule for beat-producing when the current interlocutor is my mother:

say run paragraph on;

let N be a random refrigerator which is in my apartment;

if the player wears the monocle and the player does not recollect monocle-comment:

try my mother examining the monocle;

casually queue monocle-comment;

otherwise if the N is open:

try my mother closing N;

otherwise if the pot-of-yogurt is not seen:

try my mother opening N;

otherwise if something (called impediment) is on the futon:

try my mother clearing the futon;

otherwise if my mother carries something (called impediment):

let goal be a random furniture counter which is in my apartment;

try my mother dumping inventory on the goal;

otherwise if my mother can see a switched on thing (called danger):

try my mother switching off the danger;

otherwise:

let target be a random apartmental thing which is not a person ;

if target is not nothing:

try my mother examining the target;

else:

say "Mother looks faintly bewildered.";

say run paragraph on.

Test mom-beats with "drop mother / open backpack / say we're / z / close backpack / z / z / z" holding my mother and the backpack in my apartment.

Report my mother switching off something:

if the noun is a switch which is part of a stove:

casually queue no-open-flame;

if the noun is a tap which is part of a sink:

casually queue no-water-waste;

say "She goes to [the noun] and turns it off.[run paragraph on]" instead.

Dumping inventory on is an action applying to one thing.

The dumped objects is a list of objects that varies;

Setting action variables for an actor dumping inventory on something:

truncate the dumped objects to 0 entries;

repeat with item running through things carried by the actor:

add the item to the dumped objects.

Carry out an actor dumping inventory on:

now everything carried by the actor is on the noun.

Report an actor dumping inventory on:

say "[The actor] puts [the dumped objects with definite articles] down on [the noun]."

Report my mother dumping inventory on:

say "[The actor] puts [the dumped objects with definite articles] down on [the noun].[run paragraph on]" instead.

Clearing is an action applying to one thing.

The cleared objects is a list of objects that varies.

Setting action variables for an actor clearing something:

truncate the cleared objects to 0 entries;

repeat with item running through things on the noun:

add the item to the cleared objects.

Carry out an actor clearing:

now the actor carries everything which is on the noun;

Report an actor clearing:

say "[The actor] pick[s] up [the cleared objects with definite articles] carefully."

Report my mother clearing:

say "[The actor] pick[s] up [the cleared objects with definite articles] from [the noun].[run paragraph on]" instead.

Report my mother opening a refrigerator:

say "Mother picks her way to the refrigerator, which she opens, revealing only [a list of things in the noun][queue not-planning-dinner].[run paragraph on]" instead.

Report my mother closing a refrigerator:

say "She gives the refrigerator door a little push and it swings closed.[run paragraph on]" instead.

Report my mother taking a book:

say "Mother rather absently picks up [the noun] and smooths its pages.[run paragraph on]" instead.

Report my mother examining a book which is not enclosed by the player:

say "Mother pages through [the noun], eyebrows raised.[run paragraph on]" instead.

Report my mother examining something:

say "Mother [one of]stares absently at [the noun] for a moment[or]spaces out a bit, contemplating [the noun][or]appears to be meditating about [the noun][at random].[run paragraph on]" instead.

Sanity-check going from My Apartment when confrontation-with-mother has not happened:

move my mother to the location instead.

Sanity-check going from My Apartment during confrontation-with-mother:

say "I don't quite dare just walk out on Mother. Partly it's habit, partly the sense that she's more upset than she's letting on, and that if we push her the wrong way she'll contact the authorities."

Confrontation-with-mother is a scene. Confrontation-with-mother begins when my mother is visible.

When confrontation-with-mother begins:

say "We're about to, when the door to the street opens and my mother walks into the room. She shuts it behind her and puts away her key before she notices us. Then she stands very still. For about a quarter second she considers calling the police, but I can see that worry passing away again as she takes in our clothing, age, and general demean[our].";

set the current interlocutor to my mother;

try my mother discussing hi-there-Im;

queue final-goodbye as postponed obligatory.

hi-there-Im is an NPC-directed quip.

The response is "'Hi there,' she says, coming forward to take our hand. 'I'm [Mrs] Rosehip. Alex Rosehip's mother. You must be a friend of his?'"

The nag is "Mother just stands there with an arched eyebrow. Any minute now I'm going to blurt something out through sheer force of habit."

It is restrictive.

Instead of saying no when we're his girlfriend is available:

say "What are the other options, really? Shall we claim to be burgling my apartment? To be a roommate she's never heard of, who is living with furniture that obviously isn't here? To be the gas man, a fire inspector, the police? None of that has a hope of working."

Instead of saying yes when we're his girlfriend is available:

try discussing we're his girlfriend.

we're his girlfriend is an informative quip. The comment is "'Yes [--] sort of. We've been... I mean, we've been on a few dates.' That's you, and I have to say you don't sound as keen on dating ourself as you might.".

Understand "we are" or "to be" as we're his girlfriend.

It mentions romance, yourself.

The response is "She raises her eyebrows. 'I see. How secretive of him not to bring you around. And where is Alex now? I need to speak with him. He's been hard to reach lately[queue how-well-do-you as immediate obligatory].'

I know you think it's a bit sketchy that my mother just walks into my apartment when I'm not around, but I swear to you she's never done that before. She must be more worried about something than she's letting on.".

It quip-supplies My mother.

It is restrictive.

The nag is "[one of]'Come, dear, it's not a difficult question,' she says[or]She's still waiting for us to answer[stopping]."

It directly-follows hi-there-Im.

claim to hath seen him this morning is a performative quip.

The printed name is "claim to have seen him this morning". The true-name is "claim to hath seen him this morning".

Understand "have" as claim to hath seen him this morning. The comment is "'He went out to, ah, do some research, I think. He left before I was completely awake.' (Thanks, now you've given my mother the impression that I'm a cad.)".

It mentions romance.

The response is "She looks at the dissheveled futon[if something is on the futon], with [the list of things on the futon] still arranged on it[end if], and her expression becomes even more unreadable. 'I did think I'd taught my son better manners,' she remarks. 'I apolog[ize] on his behalf.'".

It quip-supplies My mother.

It directly-follows we're his girlfriend.

Instead of shrugging when we don't ken is available:

try discussing we don't ken.

we don't ken is an informative quip.

The printed name is "we don't know". The true-name is "we don't ken".

Understand "know" as we don't ken. The comment is "'I don't know,' we say.".

It mentions yourself.

The response is "'A communicative couple, then,' she says dryly. My mother has never been very nice to girlfriends she considered stupid.".

It quip-supplies My mother.

It directly-follows we're his girlfriend.

how-well-do-you is an NPC-directed quip.

The response is "'How well do you know him?' Mother asks. She immediately catches herself, and adds: 'I'm not inquiring into the details of your relationship. But I am concerned about him. He has seemed very unhappy recently about his work. Has he said anything to you about that? Wanting to leave the program, or change careers, or... anything?' [paragraph break]I didn't think she'd noticed."

reassure Mother is a performative quip. The comment is "'I think it's graduate school getting to him a bit,' we lie. I am pretty sure this is what my mother thinks: she has little time for whining or sulking, and I believe she considers any ideological queasiness I may have exhibited to be just malingering about research that is not going well.".

It mentions yourself, education.

The response is "'Really?' she says. 'Hm.' [paragraph break]I would like her to go on, but she doesn't: because it would be indiscreet, because she doesn't trust us.".

It quip-supplies my mother.

It directly-follows how-well-do-you.

suggest the truth is a performative quip. The comment is "'I think he feels that there are things linguistic studies could accomplish if we were less hampered by local laws and corporate interests,' we say. 'Big improvements to quality of life for the poor, for instance.'".

It mentions constructed language.

The response is "She looks at us keenly. 'Did he say what he intended to do about that?'".

It quip-supplies my mother.

It is restrictive.

It directly-follows how-well-do-you.

we wouldn't do anything dangerous is an informative quip.

Understand "danger" as we wouldn't do anything dangerous.

The comment is "'I'm sure he wouldn't do anything dangerous,' we lie. 'After all, his ideas wouldn't be useful to anyone if he were arrested.'".

It mentions bureau, yourself.

The response is "'No, of course!' But I think she knows we're lying about something, even if she is not sure what that something is.".

It quip-supplies my mother.

It directly-follows suggest the truth.

Instead of saying no when probably nothing is available:

try discussing probably nothing.

probably nothing is an unlisted weakly-phrased informative quip. The comment is "'No, no. Probably nothing,' we say.".

It mentions yourself.

The response is "'Hm.'".

It quip-supplies my mother.

It directly-follows suggest the truth

not-planning-dinner is an NPC-directed quip.

The response is "'Evidently not planning to have dinner at home this evening,' she comments."

Instead of saying no or saying yes when explain we might go out is available:

try discussing explain we might go out.

explain we might go out is a performative quip. The comment is "'We were thinking of going out.'".

It mentions food, yourself.

The response is "'Were you?' she says lightly. 'Then you're definitely going to see him this evening. Where do you have reservations?' [paragraph break]There, see: I wish you wouldn't embellish on your own.".

It quip-supplies my mother.

It is restrictive.

It directly-follows not-planning-dinner.

Instead of shrugging when claim he didn't say is available:

try discussing claim he didn't say .

claim he didn't say is a weakly-phrased performative quip. The comment is "'Er... he didn't tell me. I assume he'll explain later.'".

Understand "did" or "not" or "alex" as claim he didn't say.

It mentions food.

The response is "'...Mm.'".

It quip-supplies my mother.

It directly-follows explain we might go out.

monocle-comment is an NPC-directed quip.

The response is "'He must like you,' she says, 'if he lets you wear his monocle. He's very proud of that. But do be careful with it [--] it would be a little embarrassing if someone were to catch you with it. Alex's father was technically not supposed to remove it from the Bureau.'"

agree to take care of the monocle is a weakly-phrased performative quip. The comment is "'I'll be very careful with it.'".

It mentions monocle.

The response is "'I knew you would.'".

It quip-supplies my mother.

It directly-follows monocle-comment

no-open-flame is an NPC-directed quip.

The response is "'It's not a good idea leaving the gas stove on when you're not cooking anything,' she comments. 'It catches fire even more easily than electric.'"

no-water-waste is an NPC-directed quip.

The response is "'There's no point in wasting water when we're already facing shortages.'"

final-goodbye is an NPC-directed quip.

The response is "'Well,' Mother says. 'I had better go. If you do see Alex, tell him to call me, please. It isn't an emergency, but you can tell him there's a bit of Bureau business I'd like to discuss with him.'"

Confrontation-with-mother ends when my mother recollects final-goodbye.

When confrontation-with-mother ends:

say "We nod";

if my mother carries something:

say ". [run paragraph on]";

let goal be a random furniture counter in my apartment;

try my mother dumping inventory on goal;

say " She's going,";

otherwise:

say ",";

say " and suddenly it is borne in on me that this may be the last I see of my mother in a lifetime: and I'm trying to memor[ize] the exact cut of her hair and the way her expensive Italian heels tap on the floor, and meanwhile she is going out completely indifferent to the moment. I could have stood for our previous meeting to be the last one [--] we had dinner and she hugged me goodbye then. This makes it all much much worse.

And you, you're nattering at me in our head, asking what she meant about the Bureau. It might be, I guess, that they've been watching me and that she got wind of it. That would be likely. But if so it doesn't matter, not any more.

She's not even visible through the window any longer.";

remove my mother from play;