Counterfeit Monkey — 52 of 292

Section 3 - Cars

[The aim of the car code is to create a car that

-- navigates roads the player otherwise wouldn't be able to cross

-- responds sensibly to a wide range of commands, both standard GO commands and commands about driving

-- performs as transparently as possible after initial use, automating everything to do with opening, entering, turning on, driving, turning off, exiting, and closing the car so that the player is not conscious of these steps.

Once acquired and repaired, the car should become as nearly transparent as walking across those areas on foot, except that it provides some additional boundaries when in the Roundabout area, where the player can't get out except under special circumstances.

Because any vanilla chair can be converted to a car, there are multiple cars; in practice, the player is unlikely to create more than one, and the first available one must always come from the chard.]

Understand "start [something]" as switching on.

Understand "drive [a direction]" as going when the player is in a vehicle.

Understand "drive [car] [a direction]" as car-driving when the player is in the car. Car-driving is an action applying to one thing and one visible thing. Carry out car-driving: try going the second noun.

Understand "drive to [any nonsecret room]" as approaching.

Understand "drive [car] to [any nonsecret room]" as car-approaching. Car-approaching is an action applying to one thing and one visible thing. Carry out car-approaching: try approaching the second noun.

Understand "honk" or "honk at [text]" as a mistake ("[if the player is not in the car]We aren't a goose[otherwise if the protesters are visible]One of the protesters turns and waves, taking this as a gesture of support[otherwise]We receive an insulting gesture from the person in the car ahead[end if].").

Understand "protest" or "join protest" or "picket" as a mistake ("If I thought you could change Atlantis that way, I'd be on board. But I've given up on social action long since.").

A car is a kind of vehicle. A car is usually transparent. The heft of a car is 7. The flexible appearance of a car is "Our car[one of] [--] a sub-sub-compact that looks like it might be outraced by a kid on a scooter [--][or] [--] which might better be described as a covered bicycle [--][or][at random] is parked [if the location is offroad]illegally [end if]nearby."

The description of a car is "It is little larger than a toy, but that is what you want when driving on the streets around here. Any substantial vehicle wouldn't fit down the winding drives."

The introduction is "Here is how my mother gets around. She takes a 300 Euro Hermès scarf with an orange border and a pattern of prancing horses. She tosses it in the air. As it falls, she shoots it twice, like a clay pigeon: once to take out the F, the second time for the S. And such a car: buttery leather seats, jaguar lines. If someone asks how she gets such good results, she jokes that it's because of her quality materials.

Suffice it to say that we are not similarly blessed."

Understand "toy" or "sub-subcompact" as a car.

The scent-description of a car is "metal parts and oil".

A car can be fueled or unfueled. A car is usually unfueled.

Definition: a thing is fuel-like if it is the fuel or it is the gas.

Sanity-check inserting a fuel-like thing into a car:

try fueling the second noun with the noun instead.

Understand "fuel [something] with [something preferably held]" as fueling it with. Understand "fuel [something]" as fueling it with. Fueling it with is an action applying to one thing and one carried thing.

Rule for supplying a missing second noun while fueling something with:

if the player can see the fuel:

now the second noun is the fuel;

otherwise if the player can see the gas:

now the second noun is the gas;

otherwise:

say "[You] don't have any plausible fuel to hand."

Check fueling something with a vegetable:

say "I've heard of biodiesel, but that carries the point too far." instead.

Check fueling something with something which is not fuel-like:

say "[The second noun] do[es]n't make much of a fuel." instead.

Check fueling something which is not a car with something:

say "[The noun] [one of]do[es]n't take fuel[or][is-are]n't fuel-powered[at random]." instead.

Carry out fueling something with something:

remove the second noun from play;

now the noun is fueled;

complete "Fuel the car";

record "fueling our car" as achieved;

say "I deeply fear automotive maintenance, but I can (just) manage to pour in the fuel... and I think that's done it." instead.

Rule for printing the name of a car while opening or closing the car:

say "car door".

Understand "fix [something]" or "mend [something]" or "tune [something]" or "tune up [something]" or "tune [something] up" or "repair [something]" as tuning. Tuning is an action applying to one thing.

Sanity-check tuning something which is not a car:

if the noun is an instrument:

say "Tuning [the noun] would have to be left to an expert; I have no idea how." instead;

if the noun is a person:

say "Psychiatry is not my field of expertise." instead;

