Counterfeit Monkey — 284 of 292

Chapter 4 - Puzzle Hints

Section 1 - Tutorial Area

Check requesting hint about the code:

try requesting hint about the code-lock.

Report requesting hint about the codex:

say "[one of]A codex without an X is a code[or]Try WAVE X-REMOVER AT CODEX[stopping]." instead.

Check requesting hint about the temporary barrier:

try requesting hint about the code-lock instead.

Report requesting hint about the code-lock:

if the code-lock is unlocked:

say "The barrier has been unlocked; there's nothing left for us to do there." instead;

if the codex is unseen:

say "[one of]It seems we need a code to open the lock. Something nearby might be useful[or]There's a [codex] in the museum window; maybe we could do something with that[stopping]." instead;

if the code is unseen:

say "[one of]Let's try transforming the CODEX into the code we need[or]Personally, I'd try WAVE X-REMOVER AT CODEX[stopping]." instead;

say "Now we've got a code: SET LOCK TO CODE." instead.

Check requesting hint about a pan:

try requesting hint about the word-balance instead.

Check requesting hint about the barker:

try requesting hint about the word-balance instead.

Check requesting hint about something which is on a pan when the barker is in the location:

try requesting hint about the word-balance instead.

Report requesting hint about the word-balance:

if the barker is not in the location, say "The word-balance challenge has already been solved. I don't think there's anything more we can do with it." instead;

say "[one of]The balance will tilt if the contents of one pan are lighter than those of the other.[or]We can't take anything out, but perhaps we could change what's already there.[or]The letter-remover would come in handy for this.[or]There are several different changes we could make.[or]We could try WAVE R-REMOVER AT PEAR.[stopping]" instead.

Report requesting hint about the ticket:

if the cinema lobby is not visited:

say "Most likely this will come in handy somewhere where we need a ticket." instead;

if the Screening Room is visited:

[this should not occur, because he should have torn the ticket up]

say "We have already gotten past the ticket-taker." instead;

if the location is not the cinema lobby:

say "This might be more useful back at the cinema lobby." instead;

say "Giving the ticket to the ticket-taker would probably get us into the screening room." instead.

Report requesting hint about the ticket-taker:

if the Screening Room is visited, say "We have already gotten past the ticket-taker. He'll remember that now and let us come and go as needed." instead;

if the Church Garden is unvisited, say "[one of]We should explore further.[or]We haven't yet explored the area of the church.[or]The church garden would be a good place to look.[or]Let's GO TO THE CHURCH, then GO WEST into the garden.[stopping]" instead;

if the ticket is not seen, say "[one of]There is something in the church garden that might be useful.[or]We could remove the h from THICKET in the church garden.[stopping]" instead;

if the player carries the ticket, say "We could give the ticket to the ticket-taker.";

otherwise say "We could get the ticket and give it to the ticket-taker.";

stop the action.

Report requesting hint about the tube:

say "[one of]It would be useful if this were a larger container.[or]Perhaps something that could be made from the word TUBE.[or]How about a tub?[or]WAVE E-REMOVER AT TUBE.[stopping]";

stop the action.

Check requesting hint about the locker when the lock is visible:

try requesting hint about the lock instead.

Report requesting hint about the locker:

say "Since the lock has been dealt with, we should be set." instead.

Report requesting hint about the backpacking girl:

say "[one of]We can't retrieve our things with the backpacking girl here watching, so we'll have to get her to leave[or]I bet we could freak her out with one of those standard tricks Atlanteans play on tourists — show her something really upsetting that's actually letter-created[or]Like maybe a disembodied body part[or][body-part-suggestion][stopping]." instead.

To say body-part-suggestion:

if the player carries a freaky thing (called recommended freaky):

say "I suggest showing [recommended freaky] to the girl";

else if a freaky thing (called recommended freaky) is seen:

say "Showing the girl [the recommended freaky] might work";

else:

say "[one of]I know we've seen something that could be converted into a body part[or]The wheel back at the Fair might do[or]W-remove the wheel, then take the heel and show it to the girl, is what I'm thinking of[stopping].";

Check requesting hint about the lock when the backpacking girl is visible:

try requesting hint about the backpacking girl instead.

Report requesting hint about the lock:

if the player does not enclose the tub and the player does not enclose the tube:

if the barker is in the Midway:

say "[one of]To get past the lock, we may have to restore it to its original self.[or]To do that, it would be helpful if we had some restoration gel.[or]Try the game with the barker first.[stopping]";

else:

say "[one of]We'll need that gel we won from the barker.[stopping]";

else if the player encloses the tube:

say "[one of]The restoration gel might come in handy.[or]Of course, we'd need a larger supply of it.[or]We'd better concentrate on the tube before trying to get past the lock.[stopping]";

else:

say "[one of]The lock was not originally a lock.[or]Maybe we can restore it to what it was originally.[or]PUT GEL ON LOCK.[stopping]";

stop the action.