Counterfeit Monkey — 133 of 292

Emily Short

Release 6

Section 5 - Apartment itself

My Apartment is a kitchen. The introduction of my apartment is "I'd apolog[ize] for the mess, but should [you] really be here? I'm reconciled to leaving all my things behind, you know. You made me promise that I didn't mind."

Rule for listing exits when looking in My Apartment:

do nothing instead.

The kitchen area is fixed in place in My Apartment. The flexible appearance is "It's an efficiency: note [the kitchen area], with all the usual appliances, in one corner."

Instead of examining a stove in my apartment:

say "It's an older gas range, but it's clean and it's good at stirfries."

Instead of examining an oven in my apartment:

say "I don't use it much except to bake frozen pizzas."

After writing a paragraph about the kitchen area:

now the kitchen area is mentioned;

now every stove is mentioned; now every refrigerator is mentioned; now every oven is mentioned; now every sink is mentioned; now every cabinet is mentioned; now every furniture counter is mentioned. [This is to fix it so that descriptions say, e.g., 'in THE refrigerator' rather than 'in a refrigerator'.]

Instead of entering the kitchen area, say "This is really too small a space to make that distinction interesting." Understand "appliances" or "appliance" as the kitchen area. The description of kitchen area is "I have a [if a sink is in my apartment]sink, [end if]stove, refrigerator, cabinets, a countertop: the usual[if the number of sinks in my apartment is 0]. No sink, but that's thanks to your meddling[end if]." The introduction of kitchen area is "My mother attempted to provide a microwave, rice cooker, toaster, waffle iron, and julienne-fry-maker, but I pointed out that these objects would triple-populate the two square feet of available counter space."

When play begins:

let destination be a random refrigerator which is in my apartment;

move the pot-of-yogurt to the destination;

let destination be a random furniture counter which is in my apartment;

now every book which is in My Apartment is on the destination;

Test sink-kitchen with "X KITCHEN / WAVE S-REMOVER AT SINK / X KITCHEN" in My Apartment.

Studies Primary Language Acquisition is a book in My Apartment. Journal of Third-World Economics is a book in My Apartment.

The printed name of Studies Primary Language Acquisition is "Studies in Primary Language Acquisition". Understand "studies in" as Studies Primary Language Acquisition.

The description of Studies Primary Language Acquisition is "This is a little outside my field, but I have been trying to work out the feasibility of my plans, from the perspective of language teaching."

The description of Journal of Third-World Economics is "This is just Volume 16, but I subscribed annually for a while. My whole plan is useless unless there's a well-designed language that actually takes account of economic reality in the target region. When I've moved somewhere outside Atlantis it will be easier to conduct that part of the research." Understand "volume" or "16" or "volume of" or "volume 16 of" as Journal of Third-World Economics.

A pot-of-yogurt is an edible thing. The printed name is "yogurt". Understand "yogurt" or "yoghurt" as the pot-of-yogurt. The description is "It is the gooseberry fool flavor, left over from a six-pack. I always eat the strawberry and peach first." The introduction is "Okay, I feel guilty about leaving this to go bad, but I was in a rush [--] I did get rid of most of the rest of my food over the last couple of days, but I just never had time to eat this. And it seemed wrong to throw it out. Sue me." The indefinite article of the pot-of-yogurt is "some".

Rule for printing the name of the pot-of-yogurt when the player wears the Britishizing goggles:

say "yoghurt".

Test yogurtbug with "tutorial off / x yogurt / x yoghurt" holding the pot-of-yogurt.

A futon is a clothed bed. The futon is in My Apartment. The description of the futon is "Strictly speaking, more of a futon mattress. It doesn't have a frame." The flexible appearance is "My [futon] is on the floor in the opposite corner. ".

Rule for disclosing contents of the futon:

let the special-target be the futon;

change the current-subject to special-target;

if at least two books are on the futon


say "Clumsily stacked on the futon [is-are a list of books on the futon]";

if at least three mentionable things are on the futon


say "; [a list of mentionable things on the futon] are scattered in the remaining space. ";


if something mentionable is on the futon, say ", as well as [a list of mentionable things on the futon]. ";

otherwise say ". ";

end if;


say "On top [is-are a list of things on the futon]. ";

end if;

A book called The Problem of Adjectives is on the futon. Understand "problems" as the problem of adjectives.

Test returnbook with "put problem away" holding the Problem of Adjectives in the Seminar Room.

Understand "return [something preferably held]" or "put away [something preferably held]" or "put [something preferably held] away" or "shelve [something preferably held]" as returning. Returning is an action applying to one carried thing.

Sanity-check returning guidebook:

say "I don't think anyone will mind our having it. Books at hostels come and go, to judge by your recollections." instead.

Sanity-check returning something:

if the noun is not a book:

say "[The noun] [is-are] not a library book." instead;

if the noun is not Problem of Adjectives:

say "[The noun] [is-are] ours." instead.

