Counterfeit Monkey — 131 of 292

Section 3 - Apartment Window

Southwest of Palm Square is a apartment door. apartment door is a lockable locked door. It is scenery. Southwest of apartment door is My Apartment.

Instead of knocking on the bathroom window:

if the player is in Palm Square:

say "There's no one inside; that's the point.";

otherwise:

say "No one from outside will pay any attention, which is just as well."

Before going west in Palm Square when the bathroom window is scenery:

say "That way lies the [bathroom window] of my apartment. Though in fact, if you have a mind to break in, it's the easiest way: it's not hard to force the window.";

now the bathroom window is not scenery instead.

Before unlocking or entering or opening the locked apartment door when the player does not enclose the key and the player is not in My Apartment:

if the bathroom window is scenery

begin;

reveal bathroom window;

say "You had me leave my keys behind, remember?

But if you insist, my apartment is actually pitifully easy to break into. That window there opens onto the bathroom, and you can force it from the outside without much effort." instead;

otherwise;

say "If we want to go into my apartment, we're going to have to climb in my window. Here, let me just streamline this process for us.";

try entering bathroom window instead;

end if.

Understand "force [something openable]" or "force [something openable] open" as opening.

After going through the bathroom window:

let N be the number of entries in the path so far of the player;

if N is greater than 1:

say "[path-walked so far]";

otherwise:

clear the path-walked for the player;

if Apartment Bathroom is not visited:

have Mrs Parsnip issue a challenge;

say "[one of]The window is uncomfortably high and it takes a little scramble to get in, but soon [you] [are] inside[or]This climb is noticeably more difficult now that [you] [are] three inches shorter than my normal height, but hey-ho[or]Far be it from me to critique your abilities in the stealth department, but it might be a good idea not to climb in and out of this window [i]too[/i] many times. My neighb[our]s are only used to seeing me do it once every few days[or]Oh, very well. [Mrs] Parsnip is probably out[stopping]. [command clarification break]";

continue the action.

To have Mrs Parsnip issue a challenge:

say "'Halt! You! Young person!'

It's my neighb[our], [Mrs] Parsnip, leaning out from her apartment above us. [Mrs] Parsnip and I don't interact except about once a month when she comes around to ask for my spare change for bus fare or the laundry.

'Clear off or I'll call the police!' she shouts.";

say "[line break][command prompt]";

wait for any key;

say "[paragraph break]...No, don't worry, I'll handle this.

I step us back and stare up at her. 'I'm a friend of Alex,' I say. 'He called and asked me to stop by because he thought he left the stove on. Said he climbs in the window all the time when he gets locked out.'

'That's true,' she says. 'Shouldn't be allowed out by himself. Okay, go ahead.'

In a mutter she adds, 'Not like he has anything worth stealing anyway.' She vanishes from view.[paragraph break]";

Sanity-check locking keylessly the bathroom window:

say "Oh, it doesn't lock. If it did, we wouldn't find it so easy to come and go." instead.

Report opening the bathroom window for the first time:

say "The window slides open with a hideous protesting shriek." instead.

Report closing the bathroom window:

say "[You] slide the window shut[one of]. I feel obscurely better now[or][stopping]." instead.

Before: if the current action involves the bathroom window,

reveal bathroom window.

To reveal bathroom window:

now bathroom window is obvious;

now bathroom window is fixed in place;

now the bathroom window is not scenery.

The bathroom window is a door. The bathroom window is west of Palm Square and east of the Apartment Bathroom. It is scenery. It is closed and openable. The flexible appearance is "[if the location is Palm Square][b-window-appearance][otherwise]The bathroom window gives some weak sunlight.[end if]". Apartment Bathroom and My Apartment are indoors.

Instead of examining a toilet: say "It's pretty clean."

To say b-window-appearance:

if the Apartment Bathroom is unvisited

begin;

say "Please also note the no-security window giving onto my bathroom. ";

otherwise;

say "My bathroom window [if bathroom window is open]remains vulnerably open[otherwise]is closed, but not, of course, latched[end if]. ";

end if.

The description of the bathroom window is "It is one of those windows that slides sideways open. The latch is broken, so it can't actually be secured."

Instead of searching the bathroom window: say "It is made of frosted glass, precisely because of people like you."

Understand "climb through [something]" or "climb in [something]" or "climb into [something]" or "climb out of [something]" or "climb out [something]" as entering.