Counterfeit Monkey — 71 of 292

Part 5 - Extra Actions

Section 1 - Swimming and other Seaside Activities

Swimming is an action applying to one visible thing.

Understand "swim [a direction]" as swimming.

Understand "swim" or "float" as swimming.

Rule for supplying a missing noun while swimming:

if the location is not swimmable:

say "[You][']d need to be closer to the shore.";

rule fails;

otherwise:

now the noun is north.

Check swimming:

if the location is not swimmable:

say "[You][']d need to be closer to the shore." instead.

Check swimming (this is the block swimming off the boat rule):

if the location is nautical:

say "Safest to stay on the yacht; it was hard enough getting here." instead.

Check swimming (this is the always block swimming rule):

say "Considering the delicacy of our possessions and the distance [you] need to travel, swimming is not a viable solution." instead.

Instead of swimming something when the location is the Customs Hallway or the location is the precarious perch:

say "From up here? Unlikely. And even from the water's edge, it would be better to have a boat."

Instead of swimming something when [the Holding Chamber is not visited and] the location is the Docks:

say "Going swimming in these murky waters isn't an appealing thought, and anyway [you] don't have time for a pleasure dip just now."

Definition: a room is swimmable:

if it is the Docks:

yes;

if it is nautical:

yes;

if the player can see the sea-view:

yes;

no.

Understand "surf" or "go surfing" or "windsurf" or "wind surf" as surfing. Surfing is an action applying to nothing.

Check surfing in a swimmable room:

say "The waves around here are nothing like big enough, even if [you] had a board." instead.

Check surfing:

say "Even if [you] were down by the water, the waves on this island aren't really surfable." instead.

Understand "body surf" or "bodysurf" as bodysurfing. Bodysurfing is an action applying to nothing.

Check bodysurfing in a swimmable room:

say "The waves around here are nothing like big enough, even if [you] had the skill and wanted to get our things all wet." instead.

Check bodysurfing:

say "Even if [you] were down by the water, the ocean around here isn't very surfable." instead.

Understand "dive in/into [sea-view]" or "jump in/into [sea-view]" as diving into. Understand "dive in/into [distant-sea-view]" or "jump in/into [distant-sea-view]" as diving into. Understand "dive in/into [something fluid]" or "jump in/into [something fluid]" as diving into. Understand "dive in/into [something]" or "jump in/into [something]" as diving into. Diving into is an action applying to one thing.

Instead of entering a fluid:

try diving into the noun.

Before diving into distant-sea-view:

say "[You][']d never make it from here." instead. [Need to get past the accessibility issues.]

Sanity-check diving into a person:

say "I've heard of sinking into someone's eyes before, but..." instead.

Sanity-check diving into a toilet:

say "Unhygienic even if possible." instead.

Sanity-check diving into something which is not a fluid:

say "It generally works best to dive into liquids." instead.

Sanity-check diving into a fluid thing which is not a backdrop:

say "[The noun] [is-are]n't exactly deep enough to [one of]bathe in[or]swim in[or]dive into[at random]." instead.

Check diving into sea-view:

say "The shore here slopes gradually, with very shallow water at the beginning." instead.

Test watersports with "test liquid-jump / test near-jump / test high-jump".

Test high-jump with "dive / jump into the sea / surf / bodysurf / wind surf / swim / jump" in the Precarious Perch.

Test liquid-jump with "jump / dive / jump into the spill / dive in the spill / dive into the spill / surf / bodysurf / wind surf / swim" in the Outdoor Cafe.

Test near-jump with "jump / dive / jump into the ocean / surf / bodysurf / wind surf / swim" in the Private Beach.