Check returning the Problem of Adjectives:

if the location is not Language Studies Seminar Room:

say "[The noun] came from the Language Studies Seminar Room, so that's where we would need to be.";

try approaching the Language Studies Seminar Room;

if the location is not Language Studies Seminar Room:

stop the action.

Carry out returning the Problem of Adjectives:

try putting the Problem of Adjectives on the LSR bookcase.

Instead of examining the Problem of Adjectives:

say "It's not my book; it belongs to the department, as [you] can see from the fact that it's stamped LANGUAGE STUDIES DEPARTMENT : SEMINAR ROOM inside.

I got it out because it provides a general overview of adjectival 'adherence' [--] that is, how and when an adjective is so much part of the name of something that it can be affected by tools like your [letter-remover], and when it is purely incidental.

I see I may be losing you. Shall I put this in layman's terms? >>";

if the player consents


say "[line break]The short version is: I want to design a language with spelling and pronunciation selected so that valuable resources like food, water, and clothing can easily be made from available resources and pollutants such as plastic garbage and seawater.

There are major problems in constructing such a language because ideas like 'pure' and 'potable' and 'healthy' tend to be specified by adjectives rather than by nouns [--] English doesn't have one colloquial word that means 'pure water', for instance. But I believe that a correctly constructed language that incorporated the concept of 'pure water' into a single word would be exceptionally powerful and might transform the third world.";


say "[line break]Okay, then.

In general, strongly-adhering adjectives produce problems by preventing conversions that might otherwise be possible; conversely, it is difficult to make objects with particular characteristics because those characteristics are described by weakly-adhering adjectives.

The point is: it is possible to use linguistic tools to create water. It is [i]not[/i] reliably possible, at least in American English, to use those tools to create potable water, because 'potable' is a weakly-adhering adjective describing a statistically uncommon trait. This means that linguistic reification is helpless to solve water supply problems, even in third-world regions using a high-efficacy language. For that matter even when a word has a strongly-adhering adjective, the interference of that adjective usually just makes the object impossible to reify at all.

What [you] need, therefore, is a language with nouns that uniquely specify substances['] desirable traits: 'potable' or 'pure' water should be named something distinct from adulterated forms of H2O, and so on.

Have I bored you enough yet? >>";

if the player consents, say "[line break]Right, sorry. Well, you get the general idea, anyway.";

otherwise say "[line break]Scientific jargon does, of course, exist to specify objects uniquely, but there are two problems. One is that most chemical and biological terminology is used by such a small subset of the population that it has near-zero linguistic efficacy: creating a substance by formula requires an amount of energy roughly on par with pointing a w-remover at Aberystwyth. This is not a realistic solution to resource problems.

The second difficulty is that even with well-known exceptions such as 'H2O', the formula is not usually not a linguistic subset of the formula of another widely available and well-known substance.

Hence the need for a new language with nouns designed based on careful scientific research into the primary needs and resources of living in a given region. This language could then be systematically taught to everyone dwelling in that area, causing permanent economic uplift.

'Systematically taught' is a bit of a problem, since it would take massive funding and effort to make the language known widely enough to gain linguistic efficacy. And there would be significant issues in not totally crowding out indigenous languages and thus destroying an existing culture.

But I have high hopes, assuming I can ever get out of this repressive little burg and make my case to one or more of the major world relief organ[ization]s.";

end if.

The introduction is "I should have taken it back to the library [--] I [i]meant[/i] to take it back to the library [--] but there just wasn't time. The last couple of hours before I came to meet you were frantic. The way I figured it, my parents or someone will come looking for me and they'll take it back for me. I think."

After printing the name of Problem of Adjectives while taking inventory:

say " (to return to the department seminar room)".

Report taking the Problem of Adjectives for the first time:

say "We take [the Problem of Adjectives]. Might as well return it to the department seminar room, as long as we're going that way." instead.

Before going from My Apartment when the player does not enclose The Problem of Adjectives:

try taking The Problem of Adjectives.

A description-concealing rule when The Problem of Adjectives is as-yet-unknown and The Problem of Adjectives is marked for listing:

now every marked for listing thing is not marked for listing;

now the Problem of Adjectives is marked for listing.

Rule for writing a topic sentence about the Problem of Adjectives when The Problem of Adjectives is as-yet-unknown:

say "I should point out my copy of [the Problem of Adjectives]. ".

[Before writing a paragraph about something (called special-target):

if special-target is unmentioned, let restore-state be true; otherwise let restore-state be false;

say "Starting paragraph about [special-target].";

if restore-state is true, now special-target is unmentioned.]

Ranking rule for the problem of adjectives when The Problem of Adjectives is as-yet-unknown:

increase the description-rank of Problem of Adjectives by 10.

Definition: the Problem of Adjectives is deeply dull: no.

Busy Streets is a region. High Street, Roundabout, Tall Street, Long Street North, and Long Street South are in Busy Streets.