say "I am not quite sure what you have in mind, there." instead.

Check tuning:

if the noun is not damaged:

say "The car has already been repaired and is now in working order." instead;

otherwise:

say "I'm not good at this sort of thing. I mostly leave repairs to the garage." instead.

Instead of inserting oil into a car:

say "In my limited interactions with motor vehicles, I've always taken the machine to a garage for any corrective work. This includes topping up the oil."

Report opening a car:

say "[one of][You] open the car door: perhaps unsurprisingly, it comes without an effective lock system.[or][You] swing the car door open.[or][You] open the door of the car.[stopping]" instead.

A description-concealing rule:

now every thing which encloses the player is not marked for listing.

Understand "park" as exiting when the player is in a car. Understand "park [car]" as car-parking when the player is in a car. Car-parking is an action applying to one thing. Carry out car-parking: try exiting instead.

A car is usually openable. A car is usually closed.

Check entering a closed container (this is the attempt opening on enter rule):

try opening the noun;

if the noun is closed, stop the action.

Check exiting when the player is in a closed container (called the current-container) (this is the attempt opening on exit rule):

try opening the current-container;

if the current-container is closed, stop the action.

Check exiting when the player is in a noisy car:

try switching off a random ignition which is incorporated by a car which contains the player;

Check going somewhere by a car which is not noisy:

try switching on a random ignition (called target) which is incorporated by a car which contains the player;

if the target is switched off, stop the action.

Check going somewhere by an open car (called target):

try closing the target;

if the target is open, stop the action.

Rule for describing the interior of a car:

say "[You] [are] jammed into the car with our knees almost at our chin, looking out through the bulbous little [if the player wears the Britishizing goggles]windscreen[otherwise]windshield[end if][if the ignition is switched on]. The motor is growling like a housecat with pneumonia[end if]."

The ignition is a kind of device. One ignition is part of every car. Understand "motor" as the ignition. Instead of listening to the ignition, try listening to a random car which incorporates the noun.

The gas-gauge is a kind of thing. One gas-gauge is part of every car. The description is "[if the car is fueled]It points over at the right, which must be Full[otherwise]It points all the way around at the left, or Empty[end if]." THe printed name of the gas-gauge is "gas gauge". Understand "gauge" or "gas gauge" as the gas-gauge.

Check switching on an ignition which is part of an unfueled car:

say "There's no gas in the car; without fuel, it's not going far." instead.

Check switching on an ignition which is part of a damaged car:

say "Though the engine does briefly turn on, there's clearly something wrong with it, from the unpleasant noises and the flashing lights on the dash. Perhaps it needs oil." instead.

Report switching on an ignition for the first time:

say "We switch on the ignition and the car comes to life. Smelly, trembling, putt-putting life, but still, not bad for something we conjured out of a vegetable picked outside my parents['] place." instead.

[Instead of going by the car when the ignition is switched off: say "The ignition is off at the moment." ]

Carry out going somewhere by car:

complete "Find transport for getting past the traffic on High Street";

record "traveling by car" as achieved.

The car can be operational or damaged. A car is usually damaged.

Instead of going by unfueled car:

assign "Fuel the car" at High Street;

say "The extremely primitive dial in front of us is pointing all the way to the left. I think that's its way of saying it's out of fuel. At any rate, the engine won't start."

Instead of going by damaged car:

say "The car refuses to run properly: evidently you got us a lemon. It's going to take some tuning up before it will go."

Sanity-check switching on a car:

try switching on a random ignition which is part of the noun instead.

Sanity-check switching off a car:

try switching off a random ignition which is part of the noun.

Carry out switching on the ignition:

now a random car which incorporates the noun is noisy.

Carry out switching off the ignition:

now a random car which incorporates the noun is quiet.

Instead of listening to a noisy car:

say "The car is making an unpleasant raspy growl."

Instead of going by car (called used car) to somewhere offroad:

if the player is hurrying:

if the car is noisy:

say "[one of][path-walked so far]Then[or][path-walked so far]There[or]Once [you] get to [location][or]At [location][at random] [you] [find a parking spot].[paragraph break]";

otherwise:

say "[path-walked so far]";

clear path-walked for player;

increase path description count by 1;

otherwise if the car is noisy:

say "Since there's no way by road, we'll have to leave [the used car] here. It is a moment's work to find a parking spot. [run paragraph on]";

otherwise:

say "That involves some off-road travel. We'll have to leave [the used car] here and walk. [run paragraph on]";

try exiting;

if the player is in a car,

stop the action;

otherwise try going the noun.

Report exiting when the container exited from is a car:

say "We climb out of the car." instead.

To say find a parking spot:

if the current daytime is:

-- noon:

say "struggle to find a parking spot";

-- early afternoon:

say "[one of]drive around a bit trying to get a parking spot[or]try to nab several parking spots before finally managing to be more assertive than the other drivers[or]try unsuccessfully to fit into a spot even smaller than the car, before lucking into a freshly-vacated place[at random]";

-- mid afternoon:

say "[one of]find a place to park without too much trouble[or]park deftly in the shadow of a much larger vehicle[or]have a bit of a chore finding a parking spot[at random]";

-- late afternoon:

say "pull easily into one of the available parking spots, since many people have now gone home";

-- sunset:

say "park in the most convenient spot";

-- evening:

say "park" [shouldn't happen because it shouldn't be evening while we're still in driving mode. But we'll see.]

Instead of going by car when the location is offroad:

say "This isn't exactly an area in which driving is encouraged. In fact, I'm not sure [you] can get the car anywhere."

[Include Conditional Backdrops by John Clemens.]

When play begins:

move protesters backdrop to all roads in Busy Streets;

move traffic backdrop to all roads in Busy Streets;

Some protesters are a backdrop. Understand "student" or "students" as the protesters. The description is "Hundreds of people pack the sidewalk, wearing slogans and carrying angry signs."

A description-concealing rule when the location is High Street:

now everything which is enclosed by the protesters is not marked for listing.

Instead of examining the hundreds of people: try examining the protesters.

Some hundreds of people are a person. They are part of the protesters. They wear slogans. They carry angry signs.

The description of the angry signs is "They say things like 'No Referendum = No Responsibility,' 'NOT GUILTY,' and, more daringly, 'The citizens of Atlantis have never voted for human rights violations.' Some are just photos of Bureau officials wearing Hitler mustaches.

The protesters can't say this directly, of course, but what they are protesting is the use of inanimation as a punishment by the Bureau of Orthography. Making someone into an inanimate object, or enclosing him in an inanimate object, is not technically murder, but it is considered a massive human rights violation by just about every other country in the world."

The description of the slogans is "On every shirt and coat, sometimes screen-printed, sometimes just written on with a Sharpie, is the same message: NOT GUILTY.

You know better than I do how the international media looks at Atlantis. How it presents us as a fat, wealthy plutocracy whose citizens happily engage in atrocities in order to keep hold of our unique advantages. But on most of those human rights issues, it's not as though we were ever asked. We never voted to do those things. The Bureau simply enacted them as 'non-referrable procedures.'"

Instead of listening to the protesters:

say "'Referendum Now!' they're shouting. And 'Not guilty.'"

Instead of listening to the location in the presence of the protesters:

say "There are standard traffic noises and then the protesters. [no line break]";

try listening to the protesters.

The traffic is a backdrop. It is distant. The indefinite article is "some". Understand "cars" or "vehicles" or "tail-lights" or "lights" or "drivers" or "congestion" as the traffic. The description of the traffic is "Nearly bumper-to-bumper despite the tiny size of the individual vehicles[one of]. In fact, I've never understood why people drive here at all: the city is almost small enough to make do with pedestrian routes and bicycles[or][stopping].".

Instead of entering traffic:

say "No one in these vehicles is likely to want to drive us anywhere."

[The scaffolding is a backdrop. Understand "construction" or "scaffold" as the scaffolding. The description is "Lately they've been doing a lot of construction and reconstruction around the center of town. They say it's renovation of dangerous old buildings. There are also other theories."

Instead of climbing the scaffolding:

say "I wasn't a construction worker in previous life, and I'm pretty sure you weren't either." ]

Understand "cross [traffic]" or "ignore [traffic]" as a mistake ("You may have the nerve, but I don't.") when the player can see the traffic.

Test car-behavior with "tutorial off / car-acquire / cross traffic / ignore traffic / drive to roundabout / park / get out of car / go to deep street / nw / e / climb masses / look through window / out / out / se / get in car / drive to tall street / go to roundabout / drive to monkey" in high street.

Test roundaboutation with "tutorial off / car-acquire / drive to roundabout / z / z / z" in high